subprojects/gst-plugins-ugly/meson.build

   1 project('gst-plugins-ugly', 'c',
   2   version : '1.21.0.1',
   3   meson_version : '>= 0.60',
   4   default_options : [ 'warning_level=1',
   5                       'buildtype=debugoptimized' ])
   6
   7 gst_version = meson.project_version()
   8 version_arr = gst_version.split('.')
   9 gst_version_major = version_arr[0].to_int()
  10 gst_version_minor = version_arr[1].to_int()
  11 gst_version_micro = version_arr[2].to_int()
  12  if version_arr.length() == 4
  13   gst_version_nano = version_arr[3].to_int()
  14 else
  15   gst_version_nano = 0
  16 endif
  17 gst_version_is_stable = gst_version_minor.is_even()
  18 gst_version_is_dev = gst_version_minor.is_odd() and gst_version_micro < 90
  19
  20 have_cxx = add_languages('cpp', native: false, required: false)
  21
  22 glib_req = '>= 2.62.0'
  23
  24 if gst_version_is_stable
  25   gst_req = '>= @0@.@1@.0'.format(gst_version_major, gst_version_minor)
  26 else
  27   gst_req = '>= ' + gst_version
  28 endif
  29
  30 api_version = '1.0'
  31
  32 static_build = get_option('default_library') == 'static'
  33 plugins_install_dir = join_paths(get_option('libdir'), 'gstreamer-1.0')
  34 plugins = []
  35
  36 cc = meson.get_compiler('c')
  37 if have_cxx
  38   cxx = meson.get_compiler('cpp')
  39 endif
  40
  41 if cc.get_id() == 'msvc'
  42   msvc_args = [
  43       # Ignore several spurious warnings for things gstreamer does very commonly
  44       # If a warning is completely useless and spammy, use '/wdXXXX' to suppress it
  45       # If a warning is harmless but hard to fix, use '/woXXXX' so it's shown once
  46       # NOTE: Only add warnings here if you are sure they're spurious
  47       '/wd4018', # implicit signed/unsigned conversion
  48       '/wd4146', # unary minus on unsigned (beware INT_MIN)
  49       '/wd4244', # lossy type conversion (e.g. double -> int)
  50       '/wd4305', # truncating type conversion (e.g. double -> float)
  51       cc.get_supported_arguments(['/utf-8']), # set the input encoding to utf-8
  52   ]
  53
  54   if gst_version_is_dev
  55     # Enable some warnings on MSVC to match GCC/Clang behaviour
  56     msvc_args += cc.get_supported_arguments([
  57       '/we4002', # too many actual parameters for macro 'identifier'
  58       '/we4003', # not enough actual parameters for macro 'identifier'
  59       '/we4013', # 'function' undefined; assuming extern returning int
  60       '/we4020', # 'function' : too many actual parameters
  61       '/we4027', # function declared without formal parameter list
  62       '/we4029', # declared formal parameter list different from definition
  63       '/we4033', # 'function' must return a value
  64       '/we4045', # 'array' : array bounds overflow
  65       '/we4047', # 'operator' : 'identifier1' differs in levels of indirection from 'identifier2'
  66       '/we4053', # one void operand for '?:'
  67       '/we4062', # enumerator 'identifier' in switch of enum 'enumeration' is not handled
  68       '/we4098', # 'function' : void function returning a value
  69       '/we4101', # 'identifier' : unreferenced local variable
  70       '/we4189', # 'identifier' : local variable is initialized but not referenced
  71     ])
  72   endif
  73   if have_cxx
  74     add_project_arguments(msvc_args, language: ['c', 'cpp'])
  75   else
  76     add_project_arguments(msvc_args, language: 'c')
  77   endif
  78   # Disable SAFESEH with MSVC for plugins and libs that use external deps that
  79   # are built with MinGW
  80   noseh_link_args = ['/SAFESEH:NO']
  81 else
  82   noseh_link_args = []
  83 endif
  84
  85 if cc.has_link_argument('-Wl,-Bsymbolic-functions')
  86   add_project_link_arguments('-Wl,-Bsymbolic-functions', language : 'c')
  87 endif
  88 if have_cxx and cxx.has_link_argument('-Wl,-Bsymbolic-functions')
  89   add_project_link_arguments('-Wl,-Bsymbolic-functions', language : 'cpp')
  90 endif
  91
  92 cdata = configuration_data()
  93 cdata.set('ENABLE_NLS', 1)
  94
  95 check_headers = [
  96   ['HAVE_DLFCN_H', 'dlfcn.h'],
  97   ['HAVE_INTTYPES_H', 'inttypes.h'],
  98   ['HAVE_MALLOC_H', 'malloc.h'],
  99   ['HAVE_MEMORY_H', 'memory.h'],
 100   ['HAVE_STDINT_H', 'stdint.h'],
 101   ['HAVE_STDLIB_H', 'stdlib.h'],
 102   ['HAVE_STRINGS_H', 'strings.h'],
 103   ['HAVE_STRING_H', 'string.h'],
 104   ['HAVE_SYS_STAT_H', 'sys/stat.h'],
 105   ['HAVE_SYS_TYPES_H', 'sys/types.h'],
 106   ['HAVE_UNISTD_H', 'unistd.h'],
 107   ['HAVE_WINSOCK2_H', 'winsock2.h'],
 108 ]
 109
 110 foreach h : check_headers
 111   if cc.has_header(h.get(1))
 112     cdata.set(h.get(0), 1)
 113   endif
 114 endforeach
 115
 116 check_functions = [
 117   ['HAVE_DCGETTEXT', 'dcgettext'], # FIXME: this looks unused
 118 ]
 119
 120 foreach f : check_functions
 121   if cc.has_function(f.get(1))
 122     cdata.set(f.get(0), 1)
 123   endif
 124 endforeach
 125
 126 cdata.set('SIZEOF_CHAR', cc.sizeof('char'))
 127 cdata.set('SIZEOF_INT', cc.sizeof('int'))
 128 cdata.set('SIZEOF_LONG', cc.sizeof('long'))
 129 cdata.set('SIZEOF_SHORT', cc.sizeof('short'))
 130 cdata.set('SIZEOF_VOIDP', cc.sizeof('void*'))
 131
 132 cdata.set_quoted('VERSION', gst_version)
 133 cdata.set_quoted('PACKAGE', 'gst-plugins-ugly')
 134 cdata.set_quoted('GST_LICENSE', 'LGPL')
 135 cdata.set_quoted('GETTEXT_PACKAGE', 'gst-plugins-ugly-1.0')
 136 cdata.set_quoted('LOCALEDIR', join_paths(get_option('prefix'), get_option('localedir')))
 137
 138 # GStreamer package name and origin url
 139 gst_package_name = get_option('package-name')
 140 if gst_package_name == ''
 141   if gst_version_nano == 0
 142     gst_package_name = 'GStreamer Ugly Plug-ins source release'
 143   elif gst_version_nano == 1
 144     gst_package_name = 'GStreamer Ugly Plug-ins git'
 145   else
 146     gst_package_name = 'GStreamer Ugly Plug-ins prerelease'
 147   endif
 148 endif
 149 cdata.set_quoted('GST_PACKAGE_NAME', gst_package_name)
 150 cdata.set_quoted('GST_PACKAGE_ORIGIN', get_option('package-origin'))
 151
 152 # Mandatory GST deps
 153 gst_dep = dependency('gstreamer-1.0', version : gst_req,
 154     fallback : ['gstreamer', 'gst_dep'])
 155 gstapp_dep = dependency('gstreamer-app-1.0', version : gst_req,
 156     fallback : ['gst-plugins-base', 'app_dep'])
 157 gstvideo_dep = dependency('gstreamer-video-1.0', version : gst_req,
 158     fallback : ['gst-plugins-base', 'video_dep'])
 159 gstpbutils_dep = dependency('gstreamer-pbutils-1.0', version : gst_req,
 160     fallback : ['gst-plugins-base', 'pbutils_dep'])
 161 gsttag_dep = dependency('gstreamer-tag-1.0', version : gst_req,
 162     fallback : ['gst-plugins-base', 'tag_dep'])
 163 gstfft_dep = dependency('gstreamer-fft-1.0', version : gst_req,
 164     fallback : ['gst-plugins-base', 'fft_dep'])
 165 gstaudio_dep = dependency('gstreamer-audio-1.0', version : gst_req,
 166     fallback : ['gst-plugins-base', 'audio_dep'])
 167 gstbase_dep = dependency('gstreamer-base-1.0', version : gst_req,
 168   fallback : ['gstreamer', 'gst_base_dep'])
 169 gstriff_dep = dependency('gstreamer-riff-1.0', version : gst_req,
 170     fallback : ['gst-plugins-base', 'riff_dep'])
 171 gstrtp_dep = dependency('gstreamer-rtp-1.0', version : gst_req,
 172     fallback : ['gst-plugins-base', 'rtp_dep'])
 173 gstnet_dep = dependency('gstreamer-net-1.0', version : gst_req,
 174   fallback : ['gstreamer', 'gst_net_dep'])
 175 gstsdp_dep = dependency('gstreamer-sdp-1.0', version : gst_req,
 176     fallback : ['gst-plugins-base', 'sdp_dep'])
 177 gstrtsp_dep = dependency('gstreamer-rtsp-1.0', version : gst_req,
 178     fallback : ['gst-plugins-base', 'rtsp_dep'])
 179 gstcheck_dep = dependency('gstreamer-check-1.0', version : gst_req,
 180     required : get_option('tests'),
 181     fallback : ['gstreamer', 'gst_check_dep'])
 182 gstcontroller_dep = dependency('gstreamer-controller-1.0', version : gst_req,
 183   fallback : ['gstreamer', 'gst_controller_dep'])
 184
 185 orc_dep = dependency('orc-0.4', version : '>= 0.4.16', required : get_option('orc'),
 186     fallback : ['orc', 'orc_dep'])
 187 if orc_dep.found()
 188   cdata.set('HAVE_ORC', 1) # used by a52dec for cpu detection
 189 else
 190   cdata.set('DISABLE_ORC', 1)
 191 endif
 192
 193 gmodule_dep = dependency('gmodule-no-export-2.0', version: glib_req)
 194
 195 if gmodule_dep.version().version_compare('< 2.67.4')
 196   cdata.set('g_memdup2(ptr,sz)', '(G_LIKELY(((guint64)(sz)) < G_MAXUINT)) ? g_memdup(ptr,sz) : (g_abort(),NULL)')
 197 endif
 198
 199 ugly_args = ['-DHAVE_CONFIG_H']
 200 configinc = include_directories('.')
 201 libsinc = include_directories('gst-libs')
 202
 203 # Disable compiler warnings for unused variables and args if gst debug system is disabled
 204 if gst_dep.type_name() == 'internal'
 205   gst_debug_disabled = not subproject('gstreamer').get_variable('gst_debug')
 206 else
 207   # We can't check that in the case of subprojects as we won't
 208   # be able to build against an internal dependency (which is not built yet)
 209   gst_debug_disabled = cc.has_header_symbol('gst/gstconfig.h', 'GST_DISABLE_GST_DEBUG', dependencies: gst_dep)
 210 endif
 211
 212 if gst_debug_disabled
 213   message('GStreamer debug system is disabled')
 214   if cc.has_argument('-Wno-unused')
 215     add_project_arguments('-Wno-unused', language: 'c')
 216   endif
 217   if have_cxx and cxx.has_argument ('-Wno-unused')
 218     add_project_arguments('-Wno-unused', language: 'cpp')
 219   endif
 220 else
 221   message('GStreamer debug system is enabled')
 222 endif
 223
 224 warning_flags = [
 225   '-Wmissing-declarations',
 226   '-Wredundant-decls',
 227   '-Wwrite-strings',
 228   '-Wformat',
 229   '-Wformat-nonliteral',
 230   '-Wformat-security',
 231   '-Winit-self',
 232   '-Wmissing-include-dirs',
 233   '-Waddress',
 234   '-Wno-multichar',
 235   '-Wvla',
 236   '-Wpointer-arith',
 237   '-Waggregate-return',
 238   '-fno-strict-aliasing',
 239   # Symbol visibility
 240   '-fvisibility=hidden',
 241 ]
 242
 243 warning_c_flags = [
 244   '-Wmissing-prototypes',
 245   '-Wold-style-definition',
 246   '-Wnested-externs'
 247 ]
 248
 249 foreach extra_arg : warning_flags
 250   if cc.has_argument (extra_arg)
 251     add_project_arguments([extra_arg], language: 'c')
 252   endif
 253   if have_cxx and cxx.has_argument (extra_arg)
 254     add_project_arguments([extra_arg], language: 'cpp')
 255   endif
 256 endforeach
 257
 258 foreach extra_arg : warning_c_flags
 259   if cc.has_argument (extra_arg)
 260     add_project_arguments([extra_arg], language: 'c')
 261   endif
 262 endforeach
 263
 264 # Define G_DISABLE_DEPRECATED for development versions
 265 if gst_version_is_dev
 266   message('Disabling deprecated GLib API')
 267   add_project_arguments('-DG_DISABLE_DEPRECATED', language: 'c')
 268 endif
 269
 270 cast_checks = get_option('gobject-cast-checks')
 271 if cast_checks.disabled() or (cast_checks.auto() and not gst_version_is_dev)
 272   message('Disabling GLib cast checks')
 273   add_project_arguments('-DG_DISABLE_CAST_CHECKS', language: 'c')
 274 endif
 275
 276 glib_asserts = get_option('glib-asserts')
 277 if glib_asserts.disabled() or (glib_asserts.auto() and not gst_version_is_dev)
 278   message('Disabling GLib asserts')
 279   add_project_arguments('-DG_DISABLE_ASSERT', language: 'c')
 280 endif
 281
 282 glib_checks = get_option('glib-checks')
 283 if glib_checks.disabled() or (glib_checks.auto() and not gst_version_is_dev)
 284   message('Disabling GLib checks')
 285   add_project_arguments('-DG_DISABLE_CHECKS', language: 'c')
 286 endif
 287
 288 presetdir = join_paths(get_option('datadir'), 'gstreamer-' + api_version, 'presets')
 289
 290 pkgconfig = import('pkgconfig')
 291 plugins_pkgconfig_install_dir = join_paths(plugins_install_dir, 'pkgconfig')
 292 if get_option('default_library') == 'shared'
 293   # If we don't build static plugins there is no need to generate pc files
 294   plugins_pkgconfig_install_dir = disabler()
 295 endif
 296
 297 gpl_allowed = get_option('gpl').allowed()
 298
 299 python3 = import('python').find_installation()
 300
 301 subdir('gst')
 302 subdir('ext')
 303 subdir('tests')
 304
 305 # xgettext is optional (on Windows for instance)
 306 if find_program('xgettext', required : get_option('nls')).found()
 307   subdir('po')
 308 endif
 309 subdir('docs')
 310 subdir('scripts')
 311
 312 # Set release date
 313 if gst_version_nano == 0
 314   extract_release_date = find_program('scripts/extract-release-date-from-doap-file.py')
 315   run_result = run_command(extract_release_date, gst_version, files('gst-plugins-ugly.doap'), check: true)
 316   release_date = run_result.stdout().strip()
 317   cdata.set_quoted('GST_PACKAGE_RELEASE_DATETIME', release_date)
 318   message('Package release date: ' + release_date)
 319 endif
 320
 321 configure_file(output : 'config.h', configuration : cdata)
 322
 323 plugin_names = []
 324 gst_plugins = []
 325 foreach plugin: plugins
 326   pkgconfig.generate(plugin, install_dir: plugins_pkgconfig_install_dir)
 327   dep = declare_dependency(link_with: plugin, variables: {'full_path': plugin.full_path()})
 328   meson.override_dependency(plugin.name(), dep)
 329   gst_plugins += [dep]
 330   if plugin.name().startswith('gst')
 331     plugin_names += [plugin.name().substring(3)]
 332   else
 333     plugin_names += [plugin.name()]
 334   endif
 335 endforeach
 336
 337 summary({
 338     'Plugins': plugin_names,
 339       '(A)GPL license allowed': gpl_allowed,
 340 }, list_sep: ', ')