subprojects/gst-plugins-base/meson.build

   1 project('gst-plugins-base', 'c',
   2   version : '1.21.0.1',
   3   meson_version : '>= 0.59',
   4   default_options : [ 'warning_level=1',
   5                       'buildtype=debugoptimized' ])
   6
   7 gst_version = meson.project_version()
   8 version_arr = gst_version.split('.')
   9 gst_version_major = version_arr[0].to_int()
  10 gst_version_minor = version_arr[1].to_int()
  11 gst_version_micro = version_arr[2].to_int()
  12 if version_arr.length() == 4
  13   gst_version_nano = version_arr[3].to_int()
  14 else
  15   gst_version_nano = 0
  16 endif
  17 gst_version_is_stable = gst_version_minor.is_even()
  18 gst_version_is_dev = gst_version_minor % 2 == 1 and gst_version_micro < 90
  19
  20 host_system = host_machine.system()
  21
  22 have_cxx = add_languages('cpp', native: false, required: false)
  23
  24 if host_system in ['ios', 'darwin']
  25   have_objc = add_languages('objc', native: false)
  26 else
  27   have_objc = false
  28 endif
  29
  30 glib_req = '>= 2.56.0'
  31 orc_req = '>= 0.4.24'
  32
  33 if gst_version_is_stable
  34   gst_req = '>= @0@.@1@.0'.format(gst_version_major, gst_version_minor)
  35 else
  36   gst_req = '>= ' + gst_version
  37 endif
  38
  39 api_version = '1.0'
  40 soversion = 0
  41 # maintaining compatibility with the previous libtool versioning
  42 # current = minor * 100 + micro
  43 curversion = gst_version_minor * 100 + gst_version_micro
  44 libversion = '@0@.@1@.0'.format(soversion, curversion)
  45 osxversion = curversion + 1
  46
  47 plugins_install_dir = join_paths(get_option('libdir'), 'gstreamer-1.0')
  48 static_build = get_option('default_library') == 'static'
  49 plugins = []
  50 libraries = []
  51
  52 cc = meson.get_compiler('c')
  53
  54 if cc.get_id() == 'msvc'
  55   msvc_args = [
  56       # Ignore several spurious warnings for things gstreamer does very commonly
  57       # If a warning is completely useless and spammy, use '/wdXXXX' to suppress it
  58       # If a warning is harmless but hard to fix, use '/woXXXX' so it's shown once
  59       # NOTE: Only add warnings here if you are sure they're spurious
  60       '/wd4018', # implicit signed/unsigned conversion
  61       '/wd4146', # unary minus on unsigned (beware INT_MIN)
  62       '/wd4244', # lossy type conversion (e.g. double -> int)
  63       '/wd4305', # truncating type conversion (e.g. double -> float)
  64       cc.get_supported_arguments(['/utf-8']), # set the input encoding to utf-8
  65   ]
  66
  67   if gst_version_is_dev
  68     # Enable some warnings on MSVC to match GCC/Clang behaviour
  69     msvc_args += cc.get_supported_arguments([
  70       '/we4002', # too many actual parameters for macro 'identifier'
  71       '/we4003', # not enough actual parameters for macro 'identifier'
  72       '/we4013', # 'function' undefined; assuming extern returning int
  73       '/we4020', # 'function' : too many actual parameters
  74       '/we4027', # function declared without formal parameter list
  75       '/we4029', # declared formal parameter list different from definition
  76       '/we4033', # 'function' must return a value
  77       '/we4045', # 'array' : array bounds overflow
  78       '/we4047', # 'operator' : 'identifier1' differs in levels of indirection from 'identifier2'
  79       '/we4053', # one void operand for '?:'
  80       '/we4062', # enumerator 'identifier' in switch of enum 'enumeration' is not handled
  81       '/we4098', # 'function' : void function returning a value
  82       '/we4101', # 'identifier' : unreferenced local variable
  83       '/we4189', # 'identifier' : local variable is initialized but not referenced
  84     ])
  85   endif
  86   add_project_arguments(msvc_args, language: ['c', 'cpp'])
  87   # Disable SAFESEH with MSVC for plugins and libs that use external deps that
  88   # are built with MinGW
  89   noseh_link_args = ['/SAFESEH:NO']
  90 else
  91   noseh_link_args = []
  92 endif
  93
  94 if cc.has_link_argument('-Wl,-Bsymbolic-functions')
  95   add_project_link_arguments('-Wl,-Bsymbolic-functions', language : 'c')
  96 endif
  97
  98 core_conf = configuration_data()
  99
 100 # Symbol visibility
 101 if cc.get_id() == 'msvc'
 102   export_define = '__declspec(dllexport) extern'
 103 elif cc.has_argument('-fvisibility=hidden')
 104   add_project_arguments('-fvisibility=hidden', language: 'c')
 105   if have_objc
 106     add_project_arguments('-fvisibility=hidden', language: 'objc')
 107   endif
 108   export_define = 'extern __attribute__ ((visibility ("default")))'
 109 else
 110   export_define = 'extern'
 111 endif
 112
 113 # Passing this through the command line would be too messy
 114 core_conf.set('GST_API_EXPORT', export_define)
 115
 116 # Disable strict aliasing
 117 if cc.has_argument('-fno-strict-aliasing')
 118   add_project_arguments('-fno-strict-aliasing', language: 'c')
 119 endif
 120
 121 # Define G_DISABLE_DEPRECATED for development versions
 122 if gst_version_is_dev
 123   message('Disabling deprecated GLib API')
 124   add_project_arguments('-DG_DISABLE_DEPRECATED', language: 'c')
 125 endif
 126
 127 cast_checks = get_option('gobject-cast-checks')
 128 if cast_checks.disabled() or (cast_checks.auto() and not gst_version_is_dev)
 129   message('Disabling GLib cast checks')
 130   add_project_arguments('-DG_DISABLE_CAST_CHECKS', language: 'c')
 131 endif
 132
 133 glib_asserts = get_option('glib-asserts')
 134 if glib_asserts.disabled() or (glib_asserts.auto() and not gst_version_is_dev)
 135   message('Disabling GLib asserts')
 136   add_project_arguments('-DG_DISABLE_ASSERT', language: 'c')
 137 endif
 138
 139 glib_checks = get_option('glib-checks')
 140 if glib_checks.disabled() or (glib_checks.auto() and not gst_version_is_dev)
 141   message('Disabling GLib checks')
 142   add_project_arguments('-DG_DISABLE_CHECKS', language: 'c')
 143 endif
 144
 145 # These are only needed/used by the ABI tests from core
 146 host_defines = [
 147   [ 'x86', 'HAVE_CPU_I386' ],
 148   [ 'x86_64', 'HAVE_CPU_X86_64' ],
 149   [ 'arm', 'HAVE_CPU_ARM' ],
 150   [ 'aarch64', 'HAVE_CPU_AARCH64' ],
 151   [ 'mips', 'HAVE_CPU_MIPS' ],
 152   [ 'powerpc', 'HAVE_CPU_PPC' ],
 153   [ 'powerpc64', 'HAVE_CPU_PPC64' ],
 154   [ 'alpha', 'HAVE_CPU_ALPHA' ],
 155   [ 'sparc', 'HAVE_CPU_SPARC' ],
 156   [ 'ia64', 'HAVE_CPU_IA64' ],
 157   [ 'hppa', 'HAVE_CPU_HPPA' ],
 158   [ 'm68k', 'HAVE_CPU_M68K' ],
 159   [ 's390', 'HAVE_CPU_S390' ],
 160 ]
 161 foreach h : host_defines
 162   if h.get(0) == host_machine.cpu_family()
 163     core_conf.set(h.get(1), 1)
 164   endif
 165 endforeach
 166 # FIXME: should really be called HOST_CPU or such
 167 core_conf.set_quoted('TARGET_CPU', host_machine.cpu())
 168
 169 check_headers = [
 170   ['HAVE_DLFCN_H', 'dlfcn.h'],
 171   ['HAVE_EMMINTRIN_H', 'emmintrin.h'],
 172   ['HAVE_INTTYPES_H', 'inttypes.h'],
 173   ['HAVE_MEMORY_H', 'memory.h'],
 174   ['HAVE_NETINET_IN_H', 'netinet/in.h'],
 175   ['HAVE_NETINET_TCP_H', 'netinet/tcp.h'],
 176   ['HAVE_PROCESS_H', 'process.h'],
 177   ['HAVE_SMMINTRIN_H', 'smmintrin.h'],
 178   ['HAVE_STDINT_H', 'stdint.h'],
 179   ['HAVE_STRINGS_H', 'strings.h'],
 180   ['HAVE_STRING_H', 'string.h'],
 181   ['HAVE_SYS_SOCKET_H', 'sys/socket.h'],
 182   ['HAVE_SYS_STAT_H', 'sys/stat.h'],
 183   ['HAVE_SYS_TYPES_H', 'sys/types.h'],
 184   ['HAVE_SYS_WAIT_H', 'sys/wait.h'],
 185   ['HAVE_UNISTD_H', 'unistd.h'],
 186   ['HAVE_WINSOCK2_H', 'winsock2.h'],
 187   ['HAVE_XMMINTRIN_H', 'xmmintrin.h'],
 188   ['HAVE_LINUX_DMA_BUF_H', 'linux/dma-buf.h'],
 189 ]
 190 foreach h : check_headers
 191   if cc.has_header(h.get(1))
 192     core_conf.set(h.get(0), 1)
 193   endif
 194 endforeach
 195
 196 check_functions = [
 197   ['HAVE_DCGETTEXT', 'dcgettext', '#include<libintl.h>'],
 198   ['HAVE_GMTIME_R', 'gmtime_r', '#include<time.h>'],
 199   ['HAVE_LOCALTIME_R', 'localtime_r', '#include<time.h>'],
 200   ['HAVE_LRINTF', 'lrintf', '#include<math.h>'],
 201   ['HAVE_MMAP', 'mmap', '#include<sys/mman.h>'],
 202   ['HAVE_LOG2', 'log2', '#include<math.h>'],
 203 ]
 204
 205 libm = cc.find_library('m', required : false)
 206 foreach f : check_functions
 207   if cc.has_function(f.get(1), prefix : f.get(2), dependencies : libm)
 208     core_conf.set(f.get(0), 1)
 209   endif
 210 endforeach
 211
 212 core_conf.set('SIZEOF_CHAR', cc.sizeof('char'))
 213 core_conf.set('SIZEOF_INT', cc.sizeof('int'))
 214 core_conf.set('SIZEOF_LONG', cc.sizeof('long'))
 215 core_conf.set('SIZEOF_SHORT', cc.sizeof('short'))
 216 core_conf.set('SIZEOF_VOIDP', cc.sizeof('void*'))
 217
 218 core_conf.set_quoted('GETTEXT_PACKAGE', 'gst-plugins-base-1.0')
 219 core_conf.set_quoted('LOCALEDIR', join_paths(get_option('prefix'), get_option('localedir')))
 220 core_conf.set_quoted('PACKAGE', 'gst-plugins-base')
 221 core_conf.set_quoted('VERSION', gst_version)
 222 core_conf.set_quoted('PACKAGE_VERSION', gst_version)
 223 core_conf.set_quoted('GST_API_VERSION', api_version)
 224 core_conf.set_quoted('GST_DATADIR', join_paths(get_option('prefix'), get_option('datadir')))
 225 core_conf.set_quoted('GST_LICENSE', 'LGPL')
 226
 227 install_plugins_helper = get_option('install_plugins_helper')
 228 if install_plugins_helper == ''
 229   install_plugins_helper = join_paths(get_option('prefix'),
 230                                       get_option('libexecdir'),
 231                                       'gst-install-plugins-helper')
 232 endif
 233 core_conf.set_quoted('GST_INSTALL_PLUGINS_HELPER', install_plugins_helper)
 234
 235 warning_flags = [
 236   '-Wmissing-declarations',
 237   '-Wredundant-decls',
 238   '-Wundef',
 239   '-Wwrite-strings',
 240   '-Wformat',
 241   '-Wformat-nonliteral',
 242   '-Wformat-security',
 243   '-Winit-self',
 244   '-Wmissing-include-dirs',
 245   '-Waddress',
 246   '-Wno-multichar',
 247   '-Wvla',
 248   '-Wpointer-arith',
 249 ]
 250
 251 warning_c_flags = [
 252   '-Wmissing-prototypes',
 253   '-Wdeclaration-after-statement',
 254 ]
 255
 256 warning_cxx_flags = [
 257   '-Waggregate-return',
 258 ]
 259
 260 if have_cxx
 261   cxx = meson.get_compiler('cpp')
 262   foreach extra_arg : warning_cxx_flags
 263     if cxx.has_argument (extra_arg)
 264       add_project_arguments([extra_arg], language: 'cpp')
 265     endif
 266   endforeach
 267 endif
 268
 269 foreach extra_arg : warning_flags
 270   if cc.has_argument (extra_arg)
 271     add_project_arguments([extra_arg], language: 'c')
 272   endif
 273   if have_cxx and cxx.has_argument (extra_arg)
 274     add_project_arguments([extra_arg], language: 'cpp')
 275   endif
 276 endforeach
 277
 278 foreach extra_arg : warning_c_flags
 279   if cc.has_argument (extra_arg)
 280     add_project_arguments([extra_arg], language: 'c')
 281   endif
 282 endforeach
 283
 284 # GStreamer package name and origin url
 285 gst_package_name = get_option('package-name')
 286 if gst_package_name == ''
 287   if gst_version_nano == 0
 288     gst_package_name = 'GStreamer Base Plug-ins source release'
 289   elif gst_version_nano == 1
 290     gst_package_name = 'GStreamer Base Plug-ins git'
 291   else
 292     gst_package_name = 'GStreamer Base Plug-ins prerelease'
 293   endif
 294 endif
 295 core_conf.set_quoted('GST_PACKAGE_NAME', gst_package_name)
 296 core_conf.set_quoted('GST_PACKAGE_ORIGIN', get_option('package-origin'))
 297
 298 # FIXME: These should be configure options
 299 core_conf.set_quoted('DEFAULT_VIDEOSINK', 'autovideosink')
 300 core_conf.set_quoted('DEFAULT_AUDIOSINK', 'autoaudiosink')
 301
 302 # Set whether the audioresampling method should be detected at runtime
 303 core_conf.set('AUDIORESAMPLE_FORMAT_' + get_option('audioresample_format').to_upper(), true)
 304
 305 gst_plugins_base_args = ['-DHAVE_CONFIG_H']
 306 if get_option('default_library') == 'static'
 307   gst_plugins_base_args += ['-DGST_STATIC_COMPILATION']
 308 endif
 309
 310 # X11 checks are for sys/ and tests/
 311 x11_dep = dependency('x11', required : get_option('x11'))
 312 # GLib checks are for the entire project
 313 # Almost everything that uses glib also uses gobject
 314 glib_deps = [dependency('glib-2.0', version : glib_req, fallback: ['glib', 'libglib_dep']),
 315              dependency('gobject-2.0', fallback: ['glib', 'libgobject_dep'])]
 316 # GIO is used by the GIO plugin, and by the TCP, SDP, and RTSP plugins
 317 gio_dep = dependency('gio-2.0', fallback: ['glib', 'libgio_dep'])
 318 giounix_dep = dependency('', required: false)
 319 if host_system != 'windows'
 320   giounix_dep = dependency('gio-unix-2.0', version : glib_req,
 321                            fallback: ['glib', 'libgiounix_dep'])
 322 endif
 323 gmodule_dep = dependency('gmodule-no-export-2.0',
 324                          fallback: ['glib', 'libgmodule_dep'])
 325
 326 # some of the examples can use gdk-pixbuf and GTK+3
 327 gdk_pixbuf_dep = dependency('gdk-pixbuf-2.0', required : get_option('examples'))
 328 gtk_dep = dependency('gtk+-3.0', version : '>= 3.10', required : get_option('examples'))
 329 # TODO: https://github.com/mesonbuild/meson/issues/3941
 330 if not get_option('x11').disabled()
 331   gtk_x11_dep = dependency('gtk+-x11-3.0', version : '>= 3.10', required : get_option('examples'))
 332 else
 333   gtk_x11_dep = dependency('', required : false)
 334 endif
 335 # gtk+ quartz backend is only available on macOS
 336 if host_system == 'darwin'
 337   gtk_quartz_dep = dependency('gtk+-quartz-3.0', version : '>= 3.10', required : get_option('examples'))
 338 else
 339   gtk_quartz_dep = dependency('', required : false)
 340 endif
 341
 342 core_conf.set('HAVE_X11', x11_dep.found())
 343 core_conf.set('HAVE_GIO_UNIX_2_0', giounix_dep.found())
 344
 345 if gio_dep.type_name() == 'pkgconfig'
 346     core_conf.set_quoted('GIO_MODULE_DIR',
 347         gio_dep.get_variable('giomoduledir'))
 348     core_conf.set_quoted('GIO_LIBDIR',
 349         gio_dep.get_variable('libdir'))
 350     core_conf.set_quoted('GIO_PREFIX',
 351         gio_dep.get_variable('prefix'))
 352 else
 353     core_conf.set_quoted('GIO_MODULE_DIR', join_paths(get_option('prefix'),
 354       get_option('libdir'), 'gio/modules'))
 355     core_conf.set_quoted('GIO_LIBDIR', join_paths(get_option('prefix'),
 356       get_option('libdir')))
 357     core_conf.set_quoted('GIO_PREFIX', join_paths(get_option('prefix')))
 358 endif
 359
 360 configinc = include_directories('.')
 361 libsinc = include_directories('gst-libs')
 362
 363 # To use the subproject make subprojects directory
 364 # and put gstreamer meson git there (symlinking is fine)
 365 gst_dep = dependency('gstreamer-1.0', version : gst_req,
 366   fallback : ['gstreamer', 'gst_dep'])
 367 gst_base_dep = dependency('gstreamer-base-1.0', version : gst_req,
 368   fallback : ['gstreamer', 'gst_base_dep'])
 369 gst_net_dep = dependency('gstreamer-net-1.0', version : gst_req,
 370   fallback : ['gstreamer', 'gst_net_dep'])
 371 gst_check_dep = dependency('gstreamer-check-1.0', version : gst_req,
 372   required : get_option('tests'),
 373   fallback : ['gstreamer', 'gst_check_dep'])
 374 gst_controller_dep = dependency('gstreamer-controller-1.0', version : gst_req,
 375   fallback : ['gstreamer', 'gst_controller_dep'])
 376
 377 have_orcc = false
 378 orcc_args = []
 379 orc_targets = []
 380 # Used by various libraries/elements that use Orc code
 381 orc_dep = dependency('orc-0.4', version : orc_req, required : get_option('orc'),
 382     fallback : ['orc', 'orc_dep'])
 383 orcc = find_program('orcc', required : get_option('orc'))
 384 if orc_dep.found() and orcc.found()
 385   have_orcc = true
 386   orcc_args = [orcc, '--include', 'glib.h']
 387   core_conf.set('HAVE_ORC', 1)
 388 else
 389   message('Orc Compiler not found or disabled, will use backup C code')
 390   core_conf.set('DISABLE_ORC', 1)
 391 endif
 392
 393 # Used to build SSE* things in audio-resampler
 394 sse_args = '-msse'
 395 sse2_args = '-msse2'
 396 sse41_args = '-msse4.1'
 397
 398 have_sse = cc.has_argument(sse_args)
 399 have_sse2 = cc.has_argument(sse2_args)
 400 have_sse41 = cc.has_argument(sse41_args)
 401
 402 if host_machine.cpu_family() == 'arm'
 403   if cc.compiles('''
 404 #include <arm_neon.h>
 405 int32x4_t testfunc(int16_t *a, int16_t *b) {
 406   asm volatile ("vmull.s16 q0, d0, d0" : : : "q0");
 407   return vmull_s16(vld1_s16(a), vld1_s16(b));
 408 }
 409 ''', name : 'NEON support')
 410     core_conf.set('HAVE_ARM_NEON', true)
 411   endif
 412 endif
 413
 414 if gst_dep.type_name() == 'internal'
 415     gst_proj = subproject('gstreamer')
 416
 417     if not gst_proj.get_variable('gst_debug')
 418         message('GStreamer debug system is disabled')
 419         add_project_arguments('-Wno-unused', language: 'c')
 420     else
 421         message('GStreamer debug system is enabled')
 422     endif
 423 else
 424     # We can't check that in the case of subprojects as we won't
 425     # be able to build against an internal dependency (which is not built yet)
 426     if not cc.compiles('''
 427 #include <gst/gstconfig.h>
 428 #ifdef GST_DISABLE_GST_DEBUG
 429 #error "debugging disabled, make compiler fail"
 430 #endif''' , dependencies: gst_dep)
 431         message('GStreamer debug system is disabled')
 432         add_project_arguments('-Wno-unused', language: 'c')
 433     else
 434         message('GStreamer debug system is enabled')
 435     endif
 436 endif
 437
 438 if cc.has_member('struct tcp_info', '__tcpi_reordering', prefix: '#include <netinet/tcp.h>')
 439   core_conf.set('HAVE_BSD_TCP_INFO', true)
 440 endif
 441
 442 if cc.has_member('struct tcp_info', 'tcpi_reordering', prefix: '#include <netinet/tcp.h>')
 443   core_conf.set('HAVE_LINUX_TCP_INFO', true)
 444 endif
 445
 446 gir = find_program('g-ir-scanner', required : get_option('introspection'))
 447 gnome = import('gnome')
 448 build_gir = gir.found() and (not meson.is_cross_build() or get_option('introspection').enabled())
 449 gir_init_section = [ '--add-init-section=extern void gst_init(gint*,gchar**);' + \
 450     'g_setenv("GST_REGISTRY_DISABLE", "yes", TRUE);' + \
 451     'g_setenv("GST_REGISTRY_1.0", "@0@", TRUE);'.format(meson.current_build_dir() + '/gir_empty_registry.reg') + \
 452     'g_setenv("GST_PLUGIN_PATH_1_0", "", TRUE);' + \
 453     'g_setenv("GST_PLUGIN_SYSTEM_PATH_1_0", "", TRUE);' + \
 454     'gst_init(NULL,NULL);', '--quiet']
 455
 456 pkgconfig = import('pkgconfig')
 457 plugins_pkgconfig_install_dir = join_paths(plugins_install_dir, 'pkgconfig')
 458 if get_option('default_library') == 'shared'
 459   # If we don't build static plugins there is no need to generate pc files
 460   plugins_pkgconfig_install_dir = disabler()
 461 endif
 462
 463 pkgconfig_variables = ['exec_prefix=${prefix}',
 464     'toolsdir=${exec_prefix}/bin',
 465     'pluginsdir=${libdir}/gstreamer-1.0',
 466     'datarootdir=${prefix}/share',
 467     'datadir=${datarootdir}',
 468     'girdir=${datadir}/gir-1.0',
 469     'typelibdir=${libdir}/girepository-1.0',
 470     'libexecdir=${prefix}/libexec']
 471 pkgconfig_subdirs = ['gstreamer-1.0']
 472
 473 meson_pkg_config_file_fixup_script = find_program('scripts/meson-pkg-config-file-fixup.py')
 474
 475 python3 = import('python').find_installation()
 476 subdir('gst-libs')
 477 subdir('gst')
 478 subdir('ext')
 479 subdir('sys')
 480 if not get_option('tools').disabled()
 481   subdir('tools')
 482 endif
 483 subdir('tests')
 484
 485 # xgettext is optional (on Windows for instance)
 486 if find_program('xgettext', required : get_option('nls')).found()
 487   core_conf.set('ENABLE_NLS', 1)
 488   subdir('po')
 489 endif
 490 subdir('docs')
 491 subdir('scripts')
 492
 493 base_libraries = ['allocators', 'app', 'audio', 'fft', 'pbutils', 'riff', 'rtp', 'rtsp', 'sdp', 'tag', 'video']
 494 if build_gstgl
 495   core_conf.set('HAVE_GL', 1)
 496   base_libraries += 'gl'
 497 endif
 498
 499 pkgconfig_plugins_base_libs_variables = [
 500   'libraries=' + ' '.join(base_libraries),
 501 ]
 502
 503 pkgconfig.generate(
 504   libraries : [gst_dep],
 505   variables : pkgconfig_variables + pkgconfig_plugins_base_libs_variables,
 506   uninstalled_variables : pkgconfig_plugins_base_libs_variables,
 507   subdirs : pkgconfig_subdirs,
 508   name : 'gstreamer-plugins-base-1.0',
 509   description : 'Streaming media framework, base plugins libraries',
 510 )
 511
 512 # Desperate times, desperate measures... fix up escaping of our variables
 513 run_command(meson_pkg_config_file_fixup_script,
 514   'gstreamer-plugins-base-1.0', 'libraries',
 515   check: true)
 516
 517 if have_orcc
 518   update_orc_dist_files = find_program('scripts/update-orc-dist-files.py')
 519
 520   orc_update_targets = []
 521   foreach t : orc_targets
 522     orc_name = t.get('name')
 523     orc_file = t.get('orc-source')
 524     header = t.get('header')
 525     source = t.get('source')
 526     # alias_target() only works with build targets, so can't use run_target() here
 527     orc_update_targets += [
 528       custom_target('update-orc-@0@'.format(orc_name),
 529         input: [header, source],
 530         command: [update_orc_dist_files, orc_file, header, source],
 531         output: ['@0@-dist.c'.format(orc_name)]) # not entirely true
 532     ]
 533   endforeach
 534
 535   if orc_update_targets.length() > 0
 536     update_orc_dist_target = alias_target('update-orc-dist', orc_update_targets)
 537   endif
 538 endif
 539
 540 # Set release date
 541 if gst_version_nano == 0
 542   extract_release_date = find_program('scripts/extract-release-date-from-doap-file.py')
 543   run_result = run_command(extract_release_date, gst_version, files('gst-plugins-base.doap'), check: true)
 544   release_date = run_result.stdout().strip()
 545   core_conf.set_quoted('GST_PACKAGE_RELEASE_DATETIME', release_date)
 546   message('Package release date: ' + release_date)
 547 endif
 548
 549 if gio_dep.version().version_compare('< 2.67.4')
 550   core_conf.set('g_memdup2(ptr,sz)', '(G_LIKELY(((guint64)(sz)) < G_MAXUINT)) ? g_memdup(ptr,sz) : (g_abort(),NULL)')
 551 endif
 552
 553 # Use core_conf after all subdirs have set values
 554 configure_file(output : 'config.h', configuration : core_conf)
 555
 556 plugin_names = []
 557 foreach plugin: plugins
 558   if plugin.name().startswith('gst')
 559     plugin_names += [plugin.name().substring(3)]
 560   else
 561     plugin_names += [plugin.name()]
 562   endif
 563 endforeach
 564
 565 summary({
 566     'Plugins': plugin_names,
 567 }, list_sep: ', ')