subprojects/gst-plugins-bad/tests/check/meson.build

   1 have_registry = true # FIXME get_option('registry')
   2
   3 libparser = static_library('parser',
   4   'elements/parser.c',
   5   install : false,
   6   dependencies : [gst_dep, gstcheck_dep],
   7 )
   8
   9 libparser_dep = declare_dependency(link_with: libparser,
  10   sources: ['elements/parser.h'])
  11
  12 # FIXME: automagic
  13 exif_dep = dependency('libexif', version : '>= 0.6.16', required : false)
  14
  15 # Since nalutils API is internal, need to build it again
  16 nalutils_dep = gstcodecparsers_dep.partial_dependency (compile_args: true, includes: true)
  17
  18 enable_gst_play_tests = get_option('gst_play_tests')
  19 libsoup_dep = dependency('libsoup-2.4', version : '>=2.48', required : enable_gst_play_tests,
  20   fallback : ['libsoup', 'libsoup_dep'])
  21
  22 # name, condition when to skip the test and extra dependencies
  23 base_tests = [
  24   [['elements/aesenc.c'], not aes_dep.found(), [aes_dep]],
  25   [['elements/aesdec.c'], not aes_dep.found(), [aes_dep]],
  26   [['elements/aiffparse.c']],
  27   [['elements/asfmux.c']],
  28   [['elements/autoconvert.c']],
  29   [['elements/autovideoconvert.c']],
  30   [['elements/avwait.c']],
  31   [['elements/camerabin.c']],
  32   [['elements/ccconverter.c'], not closedcaption_dep.found(), [gstvideo_dep]],
  33   [['elements/cccombiner.c'], not closedcaption_dep.found(), ],
  34   [['elements/ccextractor.c'], not closedcaption_dep.found(), ],
  35   [['elements/cudaconvert.c'], false, [gstgl_dep, gmodule_dep]],
  36   [['elements/cudafilter.c'], false, [gstgl_dep, gmodule_dep]],
  37   [['elements/d3d11colorconvert.c'], host_machine.system() != 'windows', ],
  38   [['elements/gdpdepay.c']],
  39   [['elements/gdppay.c']],
  40   [['elements/h263parse.c'], false, [libparser_dep, gstcodecparsers_dep]],
  41   [['elements/h264parse.c'], false, [libparser_dep, gstcodecparsers_dep]],
  42   [['elements/h265parse.c'], false, [libparser_dep, gstcodecparsers_dep]],
  43   [['elements/hlsdemux_m3u8.c'], not hls_dep.found(), [hls_dep]],
  44   [['elements/id3mux.c']],
  45   [['elements/interlace.c']],
  46   [['elements/jpeg2000parse.c'], false, [libparser_dep, gstcodecparsers_dep]],
  47   [['elements/line21.c'], not closedcaption_dep.found(), ],
  48   [['elements/mfvideosrc.c'], host_machine.system() != 'windows', ],
  49   [['elements/mpegtsdemux.c'], false, [gstmpegts_dep]],
  50   [['elements/mpegtsmux.c'], false, [gstmpegts_dep]],
  51   [['elements/mpeg4videoparse.c'], false, [libparser_dep, gstcodecparsers_dep]],
  52   [['elements/mpegvideoparse.c'], false, [libparser_dep, gstcodecparsers_dep]],
  53   [['elements/msdkh264enc.c'], not have_msdk, [msdk_dep]],
  54   [['elements/mxfdemux.c']],
  55   [['elements/mxfmux.c']],
  56   [['elements/nvenc.c'], false, [gstgl_dep, gmodule_dep]],
  57   [['elements/nvdec.c'], not gstgl_dep.found(), [gstgl_dep, gmodule_dep]],
  58   [['elements/svthevcenc.c'], not svthevcenc_dep.found(), [svthevcenc_dep]],
  59    [['elements/openjpeg.c'], not openjpeg_dep.found(), [openjpeg_dep]],
  60   [['elements/pcapparse.c'], false, [libparser_dep]],
  61   [['elements/pnm.c']],
  62   [['elements/ristrtpext.c']],
  63   [['elements/rtponvifparse.c']],
  64   [['elements/rtponviftimestamp.c']],
  65   [['elements/rtpsrc.c']],
  66   [['elements/rtpsink.c']],
  67   [['elements/switchbin.c']],
  68   [['elements/videoframe-audiolevel.c']],
  69   [['elements/viewfinderbin.c']],
  70   [['elements/vp9parse.c'], false, [gstcodecparsers_dep]],
  71   [['elements/av1parse.c'], false, [gstcodecparsers_dep]],
  72   [['elements/wasapi.c'], host_machine.system() != 'windows', ],
  73   [['elements/wasapi2.c'], host_machine.system() != 'windows', ],
  74   [['libs/h264parser.c'], false, [gstcodecparsers_dep]],
  75   [['libs/h265parser.c'], false, [gstcodecparsers_dep]],
  76   [['libs/insertbin.c'], false, [gstinsertbin_dep]],
  77   [['libs/isoff.c'], false, [gstisoff_dep]],
  78   [['libs/nalutils.c', '../../gst-libs/gst/codecparsers/nalutils.c'], false, [nalutils_dep]],
  79   [['libs/mpegts.c'], false, [gstmpegts_dep]],
  80   [['libs/mpegvideoparser.c'], false, [gstcodecparsers_dep]],
  81   [['libs/planaraudioadapter.c'], false, [gstbadaudio_dep]],
  82   [['libs/play.c'], not enable_gst_play_tests, [gstplay_dep, libsoup_dep]],
  83   [['libs/vc1parser.c'], false, [gstcodecparsers_dep]],
  84   [['libs/vp8parser.c'], false, [gstcodecparsers_dep]],
  85   [['libs/vp9parser.c'], false, [gstcodecparsers_dep]],
  86   [['libs/av1parser.c'], false, [gstcodecparsers_dep]],
  87   [['libs/h264bitwriter.c'], false, [gstcodecparsers_dep]],
  88   [['libs/vkmemory.c'], not gstvulkan_dep.found(), [gstvulkan_dep]],
  89   [['elements/vkcolorconvert.c'], not gstvulkan_dep.found(), [gstvulkan_dep]],
  90   [['libs/vkwindow.c'], not gstvulkan_dep.found(), [gstvulkan_dep]],
  91   [['libs/vkdevice.c'], not gstvulkan_dep.found(), [gstvulkan_dep]],
  92   [['elements/vkdeviceprovider.c'], not gstvulkan_dep.found(), [gstvulkan_dep]],
  93   [['libs/vkcommandpool.c'], not gstvulkan_dep.found(), [gstvulkan_dep]],
  94   [['libs/vkimage.c'], not gstvulkan_dep.found(), [gstvulkan_dep]],
  95   [['libs/vkinstance.c'], not gstvulkan_dep.found(), [gstvulkan_dep]],
  96   [['libs/d3d11device.cpp'], not gstd3d11_dep.found(), [gstd3d11_dep]],
  97 ]
  98
  99 # FIXME: unistd dependency, unstable or not tested yet on windows
 100 if host_machine.system() != 'windows'
 101   base_tests += [
 102     [['elements/assrender.c'], not ass_dep.found(), [ass_dep]],
 103     [['elements/avtpaafpay.c'], not avtp_dep.found(), [avtp_dep]],
 104     [['elements/avtpaafdepay.c'], not avtp_dep.found(), [avtp_dep]],
 105     [['elements/avtpcrfbase.c'], not avtp_dep.found(), [avtp_dep]],
 106     [['elements/avtpcrfcheck.c'], not avtp_dep.found(), [avtp_dep], ['../../ext/avtp/gstavtpcrfutil.c']],
 107     [['elements/avtpcrfsync.c'], not avtp_dep.found(), [avtp_dep], ['../../ext/avtp/gstavtpcrfutil.c', '../../ext/avtp/gstavtpcrfbase.c']],
 108     [['elements/avtpcrfutil.c'], not avtp_dep.found(), [avtp_dep], ['../../ext/avtp/gstavtpcrfutil.c', '../../ext/avtp/gstavtpcrfbase.c']],
 109     [['elements/avtpcvfpay.c'], not avtp_dep.found(), [avtp_dep]],
 110     [['elements/avtpcvfdepay.c'], not avtp_dep.found(), [avtp_dep]],
 111     [['elements/avtpsink.c'], not avtp_dep.found(), [avtp_dep]],
 112     [['elements/avtpsrc.c'], not avtp_dep.found(), [avtp_dep]],
 113     [['elements/clockselect.c']],
 114     [['elements/curlhttpsink.c'], not curl_dep.found(), [curl_dep]],
 115     [['elements/curlhttpsrc.c'], not curl_dep.found(), [curl_dep, gio_dep]],
 116     [['elements/curlfilesink.c'],
 117         not curl_dep.found() or not cdata.has('HAVE_UNISTD_H'), [curl_dep]],
 118     [['elements/curlftpsink.c'], not curl_dep.found(), [curl_dep]],
 119     [['elements/curlsmtpsink.c'], not curl_dep.found(), [curl_dep]],
 120     [['elements/dash_mpd.c'], not xml2_dep.found(), [xml2_dep]],
 121     [['elements/dtls.c'], not libcrypto_dep.found(), [libcrypto_dep]],
 122     [['elements/faac.c'],
 123         not faac_dep.found() or not cc.has_header_symbol('faac.h', 'faacEncOpen') or not cdata.has('HAVE_UNISTD_H'),
 124         [faac_dep]],
 125     [['elements/faad.c'],
 126         not faad_dep.found() or not have_faad_2_7 or not cdata.has('HAVE_UNISTD_H'),
 127         [faad_dep]],
 128     [['elements/jifmux.c'],
 129         not exif_dep.found() or not cdata.has('HAVE_UNISTD_H'), [exif_dep]],
 130     [['elements/jpegparse.c'], not cdata.has('HAVE_UNISTD_H')],
 131     [['elements/kate.c'],
 132         not kate_dep.found() or not cdata.has('HAVE_UNISTD_H'), [kate_dep]],
 133     [['elements/netsim.c']],
 134     [['elements/shm.c'], not shm_enabled, shm_deps],
 135     [['elements/voaacenc.c'],
 136         not voaac_dep.found() or not cdata.has('HAVE_UNISTD_H'), [voaac_dep]],
 137     [['elements/webrtcbin.c'], not libnice_dep.found(), [gstwebrtc_dep]],
 138     [['elements/x265enc.c'], not x265_dep.found(), [x265_dep]],
 139     [['elements/zbar.c'], not zbar_dep.found(), [zbar_dep]],
 140     [['elements/zxing.c'], not zxing_dep.found(), [zxing_dep]],
 141   ]
 142 endif
 143
 144 # linux only tests
 145 if host_machine.system() == 'linux'
 146   base_tests += [
 147     [['elements/vapostproc.c'], not gstva_dep.found(), [gstva_dep]],
 148   ]
 149 endif
 150
 151 test_defines = [
 152   '-UG_DISABLE_ASSERT',
 153   '-UG_DISABLE_CAST_CHECKS',
 154   '-DGST_CHECK_TEST_ENVIRONMENT_BEACON="GST_STATE_IGNORE_ELEMENTS"',
 155   '-DGST_TEST_FILES_PATH="' + meson.current_source_dir() + '/../files"',
 156   '-DTEST_PATH="' + meson.current_build_dir() + '/media"',
 157   '-DDASH_MPD_DATADIR=' + meson.current_source_dir() + '/elements/dash_mpd_data',
 158   '-DGST_USE_UNSTABLE_API',
 159 ]
 160
 161 test_deps = [gst_dep, gstapp_dep, gstbase_dep,
 162              gstbasecamerabin_dep, gstphotography_dep,
 163              gstpbutils_dep, gstcontroller_dep, gstaudio_dep,
 164              gstvideo_dep, gstrtp_dep, gsturidownloader_dep,
 165              gstcheck_dep, gio_dep, gsttag_dep]
 166
 167 pluginsdirs = [  ]
 168
 169 if gst_dep.type_name() == 'pkgconfig'
 170   pbase = dependency('gstreamer-plugins-base-' + api_version)
 171
 172   pluginsdirs = [gst_dep.get_variable('pluginsdir'),
 173                  pbase.get_variable('pluginsdir')]
 174   gst_plugin_scanner_dir = gst_dep.get_variable('pluginscannerdir')
 175 else
 176   gst_plugin_scanner_dir = subproject('gstreamer').get_variable('gst_scanner_dir')
 177 endif
 178 gst_plugin_scanner_path = join_paths(gst_plugin_scanner_dir, 'gst-plugin-scanner')
 179
 180 extra_args = []
 181 # XXX: our MinGW 32bits toolchain complians when ComPtr is in use
 182 if host_system == 'windows' and cc.get_id() != 'msvc'
 183   mingw_args = cc.get_supported_arguments([
 184     '-Wno-redundant-decls',
 185   ])
 186
 187   extra_args += mingw_args
 188 endif
 189
 190 foreach t : base_tests
 191   fnames = t.get(0)
 192   test_name = fnames[0].split('.').get(0).underscorify()
 193   skip_test = false
 194   extra_deps = [ ]
 195
 196   if t.length() >= 3
 197     extra_deps = t.get(2)
 198   endif
 199
 200   if t.length() >= 2
 201     skip_test = t.get(1)
 202   endif
 203
 204   extra_sources = t.get(3, [ ])
 205
 206   if not skip_test
 207     exe = executable(test_name, fnames, extra_sources,
 208       include_directories : [configinc],
 209       c_args : gst_plugins_bad_args + test_defines + extra_args,
 210       cpp_args : gst_plugins_bad_args + test_defines + extra_args,
 211       dependencies : [libm] + test_deps + extra_deps,
 212     )
 213
 214     env = environment()
 215     env.set('GST_PLUGIN_SYSTEM_PATH_1_0', '')
 216     env.set('CK_DEFAULT_TIMEOUT', '20')
 217     env.set('GST_STATE_IGNORE_ELEMENTS', '')
 218     env.set('GST_PLUGIN_PATH_1_0', [meson.global_build_root()] + pluginsdirs)
 219     env.set('GST_REGISTRY', join_paths(meson.current_build_dir(), '@0@.registry'.format(test_name)))
 220     env.set('GST_PLUGIN_LOADING_WHITELIST', 'gstreamer', 'gst-plugins-base',
 221       'gst-plugins-good', 'gst-plugins-ugly','gst-libav', 'libnice',
 222       'gst-plugins-bad@' + meson.project_build_root())
 223     env.set('GST_PLUGIN_SCANNER_1_0', gst_plugin_scanner_path)
 224     test(test_name, exe, env: env, timeout: 3 * 60)
 225   endif
 226 endforeach
 227
 228 # orc tests
 229 orc_tests = [
 230   ['orc_bayer', files('../../gst/bayer/gstbayerorc.orc')],
 231 ]
 232
 233 orc_test_dep = dependency('', required : false)
 234 if have_orcc
 235   # FIXME: there should really just be a separate orc-test-0.4.pc file for this
 236   if orc_dep.type_name() == 'pkgconfig'
 237     orc_test_dep = cc.find_library('orc-test-0.4', required : false)
 238   else
 239     orc_test_dep = dependency('', fallback: ['orc', 'orc_test_dep'], required: false)
 240   endif
 241 endif
 242
 243 if have_orcc and orc_test_dep.found()
 244   foreach t : orc_tests
 245     tname = t[0]
 246     torcfile = t[1]
 247     tcfilename = '@0@.c'.format(tname)
 248     test_c = custom_target(tcfilename,
 249       output: tcfilename,
 250       input: torcfile,
 251       command: [orcc, '--include', 'stdint.h', '--test', '-o', '@OUTPUT@', '@INPUT@'])
 252     test_exe = executable(tname, test_c, dependencies: [orc_dep, orc_test_dep])
 253     test(tname, test_exe)
 254   endforeach
 255 endif
 256
 257 if enable_gst_play_tests
 258   subdir ('media')
 259 endif