subprojects/gst-libav/meson.build

   1 project('gst-libav', 'c', 'cpp',
   2   version : '1.19.2',
   3   meson_version : '>= 0.54',
   4   default_options : [ 'warning_level=1',
   5                       'buildtype=debugoptimized' ])
   6
   7 gst_version = meson.project_version()
   8 version_arr = gst_version.split('.')
   9 gst_version_major = version_arr[0].to_int()
  10 gst_version_minor = version_arr[1].to_int()
  11 gst_version_micro = version_arr[2].to_int()
  12  if version_arr.length() == 4
  13   gst_version_nano = version_arr[3].to_int()
  14 else
  15   gst_version_nano = 0
  16 endif
  17
  18 api_version = '1.0'
  19 libavfilter_dep = dependency('libavfilter', version: '>= 7.16.100',
  20   fallback: ['FFmpeg', 'libavfilter_dep'])
  21 libavformat_dep = dependency('libavformat', version: '>= 58.12.100',
  22   fallback: ['FFmpeg', 'libavformat_dep'])
  23 libavcodec_dep = dependency('libavcodec', version: '>= 58.18.100',
  24   fallback: ['FFmpeg', 'libavcodec_dep'])
  25 libavutil_dep = dependency('libavutil', version: '>= 56.14.100',
  26   fallback: ['FFmpeg', 'libavutil_dep'])
  27
  28 libav_deps = [libavfilter_dep, libavformat_dep, libavcodec_dep, libavutil_dep]
  29
  30 cc = meson.get_compiler('c')
  31
  32 check_ffmpeg_src = '''#include <libavcodec/avcodec.h>
  33 #if LIBAVCODEC_VERSION_MICRO >= 100
  34 /* FFmpeg uses 100+ as its micro version */
  35 #else
  36 #error libav provider should be FFmpeg
  37 #endif'''
  38
  39 libav_deps_type_name = ''
  40
  41 foreach dep: libav_deps
  42   if libav_deps_type_name != '' and dep.type_name() != libav_deps_type_name
  43     error('Libav deps must be either all internal or all external')
  44   endif
  45   libav_deps_type_name = dep.type_name()
  46 endforeach
  47
  48 if dep.type_name() != 'internal'
  49   if not cc.compiles(check_ffmpeg_src, dependencies : libav_deps, name : 'libav is provided by FFmpeg')
  50     error('Uncompatible libavcodec found')
  51   endif
  52 endif
  53
  54 cdata = configuration_data()
  55 cdata.set('LIBAV_SOURCE', '"system install"')
  56 cdata.set('PACKAGE_VERSION', '"@0@"'.format(gst_version))
  57 cdata.set('PACKAGE', '"gst-libav"')
  58
  59 # GStreamer package name and origin url
  60 gst_package_name = get_option('package-name')
  61 if gst_package_name == ''
  62   if gst_version_nano == 0
  63     gst_package_name = 'GStreamer FFMPEG Plug-ins source release'
  64   elif gst_version_nano == 1
  65     gst_package_name = 'GStreamer FFMPEG Plug-ins git'
  66   else
  67     gst_package_name = 'GStreamer FFMPEG Plug-ins prerelease'
  68   endif
  69 endif
  70 cdata.set_quoted('GST_PACKAGE_NAME', gst_package_name)
  71 cdata.set_quoted('GST_PACKAGE_ORIGIN', get_option('package-origin'))
  72
  73
  74 check_headers = [['unistd.h', 'HAVE_UNISTD_H']]
  75
  76 foreach h : check_headers
  77   if cc.has_header(h.get(0))
  78     cdata.set(h.get(1), 1)
  79   endif
  80 endforeach
  81
  82 gst_req = '>= @0@.@1@.0'.format(gst_version_major, gst_version_minor)
  83 gst_dep = dependency('gstreamer-1.0', version : gst_req,
  84   fallback : ['gstreamer', 'gst_dep'])
  85 gstbase_dep = dependency('gstreamer-base-1.0', version : gst_req,
  86   fallback : ['gstreamer', 'gst_base_dep'])
  87 gstcheck_dep = dependency('gstreamer-check-1.0', version : gst_req,
  88   required : get_option('tests'),
  89   fallback : ['gstreamer', 'gst_check_dep'])
  90
  91 gstvideo_dep = dependency('gstreamer-video-1.0', version : gst_req,
  92     fallback : ['gst-plugins-base', 'video_dep'])
  93 gstaudio_dep = dependency('gstreamer-audio-1.0', version : gst_req,
  94     fallback : ['gst-plugins-base', 'audio_dep'])
  95 gstpbutils_dep = dependency('gstreamer-pbutils-1.0', version : gst_req,
  96     fallback : ['gst-plugins-base', 'pbutils_dep'])
  97 libm = cc.find_library('m', required : false)
  98
  99 gst_libav_args = ['-DHAVE_CONFIG_H']
 100 if cc.get_id() == 'msvc'
 101   msvc_args = [
 102       # Ignore several spurious warnings for things gstreamer does very commonly
 103       # If a warning is completely useless and spammy, use '/wdXXXX' to suppress it
 104       # If a warning is harmless but hard to fix, use '/woXXXX' so it's shown once
 105       # NOTE: Only add warnings here if you are sure they're spurious
 106       '/wd4018', # implicit signed/unsigned conversion
 107       '/wd4146', # unary minus on unsigned (beware INT_MIN)
 108       '/wd4244', # lossy type conversion (e.g. double -> int)
 109       '/wd4305', # truncating type conversion (e.g. double -> float)
 110       cc.get_supported_arguments(['/utf-8']), # set the input encoding to utf-8
 111
 112       # Enable some warnings on MSVC to match GCC/Clang behaviour
 113       '/w14062', # enumerator 'identifier' in switch of enum 'enumeration' is not handled
 114       '/w14101', # 'identifier' : unreferenced local variable
 115       '/w14189', # 'identifier' : local variable is initialized but not referenced
 116   ]
 117   add_project_arguments(msvc_args, language: ['c', 'cpp'])
 118 endif
 119
 120 # Symbol visibility
 121 if cc.has_argument('-fvisibility=hidden')
 122   add_project_arguments('-fvisibility=hidden', language: 'c')
 123 endif
 124
 125 # Don't export any symbols from static ffmpeg libraries
 126 if cc.has_link_argument('-Wl,--exclude-libs=ALL')
 127   add_project_link_arguments('-Wl,--exclude-libs=ALL', language: 'c')
 128 endif
 129
 130 # Disable strict aliasing
 131 if cc.has_argument('-fno-strict-aliasing')
 132   add_project_arguments('-fno-strict-aliasing', language: 'c')
 133 endif
 134
 135 if gst_dep.type_name() == 'internal'
 136     gst_proj = subproject('gstreamer')
 137
 138     if not gst_proj.get_variable('gst_debug')
 139         message('GStreamer debug system is disabled')
 140         add_project_arguments('-Wno-unused', language: 'c')
 141     else
 142         message('GStreamer debug system is enabled')
 143     endif
 144 else
 145     # We can't check that in the case of subprojects as we won't
 146     # be able to build against an internal dependency (which is not built yet)
 147     if not cc.compiles('''
 148 #include <gst/gstconfig.h>
 149 #ifdef GST_DISABLE_GST_DEBUG
 150 #error "debugging disabled, make compiler fail"
 151 #endif''' , dependencies: gst_dep)
 152         message('GStreamer debug system is disabled')
 153         add_project_arguments('-Wno-unused', language: 'c')
 154     else
 155         message('GStreamer debug system is enabled')
 156     endif
 157 endif
 158
 159 warning_flags = [
 160   '-Wmissing-declarations',
 161   '-Wmissing-prototypes',
 162   '-Wold-style-definition',
 163   '-Wredundant-decls',
 164   '-Wundef',
 165   '-Wwrite-strings',
 166   '-Wformat',
 167   '-Wformat-nonliteral',
 168   '-Wformat-security',
 169   '-Winit-self',
 170   '-Wmissing-include-dirs',
 171   '-Waddress',
 172   '-Wno-multichar',
 173   '-Waggregate-return',
 174   '-Wdeclaration-after-statement',
 175   '-Wvla',
 176   '-Wpointer-arith',
 177 ]
 178
 179 foreach extra_arg : warning_flags
 180   if cc.has_argument (extra_arg)
 181     add_project_arguments([extra_arg], language: 'c')
 182   endif
 183 endforeach
 184
 185 configinc = include_directories('.')
 186 plugins_install_dir = '@0@/gstreamer-1.0'.format(get_option('libdir'))
 187
 188 pkgconfig = import('pkgconfig')
 189 plugins_pkgconfig_install_dir = join_paths(plugins_install_dir, 'pkgconfig')
 190 if get_option('default_library') == 'shared'
 191   # If we don't build static plugins there is no need to generate pc files
 192   plugins_pkgconfig_install_dir = disabler()
 193 endif
 194
 195 plugins = []
 196 subdir('ext/libav')
 197 subdir('docs')
 198 subdir('tests')
 199
 200 # Set release date
 201 if gst_version_nano == 0
 202   extract_release_date = find_program('scripts/extract-release-date-from-doap-file.py')
 203   run_result = run_command(extract_release_date, gst_version, files('gst-libav.doap'))
 204   if run_result.returncode() == 0
 205     release_date = run_result.stdout().strip()
 206     cdata.set_quoted('GST_PACKAGE_RELEASE_DATETIME', release_date)
 207     message('Package release date: ' + release_date)
 208   else
 209     # Error out if our release can't be found in the .doap file
 210     error(run_result.stderr())
 211   endif
 212 endif
 213
 214 configure_file(output: 'config.h', configuration: cdata)
 215
 216 python3 = import('python').find_installation()
 217 run_command(python3, '-c', 'import shutil; shutil.copy("hooks/pre-commit.hook", ".git/hooks/pre-commit")')