subprojects/gst-libav/meson.build

   1 project('gst-libav', 'c', 'cpp',
   2   version : '1.21.0.1',
   3   meson_version : '>= 0.60',
   4   default_options : [ 'warning_level=1',
   5                       'buildtype=debugoptimized' ])
   6
   7 gst_version = meson.project_version()
   8 version_arr = gst_version.split('.')
   9 gst_version_major = version_arr[0].to_int()
  10 gst_version_minor = version_arr[1].to_int()
  11 gst_version_micro = version_arr[2].to_int()
  12  if version_arr.length() == 4
  13   gst_version_nano = version_arr[3].to_int()
  14 else
  15   gst_version_nano = 0
  16 endif
  17 gst_version_is_stable = gst_version_minor.is_even()
  18 gst_version_is_dev = gst_version_minor.is_odd() and gst_version_micro < 90
  19
  20 api_version = '1.0'
  21 libavfilter_dep = dependency('libavfilter', version: '>= 7.16.100',
  22   fallback: ['FFmpeg', 'libavfilter_dep'])
  23 libavformat_dep = dependency('libavformat', version: '>= 58.12.100',
  24   fallback: ['FFmpeg', 'libavformat_dep'])
  25 libavcodec_dep = dependency('libavcodec', version: '>= 58.18.100',
  26   fallback: ['FFmpeg', 'libavcodec_dep'])
  27 libavutil_dep = dependency('libavutil', version: '>= 56.14.100',
  28   fallback: ['FFmpeg', 'libavutil_dep'])
  29
  30 libav_deps = [libavfilter_dep, libavformat_dep, libavcodec_dep, libavutil_dep]
  31
  32 cc = meson.get_compiler('c')
  33
  34 check_ffmpeg_src = '''#include <libavcodec/avcodec.h>
  35 #if LIBAVCODEC_VERSION_MICRO >= 100
  36 /* FFmpeg uses 100+ as its micro version */
  37 #else
  38 #error libav provider should be FFmpeg
  39 #endif'''
  40
  41 libav_deps_type_name = ''
  42
  43 foreach dep: libav_deps
  44   if libav_deps_type_name != '' and dep.type_name() != libav_deps_type_name
  45     error('Libav deps must be either all internal or all external')
  46   endif
  47   libav_deps_type_name = dep.type_name()
  48 endforeach
  49
  50 if dep.type_name() != 'internal'
  51   if not cc.compiles(check_ffmpeg_src, dependencies : libav_deps, name : 'libav is provided by FFmpeg')
  52     error('Uncompatible libavcodec found')
  53   endif
  54 endif
  55
  56 cdata = configuration_data()
  57 cdata.set('LIBAV_SOURCE', '"system install"')
  58 cdata.set('PACKAGE_VERSION', '"@0@"'.format(gst_version))
  59 cdata.set('PACKAGE', '"gst-libav"')
  60
  61 # GStreamer package name and origin url
  62 gst_package_name = get_option('package-name')
  63 if gst_package_name == ''
  64   if gst_version_nano == 0
  65     gst_package_name = 'GStreamer FFMPEG Plug-ins source release'
  66   elif gst_version_nano == 1
  67     gst_package_name = 'GStreamer FFMPEG Plug-ins git'
  68   else
  69     gst_package_name = 'GStreamer FFMPEG Plug-ins prerelease'
  70   endif
  71 endif
  72 cdata.set_quoted('GST_PACKAGE_NAME', gst_package_name)
  73 cdata.set_quoted('GST_PACKAGE_ORIGIN', get_option('package-origin'))
  74
  75
  76 check_headers = [['unistd.h', 'HAVE_UNISTD_H']]
  77
  78 foreach h : check_headers
  79   if cc.has_header(h.get(0))
  80     cdata.set(h.get(1), 1)
  81   endif
  82 endforeach
  83
  84 if gst_version_is_stable
  85   gst_req = '>= @0@.@1@.0'.format(gst_version_major, gst_version_minor)
  86 else
  87   gst_req = '>= ' + gst_version
  88 endif
  89
  90 gst_dep = dependency('gstreamer-1.0', version : gst_req,
  91   fallback : ['gstreamer', 'gst_dep'])
  92 gstbase_dep = dependency('gstreamer-base-1.0', version : gst_req,
  93   fallback : ['gstreamer', 'gst_base_dep'])
  94 gstcheck_dep = dependency('gstreamer-check-1.0', version : gst_req,
  95   required : get_option('tests'),
  96   fallback : ['gstreamer', 'gst_check_dep'])
  97
  98 gstvideo_dep = dependency('gstreamer-video-1.0', version : gst_req,
  99     fallback : ['gst-plugins-base', 'video_dep'])
 100 gstaudio_dep = dependency('gstreamer-audio-1.0', version : gst_req,
 101     fallback : ['gst-plugins-base', 'audio_dep'])
 102 gstpbutils_dep = dependency('gstreamer-pbutils-1.0', version : gst_req,
 103     fallback : ['gst-plugins-base', 'pbutils_dep'])
 104 libm = cc.find_library('m', required : false)
 105
 106 gst_libav_args = ['-DHAVE_CONFIG_H']
 107 if cc.get_id() == 'msvc'
 108   msvc_args = [
 109       # Ignore several spurious warnings for things gstreamer does very commonly
 110       # If a warning is completely useless and spammy, use '/wdXXXX' to suppress it
 111       # If a warning is harmless but hard to fix, use '/woXXXX' so it's shown once
 112       # NOTE: Only add warnings here if you are sure they're spurious
 113       '/wd4018', # implicit signed/unsigned conversion
 114       '/wd4146', # unary minus on unsigned (beware INT_MIN)
 115       '/wd4244', # lossy type conversion (e.g. double -> int)
 116       '/wd4305', # truncating type conversion (e.g. double -> float)
 117       cc.get_supported_arguments(['/utf-8']), # set the input encoding to utf-8
 118   ]
 119
 120   if gst_version_is_dev
 121     # Enable some warnings on MSVC to match GCC/Clang behaviour
 122     msvc_args += cc.get_supported_arguments([
 123       '/we4002', # too many actual parameters for macro 'identifier'
 124       '/we4003', # not enough actual parameters for macro 'identifier'
 125       '/we4013', # 'function' undefined; assuming extern returning int
 126       '/we4020', # 'function' : too many actual parameters
 127       '/we4027', # function declared without formal parameter list
 128       '/we4029', # declared formal parameter list different from definition
 129       '/we4033', # 'function' must return a value
 130       '/we4045', # 'array' : array bounds overflow
 131       '/we4047', # 'operator' : 'identifier1' differs in levels of indirection from 'identifier2'
 132       '/we4053', # one void operand for '?:'
 133       '/we4062', # enumerator 'identifier' in switch of enum 'enumeration' is not handled
 134       '/we4098', # 'function' : void function returning a value
 135       '/we4101', # 'identifier' : unreferenced local variable
 136       '/we4189', # 'identifier' : local variable is initialized but not referenced
 137     ])
 138   endif
 139   add_project_arguments(msvc_args, language: ['c', 'cpp'])
 140 endif
 141
 142 # Symbol visibility
 143 if cc.has_argument('-fvisibility=hidden')
 144   add_project_arguments('-fvisibility=hidden', language: 'c')
 145 endif
 146
 147 # Don't export any symbols from static ffmpeg libraries
 148 if cc.has_link_argument('-Wl,--exclude-libs=ALL')
 149   add_project_link_arguments('-Wl,--exclude-libs=ALL', language: 'c')
 150 endif
 151
 152 # Disable strict aliasing
 153 if cc.has_argument('-fno-strict-aliasing')
 154   add_project_arguments('-fno-strict-aliasing', language: 'c')
 155 endif
 156
 157 if gst_dep.type_name() == 'internal'
 158     gst_proj = subproject('gstreamer')
 159
 160     if not gst_proj.get_variable('gst_debug')
 161         message('GStreamer debug system is disabled')
 162         add_project_arguments('-Wno-unused', language: 'c')
 163     else
 164         message('GStreamer debug system is enabled')
 165     endif
 166 else
 167     # We can't check that in the case of subprojects as we won't
 168     # be able to build against an internal dependency (which is not built yet)
 169     if not cc.compiles('''
 170 #include <gst/gstconfig.h>
 171 #ifdef GST_DISABLE_GST_DEBUG
 172 #error "debugging disabled, make compiler fail"
 173 #endif''' , dependencies: gst_dep)
 174         message('GStreamer debug system is disabled')
 175         add_project_arguments('-Wno-unused', language: 'c')
 176     else
 177         message('GStreamer debug system is enabled')
 178     endif
 179 endif
 180
 181 warning_flags = [
 182   '-Wmissing-declarations',
 183   '-Wmissing-prototypes',
 184   '-Wold-style-definition',
 185   '-Wredundant-decls',
 186   '-Wundef',
 187   '-Wwrite-strings',
 188   '-Wformat',
 189   '-Wformat-nonliteral',
 190   '-Wformat-security',
 191   '-Winit-self',
 192   '-Wmissing-include-dirs',
 193   '-Waddress',
 194   '-Wno-multichar',
 195   '-Waggregate-return',
 196   '-Wdeclaration-after-statement',
 197   '-Wvla',
 198   '-Wpointer-arith',
 199 ]
 200
 201 foreach extra_arg : warning_flags
 202   if cc.has_argument (extra_arg)
 203     add_project_arguments([extra_arg], language: 'c')
 204   endif
 205 endforeach
 206
 207 configinc = include_directories('.')
 208 plugins_install_dir = '@0@/gstreamer-1.0'.format(get_option('libdir'))
 209
 210 pkgconfig = import('pkgconfig')
 211 plugins_pkgconfig_install_dir = join_paths(plugins_install_dir, 'pkgconfig')
 212 if get_option('default_library') == 'shared'
 213   # If we don't build static plugins there is no need to generate pc files
 214   plugins_pkgconfig_install_dir = disabler()
 215 endif
 216
 217 plugins = []
 218 subdir('ext/libav')
 219 subdir('docs')
 220 subdir('tests')
 221
 222 # Set release date
 223 if gst_version_nano == 0
 224   extract_release_date = find_program('scripts/extract-release-date-from-doap-file.py')
 225   run_result = run_command(extract_release_date, gst_version, files('gst-libav.doap'), check: true)
 226   release_date = run_result.stdout().strip()
 227   cdata.set_quoted('GST_PACKAGE_RELEASE_DATETIME', release_date)
 228   message('Package release date: ' + release_date)
 229 endif
 230
 231 configure_file(output: 'config.h', configuration: cdata)