subprojects/gst-plugins-bad/ext/srtp/meson.build

   1 srtp_sources = [
   2   'gstsrtp.c',
   3   'gstsrtpelement.c',
   4   'gstsrtpplugin.c',
   5   'gstsrtpdec.c',
   6   'gstsrtpenc.c',
   7 ]
   8
   9 srtp_cargs = []
  10 if get_option('srtp').disabled()
  11   srtp_dep = dependency('', required : false)
  12   subdir_done()
  13 endif
  14
  15 srtp_dep = dependency('libsrtp2', version : '>= 2.1.0', required : false)
  16 if srtp_dep.found()
  17   srtp_cargs += ['-DHAVE_SRTP2']
  18 else
  19   srtp_dep = dependency('libsrtp', version: '>= 1.6.0', required : false)
  20   if not srtp_dep.found() and cc.has_header_symbol('srtp/srtp.h', 'crypto_policy_set_aes_gcm_128_16_auth')
  21     srtp_dep = cc.find_library('srtp', required : false)
  22   endif
  23 endif
  24 if not srtp_dep.found() and get_option('srtp').enabled()
  25   error('srtp plugin enabled but libsrtp not found')
  26 endif
  27
  28 if srtp_dep.found()
  29   gstsrtp_enums = gnome.mkenums_simple('gstsrtp-enumtypes',
  30     sources : ['gstsrtpenums.h'],
  31     decorator : 'G_GNUC_INTERNAL',
  32     install_header: false)
  33
  34   gstsrtp = library('gstsrtp',
  35     srtp_sources, gstsrtp_enums,
  36     c_args : gst_plugins_bad_args + srtp_cargs,
  37     link_args : noseh_link_args,
  38     include_directories : [configinc],
  39     dependencies : [gstrtp_dep, gstvideo_dep, srtp_dep],
  40     install : true,
  41     install_dir : plugins_install_dir,
  42   )
  43   plugins += [gstsrtp]
  44 endif