subprojects/gst-plugins-base/meson.build

   1 project('gst-plugins-base', 'c',
   2   version : '1.19.2.1',
   3   meson_version : '>= 0.59',
   4   default_options : [ 'warning_level=1',
   5                       'buildtype=debugoptimized' ])
   6
   7 gst_version = meson.project_version()
   8 version_arr = gst_version.split('.')
   9 gst_version_major = version_arr[0].to_int()
  10 gst_version_minor = version_arr[1].to_int()
  11 gst_version_micro = version_arr[2].to_int()
  12 if version_arr.length() == 4
  13   gst_version_nano = version_arr[3].to_int()
  14 else
  15   gst_version_nano = 0
  16 endif
  17 gst_version_is_dev = gst_version_minor % 2 == 1 and gst_version_micro < 90
  18
  19 host_system = host_machine.system()
  20
  21 have_cxx = add_languages('cpp', native: false, required: false)
  22
  23 if host_system in ['ios', 'darwin']
  24   have_objc = add_languages('objc', native: false)
  25 else
  26   have_objc = false
  27 endif
  28
  29 glib_req = '>= 2.56.0'
  30 orc_req = '>= 0.4.24'
  31 gst_req = '>= @0@.@1@.0'.format(gst_version_major, gst_version_minor)
  32
  33 api_version = '1.0'
  34 soversion = 0
  35 # maintaining compatibility with the previous libtool versioning
  36 # current = minor * 100 + micro
  37 curversion = gst_version_minor * 100 + gst_version_micro
  38 libversion = '@0@.@1@.0'.format(soversion, curversion)
  39 osxversion = curversion + 1
  40
  41 plugins_install_dir = join_paths(get_option('libdir'), 'gstreamer-1.0')
  42 static_build = get_option('default_library') == 'static'
  43 plugins = []
  44 libraries = []
  45
  46 cc = meson.get_compiler('c')
  47
  48 if cc.get_id() == 'msvc'
  49   msvc_args = [
  50       # Ignore several spurious warnings for things gstreamer does very commonly
  51       # If a warning is completely useless and spammy, use '/wdXXXX' to suppress it
  52       # If a warning is harmless but hard to fix, use '/woXXXX' so it's shown once
  53       # NOTE: Only add warnings here if you are sure they're spurious
  54       '/wd4018', # implicit signed/unsigned conversion
  55       '/wd4146', # unary minus on unsigned (beware INT_MIN)
  56       '/wd4244', # lossy type conversion (e.g. double -> int)
  57       '/wd4305', # truncating type conversion (e.g. double -> float)
  58       cc.get_supported_arguments(['/utf-8']), # set the input encoding to utf-8
  59
  60       # Enable some warnings on MSVC to match GCC/Clang behaviour
  61       '/w14062', # enumerator 'identifier' in switch of enum 'enumeration' is not handled
  62       '/w14101', # 'identifier' : unreferenced local variable
  63       '/w14189', # 'identifier' : local variable is initialized but not referenced
  64   ]
  65   add_project_arguments(msvc_args, language: ['c', 'cpp'])
  66   # Disable SAFESEH with MSVC for plugins and libs that use external deps that
  67   # are built with MinGW
  68   noseh_link_args = ['/SAFESEH:NO']
  69 else
  70   noseh_link_args = []
  71 endif
  72
  73 if cc.has_link_argument('-Wl,-Bsymbolic-functions')
  74   add_project_link_arguments('-Wl,-Bsymbolic-functions', language : 'c')
  75 endif
  76
  77 core_conf = configuration_data()
  78
  79 # Symbol visibility
  80 if cc.get_id() == 'msvc'
  81   export_define = '__declspec(dllexport) extern'
  82 elif cc.has_argument('-fvisibility=hidden')
  83   add_project_arguments('-fvisibility=hidden', language: 'c')
  84   if have_objc
  85     add_project_arguments('-fvisibility=hidden', language: 'objc')
  86   endif
  87   export_define = 'extern __attribute__ ((visibility ("default")))'
  88 else
  89   export_define = 'extern'
  90 endif
  91
  92 # Passing this through the command line would be too messy
  93 core_conf.set('GST_API_EXPORT', export_define)
  94
  95 # Disable strict aliasing
  96 if cc.has_argument('-fno-strict-aliasing')
  97   add_project_arguments('-fno-strict-aliasing', language: 'c')
  98 endif
  99
 100 # Define G_DISABLE_DEPRECATED for development versions
 101 if gst_version_is_dev
 102   message('Disabling deprecated GLib API')
 103   add_project_arguments('-DG_DISABLE_DEPRECATED', language: 'c')
 104 endif
 105
 106 cast_checks = get_option('gobject-cast-checks')
 107 if cast_checks.disabled() or (cast_checks.auto() and not gst_version_is_dev)
 108   message('Disabling GLib cast checks')
 109   add_project_arguments('-DG_DISABLE_CAST_CHECKS', language: 'c')
 110 endif
 111
 112 glib_asserts = get_option('glib-asserts')
 113 if glib_asserts.disabled() or (glib_asserts.auto() and not gst_version_is_dev)
 114   message('Disabling GLib asserts')
 115   add_project_arguments('-DG_DISABLE_ASSERT', language: 'c')
 116 endif
 117
 118 glib_checks = get_option('glib-checks')
 119 if glib_checks.disabled() or (glib_checks.auto() and not gst_version_is_dev)
 120   message('Disabling GLib checks')
 121   add_project_arguments('-DG_DISABLE_CHECKS', language: 'c')
 122 endif
 123
 124 # These are only needed/used by the ABI tests from core
 125 host_defines = [
 126   [ 'x86', 'HAVE_CPU_I386' ],
 127   [ 'x86_64', 'HAVE_CPU_X86_64' ],
 128   [ 'arm', 'HAVE_CPU_ARM' ],
 129   [ 'aarch64', 'HAVE_CPU_AARCH64' ],
 130   [ 'mips', 'HAVE_CPU_MIPS' ],
 131   [ 'powerpc', 'HAVE_CPU_PPC' ],
 132   [ 'powerpc64', 'HAVE_CPU_PPC64' ],
 133   [ 'alpha', 'HAVE_CPU_ALPHA' ],
 134   [ 'sparc', 'HAVE_CPU_SPARC' ],
 135   [ 'ia64', 'HAVE_CPU_IA64' ],
 136   [ 'hppa', 'HAVE_CPU_HPPA' ],
 137   [ 'm68k', 'HAVE_CPU_M68K' ],
 138   [ 's390', 'HAVE_CPU_S390' ],
 139 ]
 140 foreach h : host_defines
 141   if h.get(0) == host_machine.cpu_family()
 142     core_conf.set(h.get(1), 1)
 143   endif
 144 endforeach
 145 # FIXME: should really be called HOST_CPU or such
 146 core_conf.set_quoted('TARGET_CPU', host_machine.cpu())
 147
 148 check_headers = [
 149   ['HAVE_DLFCN_H', 'dlfcn.h'],
 150   ['HAVE_EMMINTRIN_H', 'emmintrin.h'],
 151   ['HAVE_INTTYPES_H', 'inttypes.h'],
 152   ['HAVE_MEMORY_H', 'memory.h'],
 153   ['HAVE_NETINET_IN_H', 'netinet/in.h'],
 154   ['HAVE_NETINET_TCP_H', 'netinet/tcp.h'],
 155   ['HAVE_PROCESS_H', 'process.h'],
 156   ['HAVE_SMMINTRIN_H', 'smmintrin.h'],
 157   ['HAVE_STDINT_H', 'stdint.h'],
 158   ['HAVE_STRINGS_H', 'strings.h'],
 159   ['HAVE_STRING_H', 'string.h'],
 160   ['HAVE_SYS_SOCKET_H', 'sys/socket.h'],
 161   ['HAVE_SYS_STAT_H', 'sys/stat.h'],
 162   ['HAVE_SYS_TYPES_H', 'sys/types.h'],
 163   ['HAVE_SYS_WAIT_H', 'sys/wait.h'],
 164   ['HAVE_UNISTD_H', 'unistd.h'],
 165   ['HAVE_WINSOCK2_H', 'winsock2.h'],
 166   ['HAVE_XMMINTRIN_H', 'xmmintrin.h'],
 167   ['HAVE_LINUX_DMA_BUF_H', 'linux/dma-buf.h'],
 168 ]
 169 foreach h : check_headers
 170   if cc.has_header(h.get(1))
 171     core_conf.set(h.get(0), 1)
 172   endif
 173 endforeach
 174
 175 check_functions = [
 176   ['HAVE_DCGETTEXT', 'dcgettext', '#include<libintl.h>'],
 177   ['HAVE_GMTIME_R', 'gmtime_r', '#include<time.h>'],
 178   ['HAVE_LOCALTIME_R', 'localtime_r', '#include<time.h>'],
 179   ['HAVE_LRINTF', 'lrintf', '#include<math.h>'],
 180   ['HAVE_MMAP', 'mmap', '#include<sys/mman.h>'],
 181   ['HAVE_LOG2', 'log2', '#include<math.h>'],
 182 ]
 183
 184 libm = cc.find_library('m', required : false)
 185 foreach f : check_functions
 186   if cc.has_function(f.get(1), prefix : f.get(2), dependencies : libm)
 187     core_conf.set(f.get(0), 1)
 188   endif
 189 endforeach
 190
 191 core_conf.set('SIZEOF_CHAR', cc.sizeof('char'))
 192 core_conf.set('SIZEOF_INT', cc.sizeof('int'))
 193 core_conf.set('SIZEOF_LONG', cc.sizeof('long'))
 194 core_conf.set('SIZEOF_SHORT', cc.sizeof('short'))
 195 core_conf.set('SIZEOF_VOIDP', cc.sizeof('void*'))
 196
 197 core_conf.set_quoted('GETTEXT_PACKAGE', 'gst-plugins-base-1.0')
 198 core_conf.set_quoted('LOCALEDIR', join_paths(get_option('prefix'), get_option('localedir')))
 199 core_conf.set_quoted('PACKAGE', 'gst-plugins-base')
 200 core_conf.set_quoted('VERSION', gst_version)
 201 core_conf.set_quoted('PACKAGE_VERSION', gst_version)
 202 core_conf.set_quoted('GST_API_VERSION', api_version)
 203 core_conf.set_quoted('GST_DATADIR', join_paths(get_option('prefix'), get_option('datadir')))
 204 core_conf.set_quoted('GST_LICENSE', 'LGPL')
 205
 206 install_plugins_helper = get_option('install_plugins_helper')
 207 if install_plugins_helper == ''
 208   install_plugins_helper = join_paths(get_option('prefix'),
 209                                       get_option('libexecdir'),
 210                                       'gst-install-plugins-helper')
 211 endif
 212 core_conf.set_quoted('GST_INSTALL_PLUGINS_HELPER', install_plugins_helper)
 213
 214 warning_flags = [
 215   '-Wmissing-declarations',
 216   '-Wredundant-decls',
 217   '-Wundef',
 218   '-Wwrite-strings',
 219   '-Wformat',
 220   '-Wformat-nonliteral',
 221   '-Wformat-security',
 222   '-Winit-self',
 223   '-Wmissing-include-dirs',
 224   '-Waddress',
 225   '-Wno-multichar',
 226   '-Wvla',
 227   '-Wpointer-arith',
 228 ]
 229
 230 warning_c_flags = [
 231   '-Wmissing-prototypes',
 232   '-Wdeclaration-after-statement',
 233 ]
 234
 235 warning_cxx_flags = [
 236   '-Waggregate-return',
 237 ]
 238
 239 if have_cxx
 240   cxx = meson.get_compiler('cpp')
 241   foreach extra_arg : warning_cxx_flags
 242     if cxx.has_argument (extra_arg)
 243       add_project_arguments([extra_arg], language: 'cpp')
 244     endif
 245   endforeach
 246 endif
 247
 248 foreach extra_arg : warning_flags
 249   if cc.has_argument (extra_arg)
 250     add_project_arguments([extra_arg], language: 'c')
 251   endif
 252   if have_cxx and cxx.has_argument (extra_arg)
 253     add_project_arguments([extra_arg], language: 'cpp')
 254   endif
 255 endforeach
 256
 257 foreach extra_arg : warning_c_flags
 258   if cc.has_argument (extra_arg)
 259     add_project_arguments([extra_arg], language: 'c')
 260   endif
 261 endforeach
 262
 263 # GStreamer package name and origin url
 264 gst_package_name = get_option('package-name')
 265 if gst_package_name == ''
 266   if gst_version_nano == 0
 267     gst_package_name = 'GStreamer Base Plug-ins source release'
 268   elif gst_version_nano == 1
 269     gst_package_name = 'GStreamer Base Plug-ins git'
 270   else
 271     gst_package_name = 'GStreamer Base Plug-ins prerelease'
 272   endif
 273 endif
 274 core_conf.set_quoted('GST_PACKAGE_NAME', gst_package_name)
 275 core_conf.set_quoted('GST_PACKAGE_ORIGIN', get_option('package-origin'))
 276
 277 # FIXME: These should be configure options
 278 core_conf.set_quoted('DEFAULT_VIDEOSINK', 'autovideosink')
 279 core_conf.set_quoted('DEFAULT_AUDIOSINK', 'autoaudiosink')
 280
 281 # Set whether the audioresampling method should be detected at runtime
 282 core_conf.set('AUDIORESAMPLE_FORMAT_' + get_option('audioresample_format').to_upper(), true)
 283
 284 gst_plugins_base_args = ['-DHAVE_CONFIG_H']
 285 if get_option('default_library') == 'static'
 286   gst_plugins_base_args += ['-DGST_STATIC_COMPILATION']
 287 endif
 288
 289 # X11 checks are for sys/ and tests/
 290 x11_dep = dependency('x11', required : get_option('x11'))
 291 # GLib checks are for the entire project
 292 # Almost everything that uses glib also uses gobject
 293 glib_deps = [dependency('glib-2.0', version : glib_req, fallback: ['glib', 'libglib_dep']),
 294              dependency('gobject-2.0', fallback: ['glib', 'libgobject_dep'])]
 295 # GIO is used by the GIO plugin, and by the TCP, SDP, and RTSP plugins
 296 gio_dep = dependency('gio-2.0', fallback: ['glib', 'libgio_dep'])
 297 giounix_dep = dependency('', required: false)
 298 if host_system != 'windows'
 299   giounix_dep = dependency('gio-unix-2.0', version : glib_req,
 300                            fallback: ['glib', 'libgiounix_dep'])
 301 endif
 302 gmodule_dep = dependency('gmodule-no-export-2.0',
 303                          fallback: ['glib', 'libgmodule_dep'])
 304
 305 # some of the examples can use gdk-pixbuf and GTK+3
 306 gdk_pixbuf_dep = dependency('gdk-pixbuf-2.0', required : get_option('examples'))
 307 gtk_dep = dependency('gtk+-3.0', version : '>= 3.10', required : get_option('examples'))
 308 # TODO: https://github.com/mesonbuild/meson/issues/3941
 309 if not get_option('x11').disabled()
 310   gtk_x11_dep = dependency('gtk+-x11-3.0', version : '>= 3.10', required : get_option('examples'))
 311 else
 312   gtk_x11_dep = dependency('', required : false)
 313 endif
 314 # gtk+ quartz backend is only available on macOS
 315 if host_system == 'darwin'
 316   gtk_quartz_dep = dependency('gtk+-quartz-3.0', version : '>= 3.10', required : get_option('examples'))
 317 else
 318   gtk_quartz_dep = dependency('', required : false)
 319 endif
 320
 321 core_conf.set('HAVE_X11', x11_dep.found())
 322 core_conf.set('HAVE_GIO_UNIX_2_0', giounix_dep.found())
 323
 324 if gio_dep.type_name() == 'pkgconfig'
 325     core_conf.set_quoted('GIO_MODULE_DIR',
 326         gio_dep.get_variable('giomoduledir'))
 327     core_conf.set_quoted('GIO_LIBDIR',
 328         gio_dep.get_variable('libdir'))
 329     core_conf.set_quoted('GIO_PREFIX',
 330         gio_dep.get_variable('prefix'))
 331 else
 332     core_conf.set_quoted('GIO_MODULE_DIR', join_paths(get_option('prefix'),
 333       get_option('libdir'), 'gio/modules'))
 334     core_conf.set_quoted('GIO_LIBDIR', join_paths(get_option('prefix'),
 335       get_option('libdir')))
 336     core_conf.set_quoted('GIO_PREFIX', join_paths(get_option('prefix')))
 337 endif
 338
 339 configinc = include_directories('.')
 340 libsinc = include_directories('gst-libs')
 341
 342 # To use the subproject make subprojects directory
 343 # and put gstreamer meson git there (symlinking is fine)
 344 gst_dep = dependency('gstreamer-1.0', version : gst_req,
 345   fallback : ['gstreamer', 'gst_dep'])
 346 gst_base_dep = dependency('gstreamer-base-1.0', version : gst_req,
 347   fallback : ['gstreamer', 'gst_base_dep'])
 348 gst_net_dep = dependency('gstreamer-net-1.0', version : gst_req,
 349   fallback : ['gstreamer', 'gst_net_dep'])
 350 gst_check_dep = dependency('gstreamer-check-1.0', version : gst_req,
 351   required : get_option('tests'),
 352   fallback : ['gstreamer', 'gst_check_dep'])
 353 gst_controller_dep = dependency('gstreamer-controller-1.0', version : gst_req,
 354   fallback : ['gstreamer', 'gst_controller_dep'])
 355
 356 have_orcc = false
 357 orcc_args = []
 358 orc_targets = []
 359 # Used by various libraries/elements that use Orc code
 360 orc_dep = dependency('orc-0.4', version : orc_req, required : get_option('orc'),
 361     fallback : ['orc', 'orc_dep'])
 362 orcc = find_program('orcc', required : get_option('orc'))
 363 if orc_dep.found() and orcc.found()
 364   have_orcc = true
 365   orcc_args = [orcc, '--include', 'glib.h']
 366   core_conf.set('HAVE_ORC', 1)
 367 else
 368   message('Orc Compiler not found or disabled, will use backup C code')
 369   core_conf.set('DISABLE_ORC', 1)
 370 endif
 371
 372 # Used to build SSE* things in audio-resampler
 373 sse_args = '-msse'
 374 sse2_args = '-msse2'
 375 sse41_args = '-msse4.1'
 376
 377 have_sse = cc.has_argument(sse_args)
 378 have_sse2 = cc.has_argument(sse2_args)
 379 have_sse41 = cc.has_argument(sse41_args)
 380
 381 if host_machine.cpu_family() == 'arm'
 382   if cc.compiles('''
 383 #include <arm_neon.h>
 384 int32x4_t testfunc(int16_t *a, int16_t *b) {
 385   asm volatile ("vmull.s16 q0, d0, d0" : : : "q0");
 386   return vmull_s16(vld1_s16(a), vld1_s16(b));
 387 }
 388 ''', name : 'NEON support')
 389     core_conf.set('HAVE_ARM_NEON', true)
 390   endif
 391 endif
 392
 393 if gst_dep.type_name() == 'internal'
 394     gst_proj = subproject('gstreamer')
 395
 396     if not gst_proj.get_variable('gst_debug')
 397         message('GStreamer debug system is disabled')
 398         add_project_arguments('-Wno-unused', language: 'c')
 399     else
 400         message('GStreamer debug system is enabled')
 401     endif
 402 else
 403     # We can't check that in the case of subprojects as we won't
 404     # be able to build against an internal dependency (which is not built yet)
 405     if not cc.compiles('''
 406 #include <gst/gstconfig.h>
 407 #ifdef GST_DISABLE_GST_DEBUG
 408 #error "debugging disabled, make compiler fail"
 409 #endif''' , dependencies: gst_dep)
 410         message('GStreamer debug system is disabled')
 411         add_project_arguments('-Wno-unused', language: 'c')
 412     else
 413         message('GStreamer debug system is enabled')
 414     endif
 415 endif
 416
 417 if cc.has_member('struct tcp_info', '__tcpi_reordering', prefix: '#include <netinet/tcp.h>')
 418   core_conf.set('HAVE_BSD_TCP_INFO', true)
 419 endif
 420
 421 if cc.has_member('struct tcp_info', 'tcpi_reordering', prefix: '#include <netinet/tcp.h>')
 422   core_conf.set('HAVE_LINUX_TCP_INFO', true)
 423 endif
 424
 425 gir = find_program('g-ir-scanner', required : get_option('introspection'))
 426 gnome = import('gnome')
 427 build_gir = gir.found() and (not meson.is_cross_build() or get_option('introspection').enabled())
 428 gir_init_section = [ '--add-init-section=extern void gst_init(gint*,gchar**);' + \
 429     'g_setenv("GST_REGISTRY_DISABLE", "yes", TRUE);' + \
 430     'g_setenv("GST_REGISTRY_1.0", "@0@", TRUE);'.format(meson.current_build_dir() + '/gir_empty_registry.reg') + \
 431     'g_setenv("GST_PLUGIN_PATH_1_0", "", TRUE);' + \
 432     'g_setenv("GST_PLUGIN_SYSTEM_PATH_1_0", "", TRUE);' + \
 433     'gst_init(NULL,NULL);', '--quiet']
 434
 435 pkgconfig = import('pkgconfig')
 436 plugins_pkgconfig_install_dir = join_paths(plugins_install_dir, 'pkgconfig')
 437 if get_option('default_library') == 'shared'
 438   # If we don't build static plugins there is no need to generate pc files
 439   plugins_pkgconfig_install_dir = disabler()
 440 endif
 441
 442 pkgconfig_variables = ['exec_prefix=${prefix}',
 443     'toolsdir=${exec_prefix}/bin',
 444     'pluginsdir=${libdir}/gstreamer-1.0',
 445     'datarootdir=${prefix}/share',
 446     'datadir=${datarootdir}',
 447     'girdir=${datadir}/gir-1.0',
 448     'typelibdir=${libdir}/girepository-1.0',
 449     'libexecdir=${prefix}/libexec']
 450 pkgconfig_subdirs = ['gstreamer-1.0']
 451
 452 meson_pkg_config_file_fixup_script = find_program('scripts/meson-pkg-config-file-fixup.py')
 453
 454 python3 = import('python').find_installation()
 455 subdir('gst-libs')
 456 subdir('gst')
 457 subdir('ext')
 458 subdir('sys')
 459 if not get_option('tools').disabled()
 460   subdir('tools')
 461 endif
 462 subdir('tests')
 463
 464 # xgettext is optional (on Windows for instance)
 465 if find_program('xgettext', required : get_option('nls')).found()
 466   core_conf.set('ENABLE_NLS', 1)
 467   subdir('po')
 468 endif
 469 subdir('docs')
 470 subdir('scripts')
 471
 472 base_libraries = ['allocators', 'app', 'audio', 'fft', 'pbutils', 'riff', 'rtp', 'rtsp', 'sdp', 'tag', 'video']
 473 if build_gstgl
 474   base_libraries += 'gl'
 475 endif
 476
 477 pkgconfig_plugins_base_libs_variables = [
 478   'libraries=' + ' '.join(base_libraries),
 479 ]
 480
 481 pkgconfig.generate(
 482   libraries : [gst_dep],
 483   variables : pkgconfig_variables + pkgconfig_plugins_base_libs_variables,
 484   uninstalled_variables : pkgconfig_plugins_base_libs_variables,
 485   subdirs : pkgconfig_subdirs,
 486   name : 'gstreamer-plugins-base-1.0',
 487   description : 'Streaming media framework, base plugins libraries',
 488 )
 489
 490 # Desperate times, desperate measures... fix up escaping of our variables
 491 run_command(meson_pkg_config_file_fixup_script,
 492   'gstreamer-plugins-base-1.0', 'libraries',
 493   check: true)
 494
 495 if have_orcc
 496   update_orc_dist_files = find_program('scripts/update-orc-dist-files.py')
 497
 498   orc_update_targets = []
 499   foreach t : orc_targets
 500     orc_name = t.get('name')
 501     orc_file = t.get('orc-source')
 502     header = t.get('header')
 503     source = t.get('source')
 504     # alias_target() only works with build targets, so can't use run_target() here
 505     orc_update_targets += [
 506       custom_target('update-orc-@0@'.format(orc_name),
 507         input: [header, source],
 508         command: [update_orc_dist_files, orc_file, header, source],
 509         output: ['@0@-dist.c'.format(orc_name)]) # not entirely true
 510     ]
 511   endforeach
 512
 513   if orc_update_targets.length() > 0
 514     update_orc_dist_target = alias_target('update-orc-dist', orc_update_targets)
 515   endif
 516 endif
 517
 518 # Set release date
 519 if gst_version_nano == 0
 520   extract_release_date = find_program('scripts/extract-release-date-from-doap-file.py')
 521   run_result = run_command(extract_release_date, gst_version, files('gst-plugins-base.doap'))
 522   if run_result.returncode() == 0
 523     release_date = run_result.stdout().strip()
 524     core_conf.set_quoted('GST_PACKAGE_RELEASE_DATETIME', release_date)
 525     message('Package release date: ' + release_date)
 526   else
 527     # Error out if our release can't be found in the .doap file
 528     error(run_result.stderr())
 529   endif
 530 endif
 531
 532 if gio_dep.version().version_compare('< 2.67.4')
 533   core_conf.set('g_memdup2(ptr,sz)', '(G_LIKELY(((guint64)(sz)) < G_MAXUINT)) ? g_memdup(ptr,sz) : (g_abort(),NULL)')
 534 endif
 535
 536 # Use core_conf after all subdirs have set values
 537 configure_file(output : 'config.h', configuration : core_conf)
 538
 539 plugin_names = []
 540 foreach plugin: plugins
 541   if plugin.name().startswith('gst')
 542     plugin_names += [plugin.name().substring(3)]
 543   else
 544     plugin_names += [plugin.name()]
 545   endif
 546 endforeach
 547
 548 summary({
 549     'Plugins': plugin_names,
 550 }, list_sep: ', ')