subprojects/gst-plugins-bad/gst-libs/gst/audio/meson.build

   1 badaudio_sources = files('gstnonstreamaudiodecoder.c', 'gstplanaraudioadapter.c')
   2 badaudio_headers = files('gstnonstreamaudiodecoder.h', 'audio-bad-prelude.h', 'gstplanaraudioadapter.h')
   3 install_headers(badaudio_headers, subdir : 'gstreamer-1.0/gst/audio')
   4
   5
   6 gstbadaudio = library('gstbadaudio-' + api_version,
   7   badaudio_sources,
   8   c_args : gst_plugins_bad_args + ['-DGST_USE_UNSTABLE_API', '-DBUILDING_GST_AUDIO_BAD', '-DG_LOG_DOMAIN="GStreamer-AudioBad"'],
   9   include_directories : [configinc, libsinc],
  10   version : libversion,
  11   soversion : soversion,
  12   darwin_versions : osxversion,
  13   install : true,
  14   dependencies : [gstaudio_dep, gstbase_dep],
  15 )
  16
  17 library_def = {'lib': gstbadaudio}
  18 pkg_name = 'gstreamer-bad-audio-1.0'
  19 pkgconfig.generate(gstbadaudio,
  20   libraries : [gst_dep, gstbase_dep],
  21   variables : pkgconfig_variables,
  22   subdirs : pkgconfig_subdirs,
  23   name : pkg_name,
  24   description : 'Bad audio library for GStreamer elements',
  25 )
  26 gen_sources = []
  27
  28 if build_gir
  29   gir = {
  30     'sources' : badaudio_sources + badaudio_headers,
  31     'namespace' : 'GstBadAudio',
  32     'nsversion' : api_version,
  33     'identifier_prefix' : 'Gst',
  34     'symbol_prefix' : 'gst',
  35     'export_packages' : pkg_name,
  36     'includes' : ['Gst-1.0', 'GstAudio-1.0', 'GstBase-1.0'],
  37     'install' : true,
  38     'extra_args' : gir_init_section + ['-DGST_USE_UNSTABLE_API'],
  39     'dependencies' : [gstbase_dep, gstaudio_dep]
  40   }
  41   library_def += {'gir': [gir]}
  42   if not static_build
  43     audio_gir = gnome.generate_gir(gstbadaudio, kwargs: gir)
  44     gen_sources += audio_gir
  45   endif
  46 endif
  47 gst_libraries += [[pkg_name, library_def]]
  48
  49 gstbadaudio_dep = declare_dependency(link_with : gstbadaudio,
  50   include_directories : [libsinc],
  51   sources: gen_sources,
  52   dependencies : [gstaudio_dep, gstbase_dep])
  53
  54 meson.override_dependency(pkg_name, gstbadaudio_dep)