subprojects/gst-omx/meson.build

   1 project('gst-omx', 'c',
   2   version : '1.19.2',
   3   meson_version : '>= 0.54',
   4   default_options : [ 'warning_level=1',
   5                       'buildtype=debugoptimized' ])
   6
   7 gst_version = meson.project_version()
   8 version_arr = gst_version.split('.')
   9 gst_version_major = version_arr[0].to_int()
  10 gst_version_minor = version_arr[1].to_int()
  11 gst_version_micro = version_arr[2].to_int()
  12  if version_arr.length() == 4
  13   gst_version_nano = version_arr[3].to_int()
  14 else
  15   gst_version_nano = 0
  16 endif
  17
  18 glib_req = '>= 2.56.0'
  19 gst_req = '>= @0@.@1@.0'.format(gst_version_major, gst_version_minor)
  20 tizil_req = '>= 0.19.0'
  21 api_version = '1.0'
  22
  23 plugins_install_dir = '@0@/gstreamer-1.0'.format(get_option('libdir'))
  24
  25 cc = meson.get_compiler('c')
  26
  27 if cc.get_id() == 'msvc'
  28   msvc_args = [
  29       # Ignore several spurious warnings for things gstreamer does very commonly
  30       # If a warning is completely useless and spammy, use '/wdXXXX' to suppress it
  31       # If a warning is harmless but hard to fix, use '/woXXXX' so it's shown once
  32       # NOTE: Only add warnings here if you are sure they're spurious
  33       '/wd4018', # implicit signed/unsigned conversion
  34       '/wd4146', # unary minus on unsigned (beware INT_MIN)
  35       '/wd4244', # lossy type conversion (e.g. double -> int)
  36       '/wd4305', # truncating type conversion (e.g. double -> float)
  37       cc.get_supported_arguments(['/utf-8']), # set the input encoding to utf-8
  38
  39       # Enable some warnings on MSVC to match GCC/Clang behaviour
  40       '/w14062', # enumerator 'identifier' in switch of enum 'enumeration' is not handled
  41       '/w14101', # 'identifier' : unreferenced local variable
  42       '/w14189', # 'identifier' : local variable is initialized but not referenced
  43   ]
  44   add_project_arguments(msvc_args, language: 'c')
  45   # Disable SAFESEH with MSVC for plugins and libs that use external deps that
  46   # are built with MinGW
  47   noseh_link_args = ['/SAFESEH:NO']
  48 else
  49   noseh_link_args = []
  50 endif
  51
  52 cdata = configuration_data()
  53 check_headers = [
  54 #  ['HAVE_DLFCN_H', 'dlfcn.h'],
  55 #  ['HAVE_FCNTL_H', 'fcntl.h'],
  56 #  ['HAVE_INTTYPES_H', 'inttypes.h'],
  57 #  ['HAVE_MEMORY_H', 'memory.h'],
  58 #  ['HAVE_MSACM_H', 'msacm.h'],
  59 #  ['HAVE_PTHREAD_H', 'pthread.h'],
  60 #  ['HAVE_STDINT_H', 'stdint.h'],
  61 #  ['HAVE_STDLIB_H', 'stdlib.h'],
  62 #  ['HAVE_STRINGS_H', 'strings.h'],
  63 #  ['HAVE_STRING_H', 'string.h'],
  64 #  ['HAVE_SYS_PARAM_H', 'sys/param.h'],
  65 #  ['HAVE_SYS_SOCKET_H', 'sys/socket.h'],
  66 #  ['HAVE_SYS_STAT_H', 'sys/stat.h'],
  67 #  ['HAVE_SYS_TIME_H', 'sys/time.h'],
  68 #  ['HAVE_SYS_TYPES_H', 'sys/types.h'],
  69 #  ['HAVE_SYS_UTSNAME_H', 'sys/utsname.h'],
  70 #  ['HAVE_UNISTD_H', 'unistd.h'],
  71 ]
  72
  73 foreach h : check_headers
  74   if cc.has_header(h.get(1))
  75     cdata.set(h.get(0), 1)
  76   endif
  77 endforeach
  78
  79 check_functions = [
  80 # check token HAVE_CPU_ALPHA
  81 # check token HAVE_CPU_ARM
  82 # check token HAVE_CPU_CRIS
  83 # check token HAVE_CPU_CRISV32
  84 # check token HAVE_CPU_HPPA
  85 # check token HAVE_CPU_I386
  86 # check token HAVE_CPU_IA64
  87 # check token HAVE_CPU_M68K
  88 # check token HAVE_CPU_MIPS
  89 # check token HAVE_CPU_PPC
  90 # check token HAVE_CPU_PPC64
  91 # check token HAVE_CPU_S390
  92 # check token HAVE_CPU_SPARC
  93 # check token HAVE_CPU_X86_64
  94 #  ['HAVE_DCGETTEXT', 'dcgettext'],
  95 # check token HAVE_EXPERIMENTAL
  96 # check token HAVE_EXTERNAL
  97 #  ['HAVE_GETPAGESIZE', 'getpagesize'],
  98 # check token HAVE_GETTEXT
  99 ]
 100
 101 foreach f : check_functions
 102   if cc.has_function(f.get(1))
 103     cdata.set(f.get(0), 1)
 104   endif
 105 endforeach
 106
 107 #cdata.set('SIZEOF_CHAR', cc.sizeof('char'))
 108 #cdata.set('SIZEOF_INT', cc.sizeof('int'))
 109 #cdata.set('SIZEOF_LONG', cc.sizeof('long'))
 110 #cdata.set('SIZEOF_SHORT', cc.sizeof('short'))
 111 #cdata.set('SIZEOF_VOIDP', cc.sizeof('void*'))
 112
 113 cdata.set('VERSION', '"@0@"'.format(gst_version))
 114 cdata.set('PACKAGE', '"gst-omx"')
 115 cdata.set('PACKAGE_VERSION', '"@0@"'.format(gst_version))
 116 cdata.set('PACKAGE_BUGREPORT', '"https://gitlab.freedesktop.org/gstreamer/gst-omx/issues/new"')
 117 cdata.set('PACKAGE_NAME', '"GStreamer OMX Plugins"')
 118 cdata.set('GETTEXT_PACKAGE', '"gst-omx-1.0"')
 119 cdata.set('GST_API_VERSION', '"@0@"'.format(api_version))
 120 cdata.set('GST_PACKAGE_NAME', '"GStreamer OpenMAX Plug-ins"')
 121 cdata.set('GST_PACKAGE_ORIGIN', '"Unknown package origin"')
 122 cdata.set('GST_LICENSE', '"LGPL"')
 123 cdata.set('LIBDIR', '"@0@"'.format(get_option('libdir')))
 124
 125 # FIXME: This should be exposed as a configuration option
 126 host_system = host_machine.system()
 127 if host_system == 'linux'
 128   cdata.set('DEFAULT_VIDEOSRC', '"v4l2src"')
 129 elif host_system == 'osx'
 130   cdata.set('DEFAULT_VIDEOSRC', '"avfvideosrc"')
 131 else
 132   cdata.set('DEFAULT_VIDEOSRC', '"videotestsrc"')
 133 endif
 134
 135 # Mandatory GST deps
 136 gst_dep = dependency('gstreamer-1.0', version : gst_req,
 137   fallback : ['gstreamer', 'gst_dep'])
 138 gstbase_dep = dependency('gstreamer-base-1.0', version : gst_req,
 139   fallback : ['gstreamer', 'gst_base_dep'])
 140 gstcontroller_dep = dependency('gstreamer-controller-1.0', version : gst_req,
 141   fallback : ['gstreamer', 'gst_controller_dep'])
 142 gstallocators_dep = dependency('gstreamer-allocators-1.0', version : gst_req,
 143   fallback : ['gst-plugins-base', 'allocators_dep'])
 144
 145 gstpbutils_dep = dependency('gstreamer-pbutils-1.0', version : gst_req,
 146     fallback : ['gst-plugins-base', 'pbutils_dep'])
 147 gstaudio_dep = dependency('gstreamer-audio-1.0', version : gst_req,
 148     fallback : ['gst-plugins-base', 'audio_dep'])
 149 gstfft_dep = dependency('gstreamer-fft-1.0', version : gst_req,
 150     fallback : ['gst-plugins-base', 'fft_dep'])
 151 gsttag_dep = dependency('gstreamer-tag-1.0', version : gst_req,
 152     fallback : ['gst-plugins-base', 'tag_dep'])
 153 gstvideo_dep = dependency('gstreamer-video-1.0', version : gst_req,
 154     fallback : ['gst-plugins-base', 'video_dep'])
 155
 156 gstgl_dep = dependency('gstreamer-gl-1.0', version : gst_req,
 157     fallback : ['gst-plugins-base', 'gstgl_dep'], required : false)
 158
 159 x11_dep = dependency('x11', required : false)
 160
 161 gstcheck_dep = dependency('gstreamer-check-1.0', version : gst_req,
 162     required : get_option('tests'),
 163     fallback : ['gstreamer', 'gst_check_dep'])
 164
 165 libm = cc.find_library('m', required : false)
 166 glib_dep = dependency('glib-2.0', version : glib_req, fallback: ['glib', 'libglib_dep'])
 167 gio_dep = dependency('gio-2.0', version : glib_req, fallback: ['glib', 'libgio_dep'] )
 168 gmodule_dep = dependency('gmodule-2.0', version : glib_req, fallback: ['glib', 'libgmodule_dep'])
 169
 170 gst_omx_args = ['-DHAVE_CONFIG_H']
 171 configinc = include_directories('.')
 172 omx_header_path = get_option('header_path')
 173 if omx_header_path != ''
 174   omx_inc = []
 175   gst_omx_args += ['-I' + omx_header_path]
 176 else
 177   omx_inc = include_directories (join_paths ('omx', 'openmax'))
 178 endif
 179
 180 default_omx_struct_packing = 0
 181 omx_target = get_option ('target')
 182 if omx_target == 'generic'
 183   cdata.set('USE_OMX_TARGET_GENERIC', 1)
 184 elif omx_target == 'rpi'
 185   cdata.set('USE_OMX_TARGET_RPI', 1)
 186   cdata.set('OMX_SKIP64BIT', 1)
 187   default_omx_struct_packing = 4
 188
 189   if gstgl_dep.found()
 190     if gstgl_dep.type_name() == 'pkgconfig'
 191       gl_winsys = gstgl_dep.get_pkgconfig_variable('gl_winsys').split(' ')
 192       gl_platforms = gstgl_dep.get_pkgconfig_variable('gl_platforms').split(' ')
 193     elif gstgl_dep.type_name() == 'internal'
 194       # XXX assume gst-plugins-base was built with dispmanx and egl support
 195       gl_winsys = ['dispmanx']
 196       gl_platforms = ['egl']
 197     else
 198       error ('unreachable dependency type')
 199     endif
 200
 201     if not gl_winsys.contains('dispmanx') or not gl_platforms.contains ('egl')
 202       gstgl_dep = dependency('', required : false)
 203     endif
 204   endif
 205 elif omx_target == 'bellagio'
 206   cdata.set('USE_OMX_TARGET_BELLAGIO', 1)
 207 elif omx_target == 'zynqultrascaleplus'
 208   cdata.set('USE_OMX_TARGET_ZYNQ_USCALE_PLUS', 1)
 209   have_allegro_header = cc.has_header (
 210       'OMX_Allegro.h',
 211       args : gst_omx_args,
 212       include_directories : [omx_inc])
 213   if not have_allegro_header
 214     error ('Need Allegro OMX headers to build for Zynq UltraScale+. Use -Dheader_path option to specify the path of those headers.')
 215   endif
 216 elif omx_target == 'tizonia'
 217   if omx_header_path != ''
 218     warning('Ignoring -Dheader_path because path is in tizilheaders.pc')
 219   endif
 220   cdata.set('USE_OMX_TARGET_TIZONIA', 1)
 221   tizil_dep = dependency('tizilheaders', version : tizil_req)
 222   cdata.set('TIZONIA_LIBDIR', tizil_dep.get_pkgconfig_variable('libdir'))
 223   tizil_includedir = tizil_dep.get_pkgconfig_variable('includedir')
 224   gst_omx_args += ['-I' + tizil_includedir + '/tizonia']
 225   omx_inc = []
 226 else
 227   error ('Unsupported omx target specified. Use the -Dtarget option')
 228 endif
 229
 230 message ('OMX target: ' + omx_target)
 231
 232 extra_video_headers = ''
 233 # Check for optional OpenMAX extension headers
 234
 235 if cc.has_header (
 236     'OMX_VideoExt.h',
 237     args : gst_omx_args,
 238     include_directories : [omx_inc])
 239   extra_video_headers += '''
 240 #include <OMX_VideoExt.h>'''
 241   cdata.set ('HAVE_VIDEO_EXT', 1)
 242 endif
 243
 244 if cc.has_header (
 245     'OMX_IndexExt.h',
 246     args : gst_omx_args,
 247     include_directories : [omx_inc])
 248   cdata.set ('HAVE_INDEX_EXT', 1)
 249 endif
 250
 251 if cc.has_header (
 252     'OMX_ComponentExt.h',
 253     args : gst_omx_args,
 254     include_directories : [omx_inc])
 255   cdata.set ('HAVE_COMPONENT_EXT', 1)
 256 endif
 257
 258 if cc.has_header (
 259     'OMX_CoreExt.h',
 260     args : gst_omx_args)
 261   cdata.set ('HAVE_CORE_EXT', 1)
 262 endif
 263
 264 if cc.has_header (
 265     'OMX_AudioExt.h',
 266     args : gst_omx_args)
 267   cdata.set ('HAVE_AUDIO_EXT', 1)
 268 endif
 269
 270 if cc.has_header (
 271     'OMX_IVCommonExt.h',
 272     args : gst_omx_args)
 273   cdata.set ('HAVE_IV_COMMON_EXT', 1)
 274 endif
 275
 276 if cc.has_header (
 277     'OMX_ImageExt.h',
 278     args : gst_omx_args)
 279   cdata.set ('HAVE_IMAGE_EXT', 1)
 280 endif
 281
 282 if cc.has_header (
 283     'OMX_OtherExt.h',
 284     args : gst_omx_args)
 285   cdata.set ('HAVE_OTHER_EXT', 1)
 286 endif
 287
 288 have_omx_vp8 = cc.has_header_symbol(
 289     'OMX_Video.h',
 290     'OMX_VIDEO_CodingVP8',
 291     prefix : extra_video_headers,
 292     args : gst_omx_args,
 293     include_directories : [omx_inc])
 294 if have_omx_vp8
 295   cdata.set('HAVE_VP8', 1)
 296 endif
 297
 298 have_omx_theora = cc.has_header_symbol(
 299     'OMX_Video.h',
 300     'OMX_VIDEO_CodingTheora',
 301     prefix : extra_video_headers,
 302     args : gst_omx_args,
 303     include_directories : [omx_inc])
 304 if have_omx_theora
 305   cdata.set('HAVE_THEORA', 1)
 306 endif
 307
 308 have_omx_hevc = cc.has_header_symbol(
 309     'OMX_Video.h',
 310     'OMX_VIDEO_CodingHEVC',
 311     prefix : extra_video_headers,
 312     args : gst_omx_args,
 313     include_directories : [omx_inc])
 314 if have_omx_hevc
 315   cdata.set('HAVE_HEVC', 1)
 316 endif
 317
 318 if gstgl_dep.found()
 319   cdata.set ('HAVE_GST_GL', 1)
 320 endif
 321
 322 if x11_dep.found()
 323   cdata.set ('HAVE_X11', 1)
 324 endif
 325
 326 omx_struct_packing = get_option ('struct_packing').to_int()
 327 if omx_struct_packing == 0
 328   omx_struct_packing = default_omx_struct_packing
 329 endif
 330 if omx_struct_packing != 0
 331   cdata.set('GST_OMX_STRUCT_PACKING', omx_struct_packing)
 332 endif
 333
 334 omx_conf_dir = join_paths (get_option ('prefix'), get_option ('sysconfdir'), 'xdg')
 335 cdata.set_quoted('GST_OMX_CONFIG_DIR', omx_conf_dir)
 336
 337 warning_flags = [
 338   '-Wmissing-declarations',
 339   '-Wredundant-decls',
 340   '-Wwrite-strings',
 341   '-Winit-self',
 342   '-Wmissing-include-dirs',
 343   '-Wno-multichar',
 344   '-Wvla',
 345   '-Wpointer-arith',
 346   '-Wundef',
 347 ]
 348
 349 warning_c_flags = [
 350   '-Wmissing-prototypes',
 351   '-Wdeclaration-after-statement',
 352   '-Wold-style-definition',
 353   '-Waggregate-return',
 354 ]
 355
 356 have_cxx = add_languages('cpp', required : false)
 357
 358 if have_cxx
 359   cxx = meson.get_compiler('cpp')
 360 endif
 361
 362 foreach extra_arg : warning_flags
 363   if cc.has_argument (extra_arg)
 364     add_project_arguments([extra_arg], language: 'c')
 365   endif
 366   if have_cxx and cxx.has_argument (extra_arg)
 367     add_project_arguments([extra_arg], language: 'cpp')
 368   endif
 369 endforeach
 370
 371 foreach extra_arg : warning_c_flags
 372   if cc.has_argument (extra_arg)
 373     add_project_arguments([extra_arg], language: 'c')
 374   endif
 375 endforeach
 376
 377 # Disable compiler warnings for unused variables and args if gst debug system is disabled
 378 if gst_dep.type_name() == 'internal'
 379   gst_debug_disabled = not subproject('gstreamer').get_variable('gst_debug')
 380 else
 381   # We can't check that in the case of subprojects as we won't
 382   # be able to build against an internal dependency (which is not built yet)
 383   gst_debug_disabled = cc.has_header_symbol('gst/gstconfig.h', 'GST_DISABLE_GST_DEBUG', dependencies: gst_dep)
 384 endif
 385
 386 if gst_debug_disabled
 387   message('GStreamer debug system is disabled')
 388   if cc.has_argument('-Wno-unused')
 389     add_project_arguments('-Wno-unused', language: 'c')
 390   endif
 391   if have_cxx and cxx.has_argument ('-Wno-unused')
 392     add_project_arguments('-Wno-unused', language: 'cpp')
 393   endif
 394 else
 395   message('GStreamer debug system is enabled')
 396 endif
 397
 398 subdir('config')
 399
 400 if not get_option('examples').disabled()
 401   subdir('examples')
 402 endif
 403
 404 subdir('omx')
 405
 406 if not get_option('tools').disabled()
 407   subdir('tools')
 408 endif
 409
 410 if not get_option('tests').disabled() and gstcheck_dep.found()
 411   subdir('tests')
 412 endif
 413 subdir('docs')
 414
 415 # Set release date
 416 if gst_version_nano == 0
 417   extract_release_date = find_program('scripts/extract-release-date-from-doap-file.py')
 418   run_result = run_command(extract_release_date, gst_version, files('gst-omx.doap'))
 419   if run_result.returncode() == 0
 420     release_date = run_result.stdout().strip()
 421     cdata.set_quoted('GST_PACKAGE_RELEASE_DATETIME', release_date)
 422     message('Package release date: ' + release_date)
 423   else
 424     # Error out if our release can't be found in the .doap file
 425     error(run_result.stderr())
 426   endif
 427 endif
 428
 429 configure_file(output: 'config.h', configuration: cdata)
 430
 431 python3 = find_program('python3')
 432 run_command(python3, '-c', 'import shutil; shutil.copy("hooks/pre-commit.hook", ".git/hooks/pre-commit")')