subprojects/gst-plugins-bad/gst-libs/gst/basecamerabinsrc/meson.build

   1 camerabin_sources = files(
   2   'gstcamerabin-enum.c',
   3   'gstcamerabinpreview.c',
   4   'gstbasecamerasrc.c',
   5 )
   6 camerabin_headers = files(
   7   'basecamerabinsrc-prelude.h',
   8   'gstcamerabin-enum.h',
   9   'gstcamerabinpreview.h',
  10   'gstbasecamerasrc.h',
  11 )
  12 install_headers(camerabin_headers, subdir : 'gstreamer-1.0/gst/basecamerabinsrc')
  13
  14 gstbasecamerabin = library('gstbasecamerabinsrc-' + api_version,
  15   camerabin_sources,
  16   c_args : gst_plugins_bad_args + ['-DGST_USE_UNSTABLE_API', '-DBUILDING_GST_BASE_CAMERA_BIN_SRC', '-DG_LOG_DOMAIN="GStreamer-BaseCameraBinSrc"'],
  17   include_directories : [configinc, libsinc],
  18   version : libversion,
  19   soversion : soversion,
  20   darwin_versions : osxversion,
  21   install : true,
  22   dependencies : [gstapp_dep],
  23 )
  24
  25 library_def = {'lib': gstbasecamerabin}
  26 pkg_name = 'gstreamer-bad-base-camerabinsrc-1.0'
  27 gen_sources = []
  28 if build_gir and not static_build
  29   gir = {
  30     'sources' : camerabin_sources + camerabin_headers,
  31     'namespace' : 'GstBadBaseCameraBin',
  32     'nsversion' : api_version,
  33     'identifier_prefix' : 'Gst',
  34     'symbol_prefix' : 'gst',
  35     'export_packages' : pkg_name,
  36     'includes' : ['Gst-1.0', 'GstApp-1.0'],
  37     'install' : false, # Only for the documentation
  38     'extra_args' : gir_init_section + ['-DGST_USE_UNSTABLE_API'],
  39     'dependencies' : [gstapp_dep],
  40     'build_by_default' : true,
  41   }
  42   library_def += {'gir': [gir]}
  43   if not static_build
  44     basecamerabin_gir = gnome.generate_gir(gstbasecamerabin, kwargs: gir)
  45     gen_sources += basecamerabin_gir
  46   endif
  47 endif
  48
  49 gstbasecamerabin_dep = declare_dependency(link_with : gstbasecamerabin,
  50   include_directories : [libsinc],
  51   sources: gen_sources,
  52   dependencies : [gstapp_dep])
  53 meson.override_dependency(pkg_name, gstbasecamerabin_dep)