subprojects/gst-plugins-ugly/meson.build

   1 project('gst-plugins-ugly', 'c',
   2   version : '1.19.90',
   3   meson_version : '>= 0.59',
   4   default_options : [ 'warning_level=1',
   5                       'buildtype=debugoptimized' ])
   6
   7 gst_version = meson.project_version()
   8 version_arr = gst_version.split('.')
   9 gst_version_major = version_arr[0].to_int()
  10 gst_version_minor = version_arr[1].to_int()
  11 gst_version_micro = version_arr[2].to_int()
  12  if version_arr.length() == 4
  13   gst_version_nano = version_arr[3].to_int()
  14 else
  15   gst_version_nano = 0
  16 endif
  17 gst_version_is_stable = gst_version_minor.is_even()
  18 gst_version_is_dev = gst_version_minor.is_odd() and gst_version_micro < 90
  19
  20 have_cxx = add_languages('cpp', native: false, required: false)
  21
  22 glib_req = '>= 2.56.0'
  23
  24 if gst_version_is_stable
  25   gst_req = '>= @0@.@1@.0'.format(gst_version_major, gst_version_minor)
  26 else
  27   gst_req = '>= ' + gst_version
  28 endif
  29
  30 api_version = '1.0'
  31
  32 plugins_install_dir = join_paths(get_option('libdir'), 'gstreamer-1.0')
  33 plugins = []
  34
  35 cc = meson.get_compiler('c')
  36 if have_cxx
  37   cxx = meson.get_compiler('cpp')
  38 endif
  39
  40 if cc.get_id() == 'msvc'
  41   msvc_args = [
  42       # Ignore several spurious warnings for things gstreamer does very commonly
  43       # If a warning is completely useless and spammy, use '/wdXXXX' to suppress it
  44       # If a warning is harmless but hard to fix, use '/woXXXX' so it's shown once
  45       # NOTE: Only add warnings here if you are sure they're spurious
  46       '/wd4018', # implicit signed/unsigned conversion
  47       '/wd4146', # unary minus on unsigned (beware INT_MIN)
  48       '/wd4244', # lossy type conversion (e.g. double -> int)
  49       '/wd4305', # truncating type conversion (e.g. double -> float)
  50       cc.get_supported_arguments(['/utf-8']), # set the input encoding to utf-8
  51
  52       # Enable some warnings on MSVC to match GCC/Clang behaviour
  53       '/w14062', # enumerator 'identifier' in switch of enum 'enumeration' is not handled
  54       '/w14101', # 'identifier' : unreferenced local variable
  55       '/w14189', # 'identifier' : local variable is initialized but not referenced
  56   ]
  57   if have_cxx
  58     add_project_arguments(msvc_args, language: ['c', 'cpp'])
  59   else
  60     add_project_arguments(msvc_args, language: 'c')
  61   endif
  62   # Disable SAFESEH with MSVC for plugins and libs that use external deps that
  63   # are built with MinGW
  64   noseh_link_args = ['/SAFESEH:NO']
  65 else
  66   noseh_link_args = []
  67 endif
  68
  69 if cc.has_link_argument('-Wl,-Bsymbolic-functions')
  70   add_project_link_arguments('-Wl,-Bsymbolic-functions', language : 'c')
  71 endif
  72 if have_cxx and cxx.has_link_argument('-Wl,-Bsymbolic-functions')
  73   add_project_link_arguments('-Wl,-Bsymbolic-functions', language : 'cpp')
  74 endif
  75
  76 cdata = configuration_data()
  77 check_headers = [
  78   ['HAVE_DLFCN_H', 'dlfcn.h'],
  79   ['HAVE_INTTYPES_H', 'inttypes.h'],
  80   ['HAVE_MALLOC_H', 'malloc.h'],
  81   ['HAVE_MEMORY_H', 'memory.h'],
  82   ['HAVE_STDINT_H', 'stdint.h'],
  83   ['HAVE_STDLIB_H', 'stdlib.h'],
  84   ['HAVE_STRINGS_H', 'strings.h'],
  85   ['HAVE_STRING_H', 'string.h'],
  86   ['HAVE_SYS_STAT_H', 'sys/stat.h'],
  87   ['HAVE_SYS_TYPES_H', 'sys/types.h'],
  88   ['HAVE_UNISTD_H', 'unistd.h'],
  89   ['HAVE_WINSOCK2_H', 'winsock2.h'],
  90 ]
  91
  92 foreach h : check_headers
  93   if cc.has_header(h.get(1))
  94     cdata.set(h.get(0), 1)
  95   endif
  96 endforeach
  97
  98 check_functions = [
  99   ['HAVE_DCGETTEXT', 'dcgettext'], # FIXME: this looks unused
 100 ]
 101
 102 foreach f : check_functions
 103   if cc.has_function(f.get(1))
 104     cdata.set(f.get(0), 1)
 105   endif
 106 endforeach
 107
 108 cdata.set('SIZEOF_CHAR', cc.sizeof('char'))
 109 cdata.set('SIZEOF_INT', cc.sizeof('int'))
 110 cdata.set('SIZEOF_LONG', cc.sizeof('long'))
 111 cdata.set('SIZEOF_SHORT', cc.sizeof('short'))
 112 cdata.set('SIZEOF_VOIDP', cc.sizeof('void*'))
 113
 114 cdata.set_quoted('VERSION', gst_version)
 115 cdata.set_quoted('PACKAGE', 'gst-plugins-ugly')
 116 cdata.set_quoted('GST_LICENSE', 'LGPL')
 117 cdata.set_quoted('GETTEXT_PACKAGE', 'gst-plugins-ugly-1.0')
 118 cdata.set_quoted('LOCALEDIR', join_paths(get_option('prefix'), get_option('localedir')))
 119
 120 # GStreamer package name and origin url
 121 gst_package_name = get_option('package-name')
 122 if gst_package_name == ''
 123   if gst_version_nano == 0
 124     gst_package_name = 'GStreamer Ugly Plug-ins source release'
 125   elif gst_version_nano == 1
 126     gst_package_name = 'GStreamer Ugly Plug-ins git'
 127   else
 128     gst_package_name = 'GStreamer Ugly Plug-ins prerelease'
 129   endif
 130 endif
 131 cdata.set_quoted('GST_PACKAGE_NAME', gst_package_name)
 132 cdata.set_quoted('GST_PACKAGE_ORIGIN', get_option('package-origin'))
 133
 134 # Mandatory GST deps
 135 gst_dep = dependency('gstreamer-1.0', version : gst_req,
 136     fallback : ['gstreamer', 'gst_dep'])
 137 gstapp_dep = dependency('gstreamer-app-1.0', version : gst_req,
 138     fallback : ['gst-plugins-base', 'app_dep'])
 139 gstvideo_dep = dependency('gstreamer-video-1.0', version : gst_req,
 140     fallback : ['gst-plugins-base', 'video_dep'])
 141 gstpbutils_dep = dependency('gstreamer-pbutils-1.0', version : gst_req,
 142     fallback : ['gst-plugins-base', 'pbutils_dep'])
 143 gsttag_dep = dependency('gstreamer-tag-1.0', version : gst_req,
 144     fallback : ['gst-plugins-base', 'tag_dep'])
 145 gstfft_dep = dependency('gstreamer-fft-1.0', version : gst_req,
 146     fallback : ['gst-plugins-base', 'fft_dep'])
 147 gstaudio_dep = dependency('gstreamer-audio-1.0', version : gst_req,
 148     fallback : ['gst-plugins-base', 'audio_dep'])
 149 gstbase_dep = dependency('gstreamer-base-1.0', version : gst_req,
 150   fallback : ['gstreamer', 'gst_base_dep'])
 151 gstriff_dep = dependency('gstreamer-riff-1.0', version : gst_req,
 152     fallback : ['gst-plugins-base', 'riff_dep'])
 153 gstrtp_dep = dependency('gstreamer-rtp-1.0', version : gst_req,
 154     fallback : ['gst-plugins-base', 'rtp_dep'])
 155 gstnet_dep = dependency('gstreamer-net-1.0', version : gst_req,
 156   fallback : ['gstreamer', 'gst_net_dep'])
 157 gstsdp_dep = dependency('gstreamer-sdp-1.0', version : gst_req,
 158     fallback : ['gst-plugins-base', 'sdp_dep'])
 159 gstrtsp_dep = dependency('gstreamer-rtsp-1.0', version : gst_req,
 160     fallback : ['gst-plugins-base', 'rtsp_dep'])
 161 gstcheck_dep = dependency('gstreamer-check-1.0', version : gst_req,
 162     required : get_option('tests'),
 163     fallback : ['gstreamer', 'gst_check_dep'])
 164 gstcontroller_dep = dependency('gstreamer-controller-1.0', version : gst_req,
 165   fallback : ['gstreamer', 'gst_controller_dep'])
 166
 167 orc_dep = dependency('orc-0.4', version : '>= 0.4.16', required : get_option('orc'),
 168     fallback : ['orc', 'orc_dep'])
 169 if orc_dep.found()
 170   cdata.set('HAVE_ORC', 1) # used by a52dec for cpu detection
 171 else
 172   cdata.set('DISABLE_ORC', 1)
 173 endif
 174
 175 gmodule_dep = dependency('gmodule-2.0', fallback : ['glib', 'libgmodule_dep'])
 176
 177 if gmodule_dep.version().version_compare('< 2.67.4')
 178   cdata.set('g_memdup2(ptr,sz)', '(G_LIKELY(((guint64)(sz)) < G_MAXUINT)) ? g_memdup(ptr,sz) : (g_abort(),NULL)')
 179 endif
 180
 181 ugly_args = ['-DHAVE_CONFIG_H']
 182 configinc = include_directories('.')
 183 libsinc = include_directories('gst-libs')
 184
 185 # Disable compiler warnings for unused variables and args if gst debug system is disabled
 186 if gst_dep.type_name() == 'internal'
 187   gst_debug_disabled = not subproject('gstreamer').get_variable('gst_debug')
 188 else
 189   # We can't check that in the case of subprojects as we won't
 190   # be able to build against an internal dependency (which is not built yet)
 191   gst_debug_disabled = cc.has_header_symbol('gst/gstconfig.h', 'GST_DISABLE_GST_DEBUG', dependencies: gst_dep)
 192 endif
 193
 194 if gst_debug_disabled
 195   message('GStreamer debug system is disabled')
 196   if cc.has_argument('-Wno-unused')
 197     add_project_arguments('-Wno-unused', language: 'c')
 198   endif
 199   if have_cxx and cxx.has_argument ('-Wno-unused')
 200     add_project_arguments('-Wno-unused', language: 'cpp')
 201   endif
 202 else
 203   message('GStreamer debug system is enabled')
 204 endif
 205
 206 warning_flags = [
 207   '-Wmissing-declarations',
 208   '-Wredundant-decls',
 209   '-Wwrite-strings',
 210   '-Wformat',
 211   '-Wformat-nonliteral',
 212   '-Wformat-security',
 213   '-Winit-self',
 214   '-Wmissing-include-dirs',
 215   '-Waddress',
 216   '-Wno-multichar',
 217   '-Wvla',
 218   '-Wpointer-arith',
 219   '-Waggregate-return',
 220   '-fno-strict-aliasing',
 221   # Symbol visibility
 222   '-fvisibility=hidden',
 223 ]
 224
 225 warning_c_flags = [
 226   '-Wmissing-prototypes',
 227   '-Wold-style-definition',
 228   '-Wdeclaration-after-statement',
 229   '-Wnested-externs'
 230 ]
 231
 232 foreach extra_arg : warning_flags
 233   if cc.has_argument (extra_arg)
 234     add_project_arguments([extra_arg], language: 'c')
 235   endif
 236   if have_cxx and cxx.has_argument (extra_arg)
 237     add_project_arguments([extra_arg], language: 'cpp')
 238   endif
 239 endforeach
 240
 241 foreach extra_arg : warning_c_flags
 242   if cc.has_argument (extra_arg)
 243     add_project_arguments([extra_arg], language: 'c')
 244   endif
 245 endforeach
 246
 247 # Define G_DISABLE_DEPRECATED for development versions
 248 if gst_version_is_dev
 249   message('Disabling deprecated GLib API')
 250   add_project_arguments('-DG_DISABLE_DEPRECATED', language: 'c')
 251 endif
 252
 253 cast_checks = get_option('gobject-cast-checks')
 254 if cast_checks.disabled() or (cast_checks.auto() and not gst_version_is_dev)
 255   message('Disabling GLib cast checks')
 256   add_project_arguments('-DG_DISABLE_CAST_CHECKS', language: 'c')
 257 endif
 258
 259 glib_asserts = get_option('glib-asserts')
 260 if glib_asserts.disabled() or (glib_asserts.auto() and not gst_version_is_dev)
 261   message('Disabling GLib asserts')
 262   add_project_arguments('-DG_DISABLE_ASSERT', language: 'c')
 263 endif
 264
 265 glib_checks = get_option('glib-checks')
 266 if glib_checks.disabled() or (glib_checks.auto() and not gst_version_is_dev)
 267   message('Disabling GLib checks')
 268   add_project_arguments('-DG_DISABLE_CHECKS', language: 'c')
 269 endif
 270
 271 presetdir = join_paths(get_option('datadir'), 'gstreamer-' + api_version, 'presets')
 272
 273 pkgconfig = import('pkgconfig')
 274 plugins_pkgconfig_install_dir = join_paths(plugins_install_dir, 'pkgconfig')
 275 if get_option('default_library') == 'shared'
 276   # If we don't build static plugins there is no need to generate pc files
 277   plugins_pkgconfig_install_dir = disabler()
 278 endif
 279
 280 gpl_allowed = get_option('gpl').allowed()
 281
 282 python3 = import('python').find_installation()
 283
 284 subdir('gst')
 285 subdir('ext')
 286 subdir('tests')
 287
 288 # xgettext is optional (on Windows for instance)
 289 if find_program('xgettext', required : get_option('nls')).found()
 290   cdata.set('ENABLE_NLS', 1)
 291   subdir('po')
 292 endif
 293 subdir('docs')
 294 subdir('scripts')
 295
 296 # Set release date
 297 if gst_version_nano == 0
 298   extract_release_date = find_program('scripts/extract-release-date-from-doap-file.py')
 299   run_result = run_command(extract_release_date, gst_version, files('gst-plugins-ugly.doap'), check: true)
 300   release_date = run_result.stdout().strip()
 301   cdata.set_quoted('GST_PACKAGE_RELEASE_DATETIME', release_date)
 302   message('Package release date: ' + release_date)
 303 endif
 304
 305 configure_file(output : 'config.h', configuration : cdata)
 306
 307 plugin_names = []
 308 foreach plugin: plugins
 309   if plugin.name().startswith('gst')
 310     plugin_names += [plugin.name().substring(3)]
 311   else
 312     plugin_names += [plugin.name()]
 313   endif
 314 endforeach
 315
 316 summary({
 317     'Plugins': plugin_names,
 318       '(A)GPL license allowed': gpl_allowed,
 319 }, list_sep: ', ')