subprojects/gst-plugins-base/meson.build

   1 project('gst-plugins-base', 'c',
   2   version : '1.21.0.1',
   3   meson_version : '>= 0.60',
   4   default_options : [ 'warning_level=1',
   5                       'buildtype=debugoptimized' ])
   6
   7 gst_version = meson.project_version()
   8 version_arr = gst_version.split('.')
   9 gst_version_major = version_arr[0].to_int()
  10 gst_version_minor = version_arr[1].to_int()
  11 gst_version_micro = version_arr[2].to_int()
  12 if version_arr.length() == 4
  13   gst_version_nano = version_arr[3].to_int()
  14 else
  15   gst_version_nano = 0
  16 endif
  17 gst_version_is_stable = gst_version_minor.is_even()
  18 gst_version_is_dev = gst_version_minor % 2 == 1 and gst_version_micro < 90
  19
  20 host_system = host_machine.system()
  21
  22 have_cxx = add_languages('cpp', native: false, required: false)
  23
  24 if host_system in ['ios', 'darwin']
  25   have_objc = add_languages('objc', native: false)
  26 else
  27   have_objc = false
  28 endif
  29
  30 glib_req = '>= 2.62.0'
  31 orc_req = '>= 0.4.24'
  32
  33 if gst_version_is_stable
  34   gst_req = '>= @0@.@1@.0'.format(gst_version_major, gst_version_minor)
  35 else
  36   gst_req = '>= ' + gst_version
  37 endif
  38
  39 api_version = '1.0'
  40 soversion = 0
  41 # maintaining compatibility with the previous libtool versioning
  42 # current = minor * 100 + micro
  43 curversion = gst_version_minor * 100 + gst_version_micro
  44 libversion = '@0@.@1@.0'.format(soversion, curversion)
  45 osxversion = curversion + 1
  46
  47 plugins_install_dir = join_paths(get_option('libdir'), 'gstreamer-1.0')
  48 static_build = get_option('default_library') == 'static'
  49 plugins = []
  50 libraries = []
  51
  52 cc = meson.get_compiler('c')
  53
  54 if cc.get_id() == 'msvc'
  55   msvc_args = [
  56       # Ignore several spurious warnings for things gstreamer does very commonly
  57       # If a warning is completely useless and spammy, use '/wdXXXX' to suppress it
  58       # If a warning is harmless but hard to fix, use '/woXXXX' so it's shown once
  59       # NOTE: Only add warnings here if you are sure they're spurious
  60       '/wd4018', # implicit signed/unsigned conversion
  61       '/wd4146', # unary minus on unsigned (beware INT_MIN)
  62       '/wd4244', # lossy type conversion (e.g. double -> int)
  63       '/wd4305', # truncating type conversion (e.g. double -> float)
  64       cc.get_supported_arguments(['/utf-8']), # set the input encoding to utf-8
  65   ]
  66
  67   if gst_version_is_dev
  68     # Enable some warnings on MSVC to match GCC/Clang behaviour
  69     msvc_args += cc.get_supported_arguments([
  70       '/we4002', # too many actual parameters for macro 'identifier'
  71       '/we4003', # not enough actual parameters for macro 'identifier'
  72       '/we4013', # 'function' undefined; assuming extern returning int
  73       '/we4020', # 'function' : too many actual parameters
  74       '/we4027', # function declared without formal parameter list
  75       '/we4029', # declared formal parameter list different from definition
  76       '/we4033', # 'function' must return a value
  77       '/we4045', # 'array' : array bounds overflow
  78       '/we4047', # 'operator' : 'identifier1' differs in levels of indirection from 'identifier2'
  79       '/we4053', # one void operand for '?:'
  80       '/we4062', # enumerator 'identifier' in switch of enum 'enumeration' is not handled
  81       '/we4098', # 'function' : void function returning a value
  82       '/we4101', # 'identifier' : unreferenced local variable
  83       '/we4189', # 'identifier' : local variable is initialized but not referenced
  84     ])
  85   endif
  86   add_project_arguments(msvc_args, language: ['c', 'cpp'])
  87   # Disable SAFESEH with MSVC for plugins and libs that use external deps that
  88   # are built with MinGW
  89   noseh_link_args = ['/SAFESEH:NO']
  90 else
  91   noseh_link_args = []
  92 endif
  93
  94 if cc.has_link_argument('-Wl,-Bsymbolic-functions')
  95   add_project_link_arguments('-Wl,-Bsymbolic-functions', language : 'c')
  96 endif
  97
  98 core_conf = configuration_data()
  99 core_conf.set('ENABLE_NLS', 1)
 100
 101 # Symbol visibility
 102 if cc.get_id() == 'msvc'
 103   export_define = '__declspec(dllexport) extern'
 104 elif cc.has_argument('-fvisibility=hidden')
 105   add_project_arguments('-fvisibility=hidden', language: 'c')
 106   if have_objc
 107     add_project_arguments('-fvisibility=hidden', language: 'objc')
 108   endif
 109   export_define = 'extern __attribute__ ((visibility ("default")))'
 110 else
 111   export_define = 'extern'
 112 endif
 113
 114 # Passing this through the command line would be too messy
 115 core_conf.set('GST_API_EXPORT', export_define)
 116
 117 # Disable strict aliasing
 118 if cc.has_argument('-fno-strict-aliasing')
 119   add_project_arguments('-fno-strict-aliasing', language: 'c')
 120 endif
 121
 122 # Define G_DISABLE_DEPRECATED for development versions
 123 if gst_version_is_dev
 124   message('Disabling deprecated GLib API')
 125   add_project_arguments('-DG_DISABLE_DEPRECATED', language: 'c')
 126 endif
 127
 128 cast_checks = get_option('gobject-cast-checks')
 129 if cast_checks.disabled() or (cast_checks.auto() and not gst_version_is_dev)
 130   message('Disabling GLib cast checks')
 131   add_project_arguments('-DG_DISABLE_CAST_CHECKS', language: 'c')
 132 endif
 133
 134 glib_asserts = get_option('glib-asserts')
 135 if glib_asserts.disabled() or (glib_asserts.auto() and not gst_version_is_dev)
 136   message('Disabling GLib asserts')
 137   add_project_arguments('-DG_DISABLE_ASSERT', language: 'c')
 138 endif
 139
 140 glib_checks = get_option('glib-checks')
 141 if glib_checks.disabled() or (glib_checks.auto() and not gst_version_is_dev)
 142   message('Disabling GLib checks')
 143   add_project_arguments('-DG_DISABLE_CHECKS', language: 'c')
 144 endif
 145
 146 # These are only needed/used by the ABI tests from core
 147 host_defines = [
 148   [ 'x86', 'HAVE_CPU_I386' ],
 149   [ 'x86_64', 'HAVE_CPU_X86_64' ],
 150   [ 'arm', 'HAVE_CPU_ARM' ],
 151   [ 'aarch64', 'HAVE_CPU_AARCH64' ],
 152   [ 'mips', 'HAVE_CPU_MIPS' ],
 153   [ 'powerpc', 'HAVE_CPU_PPC' ],
 154   [ 'powerpc64', 'HAVE_CPU_PPC64' ],
 155   [ 'alpha', 'HAVE_CPU_ALPHA' ],
 156   [ 'sparc', 'HAVE_CPU_SPARC' ],
 157   [ 'ia64', 'HAVE_CPU_IA64' ],
 158   [ 'hppa', 'HAVE_CPU_HPPA' ],
 159   [ 'm68k', 'HAVE_CPU_M68K' ],
 160   [ 's390', 'HAVE_CPU_S390' ],
 161 ]
 162 foreach h : host_defines
 163   if h.get(0) == host_machine.cpu_family()
 164     core_conf.set(h.get(1), 1)
 165   endif
 166 endforeach
 167 # FIXME: should really be called HOST_CPU or such
 168 core_conf.set_quoted('TARGET_CPU', host_machine.cpu())
 169
 170 check_headers = [
 171   ['HAVE_DLFCN_H', 'dlfcn.h'],
 172   ['HAVE_EMMINTRIN_H', 'emmintrin.h'],
 173   ['HAVE_INTTYPES_H', 'inttypes.h'],
 174   ['HAVE_MEMORY_H', 'memory.h'],
 175   ['HAVE_NETINET_IN_H', 'netinet/in.h'],
 176   ['HAVE_NETINET_TCP_H', 'netinet/tcp.h'],
 177   ['HAVE_PROCESS_H', 'process.h'],
 178   ['HAVE_SMMINTRIN_H', 'smmintrin.h'],
 179   ['HAVE_STDINT_H', 'stdint.h'],
 180   ['HAVE_STRINGS_H', 'strings.h'],
 181   ['HAVE_STRING_H', 'string.h'],
 182   ['HAVE_SYS_SOCKET_H', 'sys/socket.h'],
 183   ['HAVE_SYS_STAT_H', 'sys/stat.h'],
 184   ['HAVE_SYS_TYPES_H', 'sys/types.h'],
 185   ['HAVE_SYS_WAIT_H', 'sys/wait.h'],
 186   ['HAVE_UNISTD_H', 'unistd.h'],
 187   ['HAVE_WINSOCK2_H', 'winsock2.h'],
 188   ['HAVE_XMMINTRIN_H', 'xmmintrin.h'],
 189   ['HAVE_LINUX_DMA_BUF_H', 'linux/dma-buf.h'],
 190 ]
 191 foreach h : check_headers
 192   if cc.has_header(h.get(1))
 193     core_conf.set(h.get(0), 1)
 194   endif
 195 endforeach
 196
 197 check_functions = [
 198   ['HAVE_DCGETTEXT', 'dcgettext', '#include<libintl.h>'],
 199   ['HAVE_GMTIME_R', 'gmtime_r', '#include<time.h>'],
 200   ['HAVE_LOCALTIME_R', 'localtime_r', '#include<time.h>'],
 201   ['HAVE_LRINTF', 'lrintf', '#include<math.h>'],
 202   ['HAVE_MMAP', 'mmap', '#include<sys/mman.h>'],
 203   ['HAVE_LOG2', 'log2', '#include<math.h>'],
 204 ]
 205
 206 libm = cc.find_library('m', required : false)
 207 foreach f : check_functions
 208   if cc.has_function(f.get(1), prefix : f.get(2), dependencies : libm)
 209     core_conf.set(f.get(0), 1)
 210   endif
 211 endforeach
 212
 213 core_conf.set('SIZEOF_CHAR', cc.sizeof('char'))
 214 core_conf.set('SIZEOF_INT', cc.sizeof('int'))
 215 core_conf.set('SIZEOF_LONG', cc.sizeof('long'))
 216 core_conf.set('SIZEOF_SHORT', cc.sizeof('short'))
 217 core_conf.set('SIZEOF_VOIDP', cc.sizeof('void*'))
 218
 219 core_conf.set_quoted('GETTEXT_PACKAGE', 'gst-plugins-base-1.0')
 220 core_conf.set_quoted('LOCALEDIR', join_paths(get_option('prefix'), get_option('localedir')))
 221 core_conf.set_quoted('PACKAGE', 'gst-plugins-base')
 222 core_conf.set_quoted('VERSION', gst_version)
 223 core_conf.set_quoted('PACKAGE_VERSION', gst_version)
 224 core_conf.set_quoted('GST_API_VERSION', api_version)
 225 core_conf.set_quoted('GST_DATADIR', join_paths(get_option('prefix'), get_option('datadir')))
 226 core_conf.set_quoted('GST_LICENSE', 'LGPL')
 227
 228 install_plugins_helper = get_option('install_plugins_helper')
 229 if install_plugins_helper == ''
 230   install_plugins_helper = join_paths(get_option('prefix'),
 231                                       get_option('libexecdir'),
 232                                       'gst-install-plugins-helper')
 233 endif
 234 core_conf.set_quoted('GST_INSTALL_PLUGINS_HELPER', install_plugins_helper)
 235
 236 warning_flags = [
 237   '-Wmissing-declarations',
 238   '-Wredundant-decls',
 239   '-Wundef',
 240   '-Wwrite-strings',
 241   '-Wformat',
 242   '-Wformat-nonliteral',
 243   '-Wformat-security',
 244   '-Winit-self',
 245   '-Wmissing-include-dirs',
 246   '-Waddress',
 247   '-Wno-multichar',
 248   '-Wvla',
 249   '-Wpointer-arith',
 250 ]
 251
 252 warning_c_flags = [
 253   '-Wmissing-prototypes',
 254 ]
 255
 256 warning_cxx_flags = [
 257   '-Waggregate-return',
 258 ]
 259
 260 if have_cxx
 261   cxx = meson.get_compiler('cpp')
 262   foreach extra_arg : warning_cxx_flags
 263     if cxx.has_argument (extra_arg)
 264       add_project_arguments([extra_arg], language: 'cpp')
 265     endif
 266   endforeach
 267 endif
 268
 269 foreach extra_arg : warning_flags
 270   if cc.has_argument (extra_arg)
 271     add_project_arguments([extra_arg], language: 'c')
 272   endif
 273   if have_cxx and cxx.has_argument (extra_arg)
 274     add_project_arguments([extra_arg], language: 'cpp')
 275   endif
 276 endforeach
 277
 278 foreach extra_arg : warning_c_flags
 279   if cc.has_argument (extra_arg)
 280     add_project_arguments([extra_arg], language: 'c')
 281   endif
 282 endforeach
 283
 284 # GStreamer package name and origin url
 285 gst_package_name = get_option('package-name')
 286 if gst_package_name == ''
 287   if gst_version_nano == 0
 288     gst_package_name = 'GStreamer Base Plug-ins source release'
 289   elif gst_version_nano == 1
 290     gst_package_name = 'GStreamer Base Plug-ins git'
 291   else
 292     gst_package_name = 'GStreamer Base Plug-ins prerelease'
 293   endif
 294 endif
 295 core_conf.set_quoted('GST_PACKAGE_NAME', gst_package_name)
 296 core_conf.set_quoted('GST_PACKAGE_ORIGIN', get_option('package-origin'))
 297
 298 # FIXME: These should be configure options
 299 core_conf.set_quoted('DEFAULT_VIDEOSINK', 'autovideosink')
 300 core_conf.set_quoted('DEFAULT_AUDIOSINK', 'autoaudiosink')
 301
 302 # Set whether the audioresampling method should be detected at runtime
 303 core_conf.set('AUDIORESAMPLE_FORMAT_' + get_option('audioresample_format').to_upper(), true)
 304
 305 gst_plugins_base_args = ['-DHAVE_CONFIG_H']
 306 if get_option('default_library') == 'static'
 307   gst_plugins_base_args += ['-DGST_STATIC_COMPILATION']
 308 endif
 309
 310 # X11 checks are for sys/ and tests/
 311 x11_dep = dependency('x11', required : get_option('x11'))
 312 # GIO is used by the GIO plugin, and by the TCP, SDP, and RTSP plugins
 313 gio_dep = dependency('gio-2.0', version: glib_req)
 314 giounix_dep = dependency('', required: false)
 315 if host_system != 'windows'
 316   giounix_dep = dependency('gio-unix-2.0')
 317 endif
 318 gmodule_dep = dependency('gmodule-no-export-2.0')
 319
 320 # some of the examples can use gdk-pixbuf and GTK+3
 321 gdk_pixbuf_dep = dependency('gdk-pixbuf-2.0', required : get_option('examples'))
 322 gtk_dep = dependency('gtk+-3.0', version : '>= 3.10', required : get_option('examples'))
 323 # TODO: https://github.com/mesonbuild/meson/issues/3941
 324 if not get_option('x11').disabled()
 325   gtk_x11_dep = dependency('gtk+-x11-3.0', version : '>= 3.10', required : get_option('examples'))
 326 else
 327   gtk_x11_dep = dependency('', required : false)
 328 endif
 329 # gtk+ quartz backend is only available on macOS
 330 if host_system == 'darwin'
 331   gtk_quartz_dep = dependency('gtk+-quartz-3.0', version : '>= 3.10', required : get_option('examples'))
 332 else
 333   gtk_quartz_dep = dependency('', required : false)
 334 endif
 335
 336 core_conf.set('HAVE_X11', x11_dep.found())
 337 core_conf.set('HAVE_GIO_UNIX_2_0', giounix_dep.found())
 338
 339 if gio_dep.type_name() == 'pkgconfig'
 340     core_conf.set_quoted('GIO_MODULE_DIR',
 341         gio_dep.get_variable('giomoduledir'))
 342     core_conf.set_quoted('GIO_LIBDIR',
 343         gio_dep.get_variable('libdir'))
 344     core_conf.set_quoted('GIO_PREFIX',
 345         gio_dep.get_variable('prefix'))
 346 else
 347     core_conf.set_quoted('GIO_MODULE_DIR', join_paths(get_option('prefix'),
 348       get_option('libdir'), 'gio/modules'))
 349     core_conf.set_quoted('GIO_LIBDIR', join_paths(get_option('prefix'),
 350       get_option('libdir')))
 351     core_conf.set_quoted('GIO_PREFIX', join_paths(get_option('prefix')))
 352 endif
 353
 354 configinc = include_directories('.')
 355 libsinc = include_directories('gst-libs')
 356
 357 # To use the subproject make subprojects directory
 358 # and put gstreamer meson git there (symlinking is fine)
 359 gst_dep = dependency('gstreamer-1.0', version : gst_req,
 360   fallback : ['gstreamer', 'gst_dep'])
 361 gst_base_dep = dependency('gstreamer-base-1.0', version : gst_req,
 362   fallback : ['gstreamer', 'gst_base_dep'])
 363 gst_net_dep = dependency('gstreamer-net-1.0', version : gst_req,
 364   fallback : ['gstreamer', 'gst_net_dep'])
 365 gst_check_dep = dependency('gstreamer-check-1.0', version : gst_req,
 366   required : get_option('tests'),
 367   fallback : ['gstreamer', 'gst_check_dep'])
 368 gst_controller_dep = dependency('gstreamer-controller-1.0', version : gst_req,
 369   fallback : ['gstreamer', 'gst_controller_dep'])
 370
 371 have_orcc = false
 372 orcc_args = []
 373 orc_targets = []
 374 # Used by various libraries/elements that use Orc code
 375 orc_dep = dependency('orc-0.4', version : orc_req, required : get_option('orc'),
 376     fallback : ['orc', 'orc_dep'])
 377 orcc = find_program('orcc', required : get_option('orc'))
 378 if orc_dep.found() and orcc.found()
 379   have_orcc = true
 380   orcc_args = [orcc, '--include', 'glib.h']
 381   core_conf.set('HAVE_ORC', 1)
 382 else
 383   message('Orc Compiler not found or disabled, will use backup C code')
 384   core_conf.set('DISABLE_ORC', 1)
 385 endif
 386
 387 # Used to build SSE* things in audio-resampler
 388 sse_args = '-msse'
 389 sse2_args = '-msse2'
 390 sse41_args = '-msse4.1'
 391
 392 have_sse = cc.has_argument(sse_args)
 393 have_sse2 = cc.has_argument(sse2_args)
 394 have_sse41 = cc.has_argument(sse41_args)
 395
 396 if host_machine.cpu_family() == 'arm'
 397   if cc.compiles('''
 398 #include <arm_neon.h>
 399 int32x4_t testfunc(int16_t *a, int16_t *b) {
 400   asm volatile ("vmull.s16 q0, d0, d0" : : : "q0");
 401   return vmull_s16(vld1_s16(a), vld1_s16(b));
 402 }
 403 ''', name : 'NEON support')
 404     core_conf.set('HAVE_ARM_NEON', true)
 405   endif
 406 endif
 407
 408 if gst_dep.type_name() == 'internal'
 409     gst_proj = subproject('gstreamer')
 410
 411     if not gst_proj.get_variable('gst_debug')
 412         message('GStreamer debug system is disabled')
 413         add_project_arguments('-Wno-unused', language: 'c')
 414     else
 415         message('GStreamer debug system is enabled')
 416     endif
 417 else
 418     # We can't check that in the case of subprojects as we won't
 419     # be able to build against an internal dependency (which is not built yet)
 420     if not cc.compiles('''
 421 #include <gst/gstconfig.h>
 422 #ifdef GST_DISABLE_GST_DEBUG
 423 #error "debugging disabled, make compiler fail"
 424 #endif''' , dependencies: gst_dep)
 425         message('GStreamer debug system is disabled')
 426         add_project_arguments('-Wno-unused', language: 'c')
 427     else
 428         message('GStreamer debug system is enabled')
 429     endif
 430 endif
 431
 432 if cc.has_member('struct tcp_info', '__tcpi_reordering', prefix: '#include <netinet/tcp.h>')
 433   core_conf.set('HAVE_BSD_TCP_INFO', true)
 434 endif
 435
 436 if cc.has_member('struct tcp_info', 'tcpi_reordering', prefix: '#include <netinet/tcp.h>')
 437   core_conf.set('HAVE_LINUX_TCP_INFO', true)
 438 endif
 439
 440 gir = find_program('g-ir-scanner', required : get_option('introspection'))
 441 gnome = import('gnome')
 442 build_gir = gir.found() and (not meson.is_cross_build() or get_option('introspection').enabled())
 443 gir_init_section = [ '--add-init-section=extern void gst_init(gint*,gchar**);' + \
 444     'g_setenv("GST_REGISTRY_DISABLE", "yes", TRUE);' + \
 445     'g_setenv("GST_REGISTRY_1.0", "@0@", TRUE);'.format(meson.current_build_dir() + '/gir_empty_registry.reg') + \
 446     'g_setenv("GST_PLUGIN_PATH_1_0", "", TRUE);' + \
 447     'g_setenv("GST_PLUGIN_SYSTEM_PATH_1_0", "", TRUE);' + \
 448     'gst_init(NULL,NULL);', '--quiet']
 449
 450 pkgconfig = import('pkgconfig')
 451 plugins_pkgconfig_install_dir = join_paths(plugins_install_dir, 'pkgconfig')
 452 if get_option('default_library') == 'shared'
 453   # If we don't build static plugins there is no need to generate pc files
 454   plugins_pkgconfig_install_dir = disabler()
 455 endif
 456
 457 pkgconfig_variables = ['exec_prefix=${prefix}',
 458     'toolsdir=${exec_prefix}/bin',
 459     'pluginsdir=${libdir}/gstreamer-1.0',
 460     'datarootdir=${prefix}/share',
 461     'datadir=${datarootdir}',
 462     'girdir=${datadir}/gir-1.0',
 463     'typelibdir=${libdir}/girepository-1.0',
 464     'libexecdir=${prefix}/libexec']
 465 pkgconfig_subdirs = ['gstreamer-1.0']
 466
 467 meson_pkg_config_file_fixup_script = find_program('scripts/meson-pkg-config-file-fixup.py')
 468
 469 python3 = import('python').find_installation()
 470 subdir('gst-libs')
 471 subdir('gst')
 472 subdir('ext')
 473 subdir('sys')
 474 subdir('tools')
 475 subdir('tests')
 476
 477 # xgettext is optional (on Windows for instance)
 478 if find_program('xgettext', required : get_option('nls')).found()
 479   subdir('po')
 480 endif
 481 subdir('docs')
 482 subdir('scripts')
 483
 484 base_libraries = ['allocators', 'app', 'audio', 'fft', 'pbutils', 'riff', 'rtp', 'rtsp', 'sdp', 'tag', 'video']
 485 if build_gstgl
 486   core_conf.set('HAVE_GL', 1)
 487   base_libraries += 'gl'
 488 endif
 489
 490 pkgconfig_plugins_base_libs_variables = [
 491   'libraries=' + ' '.join(base_libraries),
 492 ]
 493
 494 pkgconfig.generate(
 495   libraries : [gst_dep],
 496   variables : pkgconfig_variables + pkgconfig_plugins_base_libs_variables,
 497   uninstalled_variables : pkgconfig_plugins_base_libs_variables,
 498   subdirs : pkgconfig_subdirs,
 499   name : 'gstreamer-plugins-base-1.0',
 500   description : 'Streaming media framework, base plugins libraries',
 501 )
 502
 503 # Desperate times, desperate measures... fix up escaping of our variables
 504 run_command(meson_pkg_config_file_fixup_script,
 505   'gstreamer-plugins-base-1.0', 'libraries',
 506   check: true)
 507
 508 if have_orcc
 509   update_orc_dist_files = find_program('scripts/update-orc-dist-files.py')
 510
 511   orc_update_targets = []
 512   foreach t : orc_targets
 513     orc_name = t.get('name')
 514     orc_file = t.get('orc-source')
 515     header = t.get('header')
 516     source = t.get('source')
 517     # alias_target() only works with build targets, so can't use run_target() here
 518     orc_update_targets += [
 519       custom_target('update-orc-@0@'.format(orc_name),
 520         input: [header, source],
 521         command: [update_orc_dist_files, orc_file, header, source],
 522         output: ['@0@-dist.c'.format(orc_name)]) # not entirely true
 523     ]
 524   endforeach
 525
 526   if orc_update_targets.length() > 0
 527     update_orc_dist_target = alias_target('update-orc-dist', orc_update_targets)
 528   endif
 529 endif
 530
 531 # Set release date
 532 if gst_version_nano == 0
 533   extract_release_date = find_program('scripts/extract-release-date-from-doap-file.py')
 534   run_result = run_command(extract_release_date, gst_version, files('gst-plugins-base.doap'), check: true)
 535   release_date = run_result.stdout().strip()
 536   core_conf.set_quoted('GST_PACKAGE_RELEASE_DATETIME', release_date)
 537   message('Package release date: ' + release_date)
 538 endif
 539
 540 if gio_dep.version().version_compare('< 2.67.4')
 541   core_conf.set('g_memdup2(ptr,sz)', '(G_LIKELY(((guint64)(sz)) < G_MAXUINT)) ? g_memdup(ptr,sz) : (g_abort(),NULL)')
 542 endif
 543
 544 # Use core_conf after all subdirs have set values
 545 configure_file(output : 'config.h', configuration : core_conf)
 546
 547 plugin_names = []
 548 foreach plugin: plugins
 549   if plugin.name().startswith('gst')
 550     plugin_names += [plugin.name().substring(3)]
 551   else
 552     plugin_names += [plugin.name()]
 553   endif
 554 endforeach
 555
 556 summary({
 557     'Plugins': plugin_names,
 558 }, list_sep: ', ')