subprojects/gst-devtools/validate/gst/validate/meson.build

   1 gstvalidate_sources = [
   2     'gst-validate-reporter.c',
   3     'gst-validate-mockdecryptor.c',
   4     'gst-validate-monitor.c',
   5     'gst-validate-element-monitor.c',
   6     'gst-validate-bin-monitor.c',
   7     'gst-validate-pipeline-monitor.c',
   8     'gst-validate-pad-monitor.c',
   9     'gst-validate-monitor-factory.c',
  10     'gst-validate-report.c',
  11     'gst-validate-scenario.c',
  12     'gst-validate-override.c',
  13     'gst-validate-utils.c',
  14     'gst-validate-override-registry.c',
  15     'media-descriptor.c',
  16     'media-descriptor-writer.c',
  17     'media-descriptor-parser.c',
  18     'gst-validate-media-info.c',
  19     'gst-validate-extra-checks.c',
  20     'flow/gstvalidateflow.c',
  21     'flow/formatting.c',
  22     'validate.c',
  23 ]
  24
  25 gstvalidate_headers = [
  26     'validate.h',
  27     'validate-prelude.h',
  28     'gst-validate-types.h',
  29     'gst-validate-bin-monitor.h',
  30     'gst-validate-pipeline-monitor.h',
  31     'gst-validate-element-monitor.h',
  32     'gst-validate-enums.h',
  33     'media-descriptor.h',
  34     'media-descriptor-writer.h',
  35     'media-descriptor-parser.h',
  36     'gst-validate-monitor-factory.h',
  37     'gst-validate-monitor.h',
  38     'gst-validate-override.h',
  39     'gst-validate-override-registry.h',
  40     'gst-validate-pad-monitor.h',
  41     'gst-validate-reporter.h',
  42     'gst-validate-report.h',
  43     'gst-validate-runner.h',
  44     'gst-validate-scenario.h',
  45     'gst-validate-utils.h',
  46     'gst-validate-media-info.h'
  47 ]
  48
  49 install_headers(gstvalidate_headers, subdir : 'gstreamer-1.0/gst/validate')
  50
  51 gst_validate_enums = gnome.mkenums('gstvalidateenumtypes',
  52   sources : gstvalidate_headers,
  53   h_template : 'gst-validate-enum-types.h.template',
  54   c_template : 'gst-validate-enum-types.c.template',
  55   install_header : true,
  56   install_dir : join_paths(get_option('includedir'), 'gstreamer-1.0/gst/validate'))
  57
  58 validate_deps = [gst_check_dep, gst_dep, gst_controller_dep, gstbase_dep, glib_dep, gio_dep, gmodule_dep, gst_pbutils_dep, mathlib, json_dep]
  59 gstvalidate = library('gstvalidate-1.0',
  60     sources: files('gst-validate-runner.c') + gstvalidate_sources + gst_validate_enums,
  61     version : libversion,
  62     soversion : soversion,
  63     darwin_versions : osxversion,
  64     include_directories : [inc_dirs],
  65     install: true,
  66     c_args : [gst_c_args] + ['-D_GNU_SOURCE'],
  67     dependencies : validate_deps)
  68
  69 gstvalidatetracer = library('gstvalidatetracer',
  70     sources: files('gst-validate-runner.c') + gst_validate_enums,
  71     include_directories : [inc_dirs],
  72     install: true,
  73     c_args : [gst_c_args] + ['-D__GST_VALIDATE_PLUGIN', '-D_GNU_SOURCE'],
  74     install_dir : plugins_install_dir,
  75     objects: gstvalidate.extract_objects(gstvalidate_sources),
  76     dependencies : validate_deps)
  77
  78 plugins += gstvalidatetracer
  79 pkgconfig.generate(gstvalidate,
  80   libraries : [gst_dep],
  81   subdirs : pkgconfig_subdirs,
  82   name : 'gst-validate-1.0',
  83   description : 'Gstreamer Validate',
  84 )
  85
  86 validate_gen_sources = []
  87 if build_gir
  88     gst_validate_gir_extra_args = gir_init_section + [ '--c-include=gst/validate/validate.h' ]
  89     validate_gir = gnome.generate_gir(gstvalidate,
  90             sources : gstvalidate_sources + gstvalidate_headers + gst_validate_enums,
  91             nsversion : '1.0',
  92             namespace : 'GstValidate',
  93             symbol_prefix : 'gst_validate',
  94             identifier_prefix : 'GstValidate',
  95             export_packages : 'gst-validate-' + apiversion,
  96             includes : ['GObject-2.0',
  97                         'GLib-2.0',
  98                         'Gio-2.0',
  99                         'GModule-2.0',
 100                         'Gst-' + apiversion,
 101                         'GstPbutils-' + apiversion],
 102             install : true,
 103             dependencies : validate_deps,
 104             extra_args : gst_validate_gir_extra_args,
 105     )
 106     validate_gen_sources += [validate_gir]
 107 endif
 108
 109 validate_dep = declare_dependency(link_with : gstvalidate,
 110   include_directories : [inc_dirs],
 111   dependencies : validate_deps,
 112   sources : validate_gen_sources
 113 )
 114
 115 meson.override_dependency('gst-validate-1.0', validate_dep)
 116
 117 pkgconfig.generate(gstvalidatetracer, install_dir : plugins_pkgconfig_install_dir)