subprojects/gst-plugins-ugly/ext/x264/meson.build

   1 x264_sources = [
   2   'gstx264enc.c',
   3   'gstencoderbitrateprofilemanager.c',
   4 ]
   5
   6 x264_dep = dependency('x264', required : get_option('x264'),
   7                       fallback: ['x264', 'libx264_dep'])
   8
   9 if x264_dep.found()
  10   x264_libraries = get_option('x264_libraries')
  11   x264_args = []
  12   if x264_libraries != ''
  13     x264_args += ['-DHAVE_X264_ADDITIONAL_LIBRARIES="@0@"'.format(x264_libraries)]
  14     extra_gmodule_dep = [gmodule_dep]
  15   else
  16     extra_gmodule_dep = []
  17   endif
  18
  19   gstx264 = library('gstx264',
  20     x264_sources,
  21     c_args : ugly_args + x264_args,
  22     include_directories : [configinc],
  23     dependencies : [gstbase_dep, gstvideo_dep, gstpbutils_dep, x264_dep] + extra_gmodule_dep,
  24     install : true,
  25     install_dir : plugins_install_dir,
  26   )
  27   pkgconfig.generate(gstx264, install_dir : plugins_pkgconfig_install_dir)
  28   plugins += [gstx264]
  29
  30   install_data(sources: 'GstX264Enc.prs', install_dir: presetdir)
  31 endif