subprojects/gst-plugins-base/tests/validate/meson.build

   1 gst_tester = find_program('gst-tester-@0@'.format(api_version), required: get_option('tests'))
   2 if not gst_tester.found()
   3     subdir_done()
   4 endif
   5
   6 tests = [
   7     'audiotestsrc/reverse',
   8     'videorate/10_to_1fps',
   9     'videorate/reverse.10_to_1fps',
  10     'videorate/reverse.10_to_30fps',
  11     'videorate/reverse.1_to_10fps',
  12     'videorate/reverse.30fps',
  13     'videorate/reverse.variable_to_10fps',
  14     'videorate/change_rate_while_playing',
  15     'videorate/change_rate_reverse_playback',
  16     'videorate/rate_0_5',
  17     'videorate/rate_0_5_with_decoder',
  18     'videorate/rate_2_0',
  19     'videorate/rate_2_0_with_decoder',
  20     'compositor/renogotiate_failing_unsupported_src_format',
  21     'giosrc/read-growing-file',
  22     'encodebin/set-encoder-properties',
  23     'uridecodebin/expose_raw_pad_caps',
  24 ]
  25
  26 env = environment()
  27 env.set('GST_PLUGIN_PATH_1_0', meson.global_build_root(), pluginsdirs)
  28 env.set('GST_PLUGIN_SYSTEM_PATH_1_0', '')
  29 env.set('GST_REGISTRY', '@0@/@1@.registry'.format(meson.current_build_dir(), 'validate'))
  30 env.set('GST_PLUGIN_SCANNER_1_0', gst_plugin_scanner_path)
  31 env.set('GST_PLUGIN_LOADING_WHITELIST', 'gstreamer', 'gst-validate',
  32     'gst-plugins-base@' + meson.project_build_root())
  33
  34 foreach t: tests
  35     test_dir_name = t.split('/')
  36     test_name = 'validate'
  37     foreach c: test_dir_name
  38         test_name += '.' + c
  39     endforeach
  40     test_env = env
  41     test_env.set('GST_VALIDATE_LOGSDIR', join_paths(meson.current_build_dir(), test_name))
  42     test_file = join_paths(meson.current_source_dir(), t + '.validatetest')
  43     test(test_name, gst_tester, args: [test_file, '--use-fakesinks'],
  44         env: test_env, timeout : 3 * 60, protocol: 'tap')
  45 endforeach