subprojects/gst-plugins-base/ext/vorbis/meson.build

   1 vorbis_sources = [
   2   'gstvorbis.c',
   3   'gstvorbiselement.c',
   4   'gstvorbisdec.c',
   5   'gstvorbisdeclib.c',
   6   'gstvorbisenc.c',
   7   'gstvorbisparse.c',
   8   'gstvorbistag.c',
   9   'gstvorbiscommon.c',
  10 ]
  11
  12 vorbisidec_sources = [
  13   'gstivorbisdec.c',
  14   'gstvorbiselement.c',
  15   'gstvorbisdec.c',
  16   'gstvorbisdeclib.c',
  17   'gstvorbiscommon.c',
  18 ]
  19
  20 vorbis_dep = dependency('vorbis', version : '>= 1.3.1', allow_fallback: true, required : get_option('vorbis'))
  21 vorbisenc_dep = dependency('vorbisenc', version : '>= 1.3.1', allow_fallback: true, required : get_option('vorbis'))
  22 vorbisidec_dep = dependency('vorbisidec', allow_fallback: true, required : get_option('tremor'))
  23
  24 if vorbis_dep.found()
  25   vorbis_deps = [vorbis_dep]
  26   if vorbisenc_dep.found()
  27     vorbis_deps += vorbisenc_dep
  28   endif
  29   gstvorbis = library('gstvorbis',
  30     vorbis_sources,
  31     c_args : gst_plugins_base_args,
  32     link_args : noseh_link_args,
  33     include_directories: [configinc, libsinc],
  34     dependencies : vorbis_deps + glib_deps + [audio_dep, tag_dep, gst_dep, gst_base_dep],
  35     install : true,
  36     install_dir : plugins_install_dir,
  37   )
  38   pkgconfig.generate(gstvorbis, install_dir : plugins_pkgconfig_install_dir)
  39   plugins += [gstvorbis]
  40 endif
  41
  42 if vorbisidec_dep.found()
  43   # NOTE: This plugin is only useful if your device does not support hardware
  44   # floating point and needs integer ops for performance reasons.
  45   gstivorbisdec = library('gstivorbisdec',
  46     vorbisidec_sources,
  47     c_args : gst_plugins_base_args + ['-DTREMOR'],
  48     link_args : noseh_link_args,
  49     include_directories: [configinc, libsinc],
  50     dependencies : glib_deps + [vorbisidec_dep, audio_dep, tag_dep, gst_dep, gst_base_dep],
  51     install : true,
  52     install_dir : plugins_install_dir,
  53   )
  54   pkgconfig.generate(gstivorbisdec, install_dir : plugins_pkgconfig_install_dir)
  55   plugins += [gstivorbisdec]
  56 endif