subprojects/gst-plugins-bad/ext/flite/meson.build

   1 flite_sources = [
   2   'gstflite.c',
   3   'gstflitetestsrc.c',
   4 ]
   5
   6 flite_libs = [
   7   'flite',
   8   'flite_cmu_us_kal',
   9   'flite_usenglish',
  10   'flite_cmulex'
  11 ]
  12
  13 if get_option('flite').disabled()
  14   subdir_done()
  15 endif
  16
  17 flite_deps = [ ]
  18 foreach flite_lib : flite_libs
  19   flite_lib_dep = cc.find_library(flite_lib, required : get_option('flite'))
  20   if flite_lib_dep.found()
  21     flite_deps += [flite_lib_dep]
  22   endif
  23 endforeach
  24 have_flite_h = cc.has_header_symbol('flite/flite.h', 'flite_init')
  25 if not have_flite_h and get_option('flite').enabled()
  26   error('flite plugin enabled, but flite.h not found')
  27 endif
  28
  29 if flite_deps.length() == flite_libs.length() and have_flite_h
  30   gstflite = library('gstflite',
  31     flite_sources,
  32     c_args : gst_plugins_bad_args,
  33     include_directories : [configinc],
  34     dependencies : [gstaudio_dep] + flite_deps,
  35     install : true,
  36     install_dir : plugins_install_dir,
  37   )
  38   plugins += [gstflite]
  39 endif