subprojects/gst-plugins-bad/gst-libs/gst/play/meson.build

   1 gstplay_sources = [
   2   'gstplay.c',
   3   'gstplay-signal-adapter.c',
   4   'gstplay-video-renderer.c',
   5   'gstplay-media-info.c',
   6   'gstplay-video-overlay-video-renderer.c',
   7   'gstplay-visualization.c',
   8 ]
   9
  10 gstplay_headers = [
  11   'play.h',
  12   'play-prelude.h',
  13   'gstplay.h',
  14   'gstplay-types.h',
  15   'gstplay-signal-adapter.h',
  16   'gstplay-video-renderer.h',
  17   'gstplay-media-info.h',
  18   'gstplay-video-overlay-video-renderer.h',
  19   'gstplay-visualization.h',
  20 ]
  21
  22 install_headers(gstplay_headers, subdir : 'gstreamer-' + api_version + '/gst/play/')
  23
  24 gstplay = library('gstplay-' + api_version,
  25   gstplay_sources,
  26   c_args : gst_plugins_bad_args + ['-DBUILDING_GST_PLAY'],
  27   include_directories : [configinc, libsinc],
  28   version : libversion,
  29   soversion : soversion,
  30   darwin_versions : osxversion,
  31   install : true,
  32   dependencies : [gstbase_dep, gstvideo_dep, gstaudio_dep,
  33                   gsttag_dep, gstpbutils_dep],
  34 )
  35
  36 pkgconfig.generate(gstplay,
  37   libraries : [gst_dep, gstvideo_dep],
  38   variables : pkgconfig_variables,
  39   subdirs : pkgconfig_subdirs,
  40   name : 'gstreamer-play-1.0',
  41   description : 'GStreamer Player convenience library',
  42 )
  43
  44 gen_sources = []
  45 if build_gir
  46   play_gir = gnome.generate_gir(gstplay,
  47     sources : gstplay_sources + gstplay_headers,
  48     namespace : 'GstPlay',
  49     nsversion : api_version,
  50     identifier_prefix : 'Gst',
  51     symbol_prefix : 'gst',
  52     export_packages : 'gstreamer-play-1.0',
  53     includes : ['Gst-1.0', 'GstPbutils-1.0', 'GstBase-1.0', 'GstVideo-1.0',
  54       'GstAudio-1.0', 'GstTag-1.0'],
  55     install : true,
  56     extra_args : gir_init_section + ['-DGST_USE_UNSTABLE_API'] + ['--c-include=gst/play/play.h'],
  57     dependencies : [gstbase_dep, gstvideo_dep, gstaudio_dep,
  58                   gsttag_dep, gstpbutils_dep]
  59   )
  60   gen_sources += play_gir
  61 endif
  62
  63 gstplay_dep = declare_dependency(link_with : gstplay,
  64   include_directories : [libsinc],
  65   sources: gen_sources,
  66   dependencies : [gstbase_dep, gstvideo_dep, gstaudio_dep,
  67                   gsttag_dep, gstpbutils_dep])
  68
  69 meson.override_dependency('gstreamer-play-1.0', gstplay_dep)