subprojects/gst-plugins-bad/gst-libs/gst/mpegts/meson.build

   1 mpegts_sources = files(
   2   'mpegts.c',
   3   'gstmpegtssection.c',
   4   'gstmpegtsdescriptor.c',
   5   'gst-dvb-descriptor.c',
   6   'gst-dvb-section.c',
   7   'gst-atsc-section.c',
   8   'gst-scte-section.c',
   9 )
  10
  11 mpegts_headers = files(
  12   'gstmpegtssection.h',
  13   'gst-atsc-section.h',
  14   'gst-dvb-section.h',
  15   'gst-scte-section.h',
  16   'gst-hdmv-section.h',
  17   'gstmpegtsdescriptor.h',
  18   'gst-atsc-descriptor.h',
  19   'gst-dvb-descriptor.h',
  20   'gst-isdb-descriptor.h',
  21   'mpegts-prelude.h',
  22   'mpegts.h',
  23 )
  24 install_headers(mpegts_headers, subdir : 'gstreamer-1.0/gst/mpegts')
  25
  26 mpegts_enums = gnome.mkenums_simple('gstmpegts-enumtypes',
  27   sources : mpegts_headers,
  28   body_prefix : '#ifdef HAVE_CONFIG_H\n#include "config.h"\n#endif',
  29   header_prefix : '#include <gst/mpegts/mpegts-prelude.h>',
  30   decorator : 'GST_MPEGTS_API',
  31   install_header: true,
  32   install_dir : join_paths(get_option('includedir'), 'gstreamer-1.0/gst/mpegts'))
  33
  34 mpegtsenumtypes_h = mpegts_enums[1]
  35
  36 gen_sources = [mpegtsenumtypes_h]
  37
  38 gstmpegts = library('gstmpegts-' + api_version,
  39   mpegts_sources, mpegts_enums,
  40   c_args : gst_plugins_bad_args + ['-DGST_USE_UNSTABLE_API', '-DBUILDING_GST_MPEGTS', '-DG_LOG_DOMAIN="GStreamer-MpegTS"'],
  41   include_directories : [configinc, libsinc],
  42   version : libversion,
  43   soversion : soversion,
  44   darwin_versions : osxversion,
  45   install : true,
  46   dependencies : [gst_dep],
  47 )
  48
  49 library_def = {'lib': gstmpegts}
  50 pkg_name = 'gstreamer-mpegts-1.0'
  51 pkgconfig.generate(gstmpegts,
  52   libraries : [gst_dep, gstbase_dep],
  53   variables : pkgconfig_variables,
  54   subdirs : pkgconfig_subdirs,
  55   name : pkg_name,
  56   description : 'GStreamer MPEG-TS support',
  57 )
  58
  59 if build_gir
  60   gir = {
  61     'sources' : mpegts_sources + mpegts_headers,
  62     'namespace' : 'GstMpegts',
  63     'nsversion' : api_version,
  64     'identifier_prefix' : 'GstMpegts',
  65     'symbol_prefix' : ['gst_mpegts', 'gst'],
  66     'export_packages' : pkg_name,
  67     'includes' : ['Gst-1.0'],
  68     'install' : true,
  69     'extra_args' : gir_init_section + ['-DGST_USE_UNSTABLE_API'] + ['--c-include=gst/mpegts/mpegts.h'],
  70     'dependencies' : [gst_dep]
  71   }
  72   library_def += {'gir': [gir]}
  73   if not static_build
  74     mpegts_gir = gnome.generate_gir(gstmpegts, kwargs: gir)
  75     gen_sources += mpegts_gir
  76   endif
  77 endif
  78 gst_libraries += [[pkg_name, library_def]]
  79
  80 gstmpegts_dep = declare_dependency(link_with : gstmpegts,
  81   include_directories : [libsinc],
  82   dependencies : [gst_dep],
  83   sources : gen_sources)
  84 meson.override_dependency(pkg_name, gstmpegts_dep)