subprojects/gst-plugins-ugly/meson.build

   1 project('gst-plugins-ugly', 'c',
   2   version : '1.21.0.1',
   3   meson_version : '>= 0.60',
   4   default_options : [ 'warning_level=1',
   5                       'buildtype=debugoptimized' ])
   6
   7 gst_version = meson.project_version()
   8 version_arr = gst_version.split('.')
   9 gst_version_major = version_arr[0].to_int()
  10 gst_version_minor = version_arr[1].to_int()
  11 gst_version_micro = version_arr[2].to_int()
  12  if version_arr.length() == 4
  13   gst_version_nano = version_arr[3].to_int()
  14 else
  15   gst_version_nano = 0
  16 endif
  17 gst_version_is_stable = gst_version_minor.is_even()
  18 gst_version_is_dev = gst_version_minor.is_odd() and gst_version_micro < 90
  19
  20 have_cxx = add_languages('cpp', native: false, required: false)
  21
  22 glib_req = '>= 2.56.0'
  23
  24 if gst_version_is_stable
  25   gst_req = '>= @0@.@1@.0'.format(gst_version_major, gst_version_minor)
  26 else
  27   gst_req = '>= ' + gst_version
  28 endif
  29
  30 api_version = '1.0'
  31
  32 plugins_install_dir = join_paths(get_option('libdir'), 'gstreamer-1.0')
  33 plugins = []
  34
  35 cc = meson.get_compiler('c')
  36 if have_cxx
  37   cxx = meson.get_compiler('cpp')
  38 endif
  39
  40 if cc.get_id() == 'msvc'
  41   msvc_args = [
  42       # Ignore several spurious warnings for things gstreamer does very commonly
  43       # If a warning is completely useless and spammy, use '/wdXXXX' to suppress it
  44       # If a warning is harmless but hard to fix, use '/woXXXX' so it's shown once
  45       # NOTE: Only add warnings here if you are sure they're spurious
  46       '/wd4018', # implicit signed/unsigned conversion
  47       '/wd4146', # unary minus on unsigned (beware INT_MIN)
  48       '/wd4244', # lossy type conversion (e.g. double -> int)
  49       '/wd4305', # truncating type conversion (e.g. double -> float)
  50       cc.get_supported_arguments(['/utf-8']), # set the input encoding to utf-8
  51   ]
  52
  53   if gst_version_is_dev
  54     # Enable some warnings on MSVC to match GCC/Clang behaviour
  55     msvc_args += cc.get_supported_arguments([
  56       '/we4002', # too many actual parameters for macro 'identifier'
  57       '/we4003', # not enough actual parameters for macro 'identifier'
  58       '/we4013', # 'function' undefined; assuming extern returning int
  59       '/we4020', # 'function' : too many actual parameters
  60       '/we4027', # function declared without formal parameter list
  61       '/we4029', # declared formal parameter list different from definition
  62       '/we4033', # 'function' must return a value
  63       '/we4045', # 'array' : array bounds overflow
  64       '/we4047', # 'operator' : 'identifier1' differs in levels of indirection from 'identifier2'
  65       '/we4053', # one void operand for '?:'
  66       '/we4062', # enumerator 'identifier' in switch of enum 'enumeration' is not handled
  67       '/we4098', # 'function' : void function returning a value
  68       '/we4101', # 'identifier' : unreferenced local variable
  69       '/we4189', # 'identifier' : local variable is initialized but not referenced
  70     ])
  71   endif
  72   if have_cxx
  73     add_project_arguments(msvc_args, language: ['c', 'cpp'])
  74   else
  75     add_project_arguments(msvc_args, language: 'c')
  76   endif
  77   # Disable SAFESEH with MSVC for plugins and libs that use external deps that
  78   # are built with MinGW
  79   noseh_link_args = ['/SAFESEH:NO']
  80 else
  81   noseh_link_args = []
  82 endif
  83
  84 if cc.has_link_argument('-Wl,-Bsymbolic-functions')
  85   add_project_link_arguments('-Wl,-Bsymbolic-functions', language : 'c')
  86 endif
  87 if have_cxx and cxx.has_link_argument('-Wl,-Bsymbolic-functions')
  88   add_project_link_arguments('-Wl,-Bsymbolic-functions', language : 'cpp')
  89 endif
  90
  91 cdata = configuration_data()
  92 check_headers = [
  93   ['HAVE_DLFCN_H', 'dlfcn.h'],
  94   ['HAVE_INTTYPES_H', 'inttypes.h'],
  95   ['HAVE_MALLOC_H', 'malloc.h'],
  96   ['HAVE_MEMORY_H', 'memory.h'],
  97   ['HAVE_STDINT_H', 'stdint.h'],
  98   ['HAVE_STDLIB_H', 'stdlib.h'],
  99   ['HAVE_STRINGS_H', 'strings.h'],
 100   ['HAVE_STRING_H', 'string.h'],
 101   ['HAVE_SYS_STAT_H', 'sys/stat.h'],
 102   ['HAVE_SYS_TYPES_H', 'sys/types.h'],
 103   ['HAVE_UNISTD_H', 'unistd.h'],
 104   ['HAVE_WINSOCK2_H', 'winsock2.h'],
 105 ]
 106
 107 foreach h : check_headers
 108   if cc.has_header(h.get(1))
 109     cdata.set(h.get(0), 1)
 110   endif
 111 endforeach
 112
 113 check_functions = [
 114   ['HAVE_DCGETTEXT', 'dcgettext'], # FIXME: this looks unused
 115 ]
 116
 117 foreach f : check_functions
 118   if cc.has_function(f.get(1))
 119     cdata.set(f.get(0), 1)
 120   endif
 121 endforeach
 122
 123 cdata.set('SIZEOF_CHAR', cc.sizeof('char'))
 124 cdata.set('SIZEOF_INT', cc.sizeof('int'))
 125 cdata.set('SIZEOF_LONG', cc.sizeof('long'))
 126 cdata.set('SIZEOF_SHORT', cc.sizeof('short'))
 127 cdata.set('SIZEOF_VOIDP', cc.sizeof('void*'))
 128
 129 cdata.set_quoted('VERSION', gst_version)
 130 cdata.set_quoted('PACKAGE', 'gst-plugins-ugly')
 131 cdata.set_quoted('GST_LICENSE', 'LGPL')
 132 cdata.set_quoted('GETTEXT_PACKAGE', 'gst-plugins-ugly-1.0')
 133 cdata.set_quoted('LOCALEDIR', join_paths(get_option('prefix'), get_option('localedir')))
 134
 135 # GStreamer package name and origin url
 136 gst_package_name = get_option('package-name')
 137 if gst_package_name == ''
 138   if gst_version_nano == 0
 139     gst_package_name = 'GStreamer Ugly Plug-ins source release'
 140   elif gst_version_nano == 1
 141     gst_package_name = 'GStreamer Ugly Plug-ins git'
 142   else
 143     gst_package_name = 'GStreamer Ugly Plug-ins prerelease'
 144   endif
 145 endif
 146 cdata.set_quoted('GST_PACKAGE_NAME', gst_package_name)
 147 cdata.set_quoted('GST_PACKAGE_ORIGIN', get_option('package-origin'))
 148
 149 # Mandatory GST deps
 150 gst_dep = dependency('gstreamer-1.0', version : gst_req,
 151     fallback : ['gstreamer', 'gst_dep'])
 152 gstapp_dep = dependency('gstreamer-app-1.0', version : gst_req,
 153     fallback : ['gst-plugins-base', 'app_dep'])
 154 gstvideo_dep = dependency('gstreamer-video-1.0', version : gst_req,
 155     fallback : ['gst-plugins-base', 'video_dep'])
 156 gstpbutils_dep = dependency('gstreamer-pbutils-1.0', version : gst_req,
 157     fallback : ['gst-plugins-base', 'pbutils_dep'])
 158 gsttag_dep = dependency('gstreamer-tag-1.0', version : gst_req,
 159     fallback : ['gst-plugins-base', 'tag_dep'])
 160 gstfft_dep = dependency('gstreamer-fft-1.0', version : gst_req,
 161     fallback : ['gst-plugins-base', 'fft_dep'])
 162 gstaudio_dep = dependency('gstreamer-audio-1.0', version : gst_req,
 163     fallback : ['gst-plugins-base', 'audio_dep'])
 164 gstbase_dep = dependency('gstreamer-base-1.0', version : gst_req,
 165   fallback : ['gstreamer', 'gst_base_dep'])
 166 gstriff_dep = dependency('gstreamer-riff-1.0', version : gst_req,
 167     fallback : ['gst-plugins-base', 'riff_dep'])
 168 gstrtp_dep = dependency('gstreamer-rtp-1.0', version : gst_req,
 169     fallback : ['gst-plugins-base', 'rtp_dep'])
 170 gstnet_dep = dependency('gstreamer-net-1.0', version : gst_req,
 171   fallback : ['gstreamer', 'gst_net_dep'])
 172 gstsdp_dep = dependency('gstreamer-sdp-1.0', version : gst_req,
 173     fallback : ['gst-plugins-base', 'sdp_dep'])
 174 gstrtsp_dep = dependency('gstreamer-rtsp-1.0', version : gst_req,
 175     fallback : ['gst-plugins-base', 'rtsp_dep'])
 176 gstcheck_dep = dependency('gstreamer-check-1.0', version : gst_req,
 177     required : get_option('tests'),
 178     fallback : ['gstreamer', 'gst_check_dep'])
 179 gstcontroller_dep = dependency('gstreamer-controller-1.0', version : gst_req,
 180   fallback : ['gstreamer', 'gst_controller_dep'])
 181
 182 orc_dep = dependency('orc-0.4', version : '>= 0.4.16', required : get_option('orc'),
 183     fallback : ['orc', 'orc_dep'])
 184 if orc_dep.found()
 185   cdata.set('HAVE_ORC', 1) # used by a52dec for cpu detection
 186 else
 187   cdata.set('DISABLE_ORC', 1)
 188 endif
 189
 190 gmodule_dep = dependency('gmodule-no-export-2.0', version: glib_req)
 191
 192 if gmodule_dep.version().version_compare('< 2.67.4')
 193   cdata.set('g_memdup2(ptr,sz)', '(G_LIKELY(((guint64)(sz)) < G_MAXUINT)) ? g_memdup(ptr,sz) : (g_abort(),NULL)')
 194 endif
 195
 196 ugly_args = ['-DHAVE_CONFIG_H']
 197 configinc = include_directories('.')
 198 libsinc = include_directories('gst-libs')
 199
 200 # Disable compiler warnings for unused variables and args if gst debug system is disabled
 201 if gst_dep.type_name() == 'internal'
 202   gst_debug_disabled = not subproject('gstreamer').get_variable('gst_debug')
 203 else
 204   # We can't check that in the case of subprojects as we won't
 205   # be able to build against an internal dependency (which is not built yet)
 206   gst_debug_disabled = cc.has_header_symbol('gst/gstconfig.h', 'GST_DISABLE_GST_DEBUG', dependencies: gst_dep)
 207 endif
 208
 209 if gst_debug_disabled
 210   message('GStreamer debug system is disabled')
 211   if cc.has_argument('-Wno-unused')
 212     add_project_arguments('-Wno-unused', language: 'c')
 213   endif
 214   if have_cxx and cxx.has_argument ('-Wno-unused')
 215     add_project_arguments('-Wno-unused', language: 'cpp')
 216   endif
 217 else
 218   message('GStreamer debug system is enabled')
 219 endif
 220
 221 warning_flags = [
 222   '-Wmissing-declarations',
 223   '-Wredundant-decls',
 224   '-Wwrite-strings',
 225   '-Wformat',
 226   '-Wformat-nonliteral',
 227   '-Wformat-security',
 228   '-Winit-self',
 229   '-Wmissing-include-dirs',
 230   '-Waddress',
 231   '-Wno-multichar',
 232   '-Wvla',
 233   '-Wpointer-arith',
 234   '-Waggregate-return',
 235   '-fno-strict-aliasing',
 236   # Symbol visibility
 237   '-fvisibility=hidden',
 238 ]
 239
 240 warning_c_flags = [
 241   '-Wmissing-prototypes',
 242   '-Wold-style-definition',
 243   '-Wdeclaration-after-statement',
 244   '-Wnested-externs'
 245 ]
 246
 247 foreach extra_arg : warning_flags
 248   if cc.has_argument (extra_arg)
 249     add_project_arguments([extra_arg], language: 'c')
 250   endif
 251   if have_cxx and cxx.has_argument (extra_arg)
 252     add_project_arguments([extra_arg], language: 'cpp')
 253   endif
 254 endforeach
 255
 256 foreach extra_arg : warning_c_flags
 257   if cc.has_argument (extra_arg)
 258     add_project_arguments([extra_arg], language: 'c')
 259   endif
 260 endforeach
 261
 262 # Define G_DISABLE_DEPRECATED for development versions
 263 if gst_version_is_dev
 264   message('Disabling deprecated GLib API')
 265   add_project_arguments('-DG_DISABLE_DEPRECATED', language: 'c')
 266 endif
 267
 268 cast_checks = get_option('gobject-cast-checks')
 269 if cast_checks.disabled() or (cast_checks.auto() and not gst_version_is_dev)
 270   message('Disabling GLib cast checks')
 271   add_project_arguments('-DG_DISABLE_CAST_CHECKS', language: 'c')
 272 endif
 273
 274 glib_asserts = get_option('glib-asserts')
 275 if glib_asserts.disabled() or (glib_asserts.auto() and not gst_version_is_dev)
 276   message('Disabling GLib asserts')
 277   add_project_arguments('-DG_DISABLE_ASSERT', language: 'c')
 278 endif
 279
 280 glib_checks = get_option('glib-checks')
 281 if glib_checks.disabled() or (glib_checks.auto() and not gst_version_is_dev)
 282   message('Disabling GLib checks')
 283   add_project_arguments('-DG_DISABLE_CHECKS', language: 'c')
 284 endif
 285
 286 presetdir = join_paths(get_option('datadir'), 'gstreamer-' + api_version, 'presets')
 287
 288 pkgconfig = import('pkgconfig')
 289 plugins_pkgconfig_install_dir = join_paths(plugins_install_dir, 'pkgconfig')
 290 if get_option('default_library') == 'shared'
 291   # If we don't build static plugins there is no need to generate pc files
 292   plugins_pkgconfig_install_dir = disabler()
 293 endif
 294
 295 gpl_allowed = get_option('gpl').allowed()
 296
 297 python3 = import('python').find_installation()
 298
 299 subdir('gst')
 300 subdir('ext')
 301 subdir('tests')
 302
 303 # xgettext is optional (on Windows for instance)
 304 if find_program('xgettext', required : get_option('nls')).found()
 305   cdata.set('ENABLE_NLS', 1)
 306   subdir('po')
 307 endif
 308 subdir('docs')
 309 subdir('scripts')
 310
 311 # Set release date
 312 if gst_version_nano == 0
 313   extract_release_date = find_program('scripts/extract-release-date-from-doap-file.py')
 314   run_result = run_command(extract_release_date, gst_version, files('gst-plugins-ugly.doap'), check: true)
 315   release_date = run_result.stdout().strip()
 316   cdata.set_quoted('GST_PACKAGE_RELEASE_DATETIME', release_date)
 317   message('Package release date: ' + release_date)
 318 endif
 319
 320 configure_file(output : 'config.h', configuration : cdata)
 321
 322 plugin_names = []
 323 foreach plugin: plugins
 324   if plugin.name().startswith('gst')
 325     plugin_names += [plugin.name().substring(3)]
 326   else
 327     plugin_names += [plugin.name()]
 328   endif
 329 endforeach
 330
 331 summary({
 332     'Plugins': plugin_names,
 333       '(A)GPL license allowed': gpl_allowed,
 334 }, list_sep: ', ')