subprojects/gst-plugins-ugly/meson.build

   1 project('gst-plugins-ugly', 'c',
   2   version : '1.21.0.1',
   3   meson_version : '>= 0.60',
   4   default_options : [ 'warning_level=1',
   5                       'buildtype=debugoptimized' ])
   6
   7 gst_version = meson.project_version()
   8 version_arr = gst_version.split('.')
   9 gst_version_major = version_arr[0].to_int()
  10 gst_version_minor = version_arr[1].to_int()
  11 gst_version_micro = version_arr[2].to_int()
  12  if version_arr.length() == 4
  13   gst_version_nano = version_arr[3].to_int()
  14 else
  15   gst_version_nano = 0
  16 endif
  17 gst_version_is_stable = gst_version_minor.is_even()
  18 gst_version_is_dev = gst_version_minor.is_odd() and gst_version_micro < 90
  19
  20 have_cxx = add_languages('cpp', native: false, required: false)
  21
  22 glib_req = '>= 2.56.0'
  23
  24 if gst_version_is_stable
  25   gst_req = '>= @0@.@1@.0'.format(gst_version_major, gst_version_minor)
  26 else
  27   gst_req = '>= ' + gst_version
  28 endif
  29
  30 api_version = '1.0'
  31
  32 plugins_install_dir = join_paths(get_option('libdir'), 'gstreamer-1.0')
  33 plugins = []
  34
  35 cc = meson.get_compiler('c')
  36 if have_cxx
  37   cxx = meson.get_compiler('cpp')
  38 endif
  39
  40 if cc.get_id() == 'msvc'
  41   msvc_args = [
  42       # Ignore several spurious warnings for things gstreamer does very commonly
  43       # If a warning is completely useless and spammy, use '/wdXXXX' to suppress it
  44       # If a warning is harmless but hard to fix, use '/woXXXX' so it's shown once
  45       # NOTE: Only add warnings here if you are sure they're spurious
  46       '/wd4018', # implicit signed/unsigned conversion
  47       '/wd4146', # unary minus on unsigned (beware INT_MIN)
  48       '/wd4244', # lossy type conversion (e.g. double -> int)
  49       '/wd4305', # truncating type conversion (e.g. double -> float)
  50       cc.get_supported_arguments(['/utf-8']), # set the input encoding to utf-8
  51   ]
  52
  53   if gst_version_is_dev
  54     # Enable some warnings on MSVC to match GCC/Clang behaviour
  55     msvc_args += cc.get_supported_arguments([
  56       '/we4002', # too many actual parameters for macro 'identifier'
  57       '/we4003', # not enough actual parameters for macro 'identifier'
  58       '/we4013', # 'function' undefined; assuming extern returning int
  59       '/we4020', # 'function' : too many actual parameters
  60       '/we4027', # function declared without formal parameter list
  61       '/we4029', # declared formal parameter list different from definition
  62       '/we4033', # 'function' must return a value
  63       '/we4045', # 'array' : array bounds overflow
  64       '/we4047', # 'operator' : 'identifier1' differs in levels of indirection from 'identifier2'
  65       '/we4053', # one void operand for '?:'
  66       '/we4062', # enumerator 'identifier' in switch of enum 'enumeration' is not handled
  67       '/we4098', # 'function' : void function returning a value
  68       '/we4101', # 'identifier' : unreferenced local variable
  69       '/we4189', # 'identifier' : local variable is initialized but not referenced
  70     ])
  71   endif
  72   if have_cxx
  73     add_project_arguments(msvc_args, language: ['c', 'cpp'])
  74   else
  75     add_project_arguments(msvc_args, language: 'c')
  76   endif
  77   # Disable SAFESEH with MSVC for plugins and libs that use external deps that
  78   # are built with MinGW
  79   noseh_link_args = ['/SAFESEH:NO']
  80 else
  81   noseh_link_args = []
  82 endif
  83
  84 if cc.has_link_argument('-Wl,-Bsymbolic-functions')
  85   add_project_link_arguments('-Wl,-Bsymbolic-functions', language : 'c')
  86 endif
  87 if have_cxx and cxx.has_link_argument('-Wl,-Bsymbolic-functions')
  88   add_project_link_arguments('-Wl,-Bsymbolic-functions', language : 'cpp')
  89 endif
  90
  91 cdata = configuration_data()
  92 cdata.set('ENABLE_NLS', 1)
  93
  94 check_headers = [
  95   ['HAVE_DLFCN_H', 'dlfcn.h'],
  96   ['HAVE_INTTYPES_H', 'inttypes.h'],
  97   ['HAVE_MALLOC_H', 'malloc.h'],
  98   ['HAVE_MEMORY_H', 'memory.h'],
  99   ['HAVE_STDINT_H', 'stdint.h'],
 100   ['HAVE_STDLIB_H', 'stdlib.h'],
 101   ['HAVE_STRINGS_H', 'strings.h'],
 102   ['HAVE_STRING_H', 'string.h'],
 103   ['HAVE_SYS_STAT_H', 'sys/stat.h'],
 104   ['HAVE_SYS_TYPES_H', 'sys/types.h'],
 105   ['HAVE_UNISTD_H', 'unistd.h'],
 106   ['HAVE_WINSOCK2_H', 'winsock2.h'],
 107 ]
 108
 109 foreach h : check_headers
 110   if cc.has_header(h.get(1))
 111     cdata.set(h.get(0), 1)
 112   endif
 113 endforeach
 114
 115 check_functions = [
 116   ['HAVE_DCGETTEXT', 'dcgettext'], # FIXME: this looks unused
 117 ]
 118
 119 foreach f : check_functions
 120   if cc.has_function(f.get(1))
 121     cdata.set(f.get(0), 1)
 122   endif
 123 endforeach
 124
 125 cdata.set('SIZEOF_CHAR', cc.sizeof('char'))
 126 cdata.set('SIZEOF_INT', cc.sizeof('int'))
 127 cdata.set('SIZEOF_LONG', cc.sizeof('long'))
 128 cdata.set('SIZEOF_SHORT', cc.sizeof('short'))
 129 cdata.set('SIZEOF_VOIDP', cc.sizeof('void*'))
 130
 131 cdata.set_quoted('VERSION', gst_version)
 132 cdata.set_quoted('PACKAGE', 'gst-plugins-ugly')
 133 cdata.set_quoted('GST_LICENSE', 'LGPL')
 134 cdata.set_quoted('GETTEXT_PACKAGE', 'gst-plugins-ugly-1.0')
 135 cdata.set_quoted('LOCALEDIR', join_paths(get_option('prefix'), get_option('localedir')))
 136
 137 # GStreamer package name and origin url
 138 gst_package_name = get_option('package-name')
 139 if gst_package_name == ''
 140   if gst_version_nano == 0
 141     gst_package_name = 'GStreamer Ugly Plug-ins source release'
 142   elif gst_version_nano == 1
 143     gst_package_name = 'GStreamer Ugly Plug-ins git'
 144   else
 145     gst_package_name = 'GStreamer Ugly Plug-ins prerelease'
 146   endif
 147 endif
 148 cdata.set_quoted('GST_PACKAGE_NAME', gst_package_name)
 149 cdata.set_quoted('GST_PACKAGE_ORIGIN', get_option('package-origin'))
 150
 151 # Mandatory GST deps
 152 gst_dep = dependency('gstreamer-1.0', version : gst_req,
 153     fallback : ['gstreamer', 'gst_dep'])
 154 gstapp_dep = dependency('gstreamer-app-1.0', version : gst_req,
 155     fallback : ['gst-plugins-base', 'app_dep'])
 156 gstvideo_dep = dependency('gstreamer-video-1.0', version : gst_req,
 157     fallback : ['gst-plugins-base', 'video_dep'])
 158 gstpbutils_dep = dependency('gstreamer-pbutils-1.0', version : gst_req,
 159     fallback : ['gst-plugins-base', 'pbutils_dep'])
 160 gsttag_dep = dependency('gstreamer-tag-1.0', version : gst_req,
 161     fallback : ['gst-plugins-base', 'tag_dep'])
 162 gstfft_dep = dependency('gstreamer-fft-1.0', version : gst_req,
 163     fallback : ['gst-plugins-base', 'fft_dep'])
 164 gstaudio_dep = dependency('gstreamer-audio-1.0', version : gst_req,
 165     fallback : ['gst-plugins-base', 'audio_dep'])
 166 gstbase_dep = dependency('gstreamer-base-1.0', version : gst_req,
 167   fallback : ['gstreamer', 'gst_base_dep'])
 168 gstriff_dep = dependency('gstreamer-riff-1.0', version : gst_req,
 169     fallback : ['gst-plugins-base', 'riff_dep'])
 170 gstrtp_dep = dependency('gstreamer-rtp-1.0', version : gst_req,
 171     fallback : ['gst-plugins-base', 'rtp_dep'])
 172 gstnet_dep = dependency('gstreamer-net-1.0', version : gst_req,
 173   fallback : ['gstreamer', 'gst_net_dep'])
 174 gstsdp_dep = dependency('gstreamer-sdp-1.0', version : gst_req,
 175     fallback : ['gst-plugins-base', 'sdp_dep'])
 176 gstrtsp_dep = dependency('gstreamer-rtsp-1.0', version : gst_req,
 177     fallback : ['gst-plugins-base', 'rtsp_dep'])
 178 gstcheck_dep = dependency('gstreamer-check-1.0', version : gst_req,
 179     required : get_option('tests'),
 180     fallback : ['gstreamer', 'gst_check_dep'])
 181 gstcontroller_dep = dependency('gstreamer-controller-1.0', version : gst_req,
 182   fallback : ['gstreamer', 'gst_controller_dep'])
 183
 184 orc_dep = dependency('orc-0.4', version : '>= 0.4.16', required : get_option('orc'),
 185     fallback : ['orc', 'orc_dep'])
 186 if orc_dep.found()
 187   cdata.set('HAVE_ORC', 1) # used by a52dec for cpu detection
 188 else
 189   cdata.set('DISABLE_ORC', 1)
 190 endif
 191
 192 gmodule_dep = dependency('gmodule-no-export-2.0', version: glib_req)
 193
 194 if gmodule_dep.version().version_compare('< 2.67.4')
 195   cdata.set('g_memdup2(ptr,sz)', '(G_LIKELY(((guint64)(sz)) < G_MAXUINT)) ? g_memdup(ptr,sz) : (g_abort(),NULL)')
 196 endif
 197
 198 ugly_args = ['-DHAVE_CONFIG_H']
 199 configinc = include_directories('.')
 200 libsinc = include_directories('gst-libs')
 201
 202 # Disable compiler warnings for unused variables and args if gst debug system is disabled
 203 if gst_dep.type_name() == 'internal'
 204   gst_debug_disabled = not subproject('gstreamer').get_variable('gst_debug')
 205 else
 206   # We can't check that in the case of subprojects as we won't
 207   # be able to build against an internal dependency (which is not built yet)
 208   gst_debug_disabled = cc.has_header_symbol('gst/gstconfig.h', 'GST_DISABLE_GST_DEBUG', dependencies: gst_dep)
 209 endif
 210
 211 if gst_debug_disabled
 212   message('GStreamer debug system is disabled')
 213   if cc.has_argument('-Wno-unused')
 214     add_project_arguments('-Wno-unused', language: 'c')
 215   endif
 216   if have_cxx and cxx.has_argument ('-Wno-unused')
 217     add_project_arguments('-Wno-unused', language: 'cpp')
 218   endif
 219 else
 220   message('GStreamer debug system is enabled')
 221 endif
 222
 223 warning_flags = [
 224   '-Wmissing-declarations',
 225   '-Wredundant-decls',
 226   '-Wwrite-strings',
 227   '-Wformat',
 228   '-Wformat-nonliteral',
 229   '-Wformat-security',
 230   '-Winit-self',
 231   '-Wmissing-include-dirs',
 232   '-Waddress',
 233   '-Wno-multichar',
 234   '-Wvla',
 235   '-Wpointer-arith',
 236   '-Waggregate-return',
 237   '-fno-strict-aliasing',
 238   # Symbol visibility
 239   '-fvisibility=hidden',
 240 ]
 241
 242 warning_c_flags = [
 243   '-Wmissing-prototypes',
 244   '-Wold-style-definition',
 245   '-Wdeclaration-after-statement',
 246   '-Wnested-externs'
 247 ]
 248
 249 foreach extra_arg : warning_flags
 250   if cc.has_argument (extra_arg)
 251     add_project_arguments([extra_arg], language: 'c')
 252   endif
 253   if have_cxx and cxx.has_argument (extra_arg)
 254     add_project_arguments([extra_arg], language: 'cpp')
 255   endif
 256 endforeach
 257
 258 foreach extra_arg : warning_c_flags
 259   if cc.has_argument (extra_arg)
 260     add_project_arguments([extra_arg], language: 'c')
 261   endif
 262 endforeach
 263
 264 # Define G_DISABLE_DEPRECATED for development versions
 265 if gst_version_is_dev
 266   message('Disabling deprecated GLib API')
 267   add_project_arguments('-DG_DISABLE_DEPRECATED', language: 'c')
 268 endif
 269
 270 cast_checks = get_option('gobject-cast-checks')
 271 if cast_checks.disabled() or (cast_checks.auto() and not gst_version_is_dev)
 272   message('Disabling GLib cast checks')
 273   add_project_arguments('-DG_DISABLE_CAST_CHECKS', language: 'c')
 274 endif
 275
 276 glib_asserts = get_option('glib-asserts')
 277 if glib_asserts.disabled() or (glib_asserts.auto() and not gst_version_is_dev)
 278   message('Disabling GLib asserts')
 279   add_project_arguments('-DG_DISABLE_ASSERT', language: 'c')
 280 endif
 281
 282 glib_checks = get_option('glib-checks')
 283 if glib_checks.disabled() or (glib_checks.auto() and not gst_version_is_dev)
 284   message('Disabling GLib checks')
 285   add_project_arguments('-DG_DISABLE_CHECKS', language: 'c')
 286 endif
 287
 288 presetdir = join_paths(get_option('datadir'), 'gstreamer-' + api_version, 'presets')
 289
 290 pkgconfig = import('pkgconfig')
 291 plugins_pkgconfig_install_dir = join_paths(plugins_install_dir, 'pkgconfig')
 292 if get_option('default_library') == 'shared'
 293   # If we don't build static plugins there is no need to generate pc files
 294   plugins_pkgconfig_install_dir = disabler()
 295 endif
 296
 297 gpl_allowed = get_option('gpl').allowed()
 298
 299 python3 = import('python').find_installation()
 300
 301 subdir('gst')
 302 subdir('ext')
 303 subdir('tests')
 304
 305 # xgettext is optional (on Windows for instance)
 306 if find_program('xgettext', required : get_option('nls')).found()
 307   subdir('po')
 308 endif
 309 subdir('docs')
 310 subdir('scripts')
 311
 312 # Set release date
 313 if gst_version_nano == 0
 314   extract_release_date = find_program('scripts/extract-release-date-from-doap-file.py')
 315   run_result = run_command(extract_release_date, gst_version, files('gst-plugins-ugly.doap'), check: true)
 316   release_date = run_result.stdout().strip()
 317   cdata.set_quoted('GST_PACKAGE_RELEASE_DATETIME', release_date)
 318   message('Package release date: ' + release_date)
 319 endif
 320
 321 configure_file(output : 'config.h', configuration : cdata)
 322
 323 plugin_names = []
 324 foreach plugin: plugins
 325   if plugin.name().startswith('gst')
 326     plugin_names += [plugin.name().substring(3)]
 327   else
 328     plugin_names += [plugin.name()]
 329   endif
 330 endforeach
 331
 332 summary({
 333     'Plugins': plugin_names,
 334       '(A)GPL license allowed': gpl_allowed,
 335 }, list_sep: ', ')