subprojects/gst-devtools/docs/meson.build

   1 build_hotdoc = false
   2
   3 if meson.is_cross_build()
   4     if get_option('doc').enabled()
   5         error('Documentation enabled but building the doc while cross building is not supported yet.')
   6     endif
   7
   8     message('Documentation not built as building it while cross building is not supported yet.')
   9     subdir_done()
  10 endif
  11
  12 if static_build
  13     if get_option('doc').enabled()
  14         error('Documentation enabled but not supported when building statically.')
  15     endif
  16
  17     message('Building statically, can\'t build the documentation')
  18     subdir_done()
  19 endif
  20
  21 if not build_gir
  22     if get_option('doc').enabled()
  23         error('Documentation enabled but introspection not built.')
  24     endif
  25
  26     message('Introspection not built, won\'t build documentation requiring it')
  27     subdir_done()
  28 endif
  29
  30 hotdoc_p = find_program('hotdoc', required: get_option('doc'))
  31 if not hotdoc_p.found()
  32     message('Hotdoc not found, not building the documentation')
  33     subdir_done()
  34 endif
  35
  36 required_hotdoc_extensions = ['gi-extension']
  37 hotdoc = import('hotdoc')
  38 foreach extension: required_hotdoc_extensions
  39     if not hotdoc.has_extensions(extension)
  40         if get_option('doc').enabled()
  41             error('Documentation enabled but @0@ missing'.format(extension))
  42         endif
  43
  44         message('@0@ extension not found, not building documentation'.format(extension))
  45         subdir_done()
  46     endif
  47 endforeach
  48
  49 excludes = ['gettext.h',
  50     'gst-validate-internal.h',
  51     'gst-validate-i18n-lib.c'
  52 ]
  53
  54 build_hotdoc = true
  55 validate_excludes = []
  56 foreach f: excludes
  57     validate_excludes += [join_paths(meson.current_source_dir(), '..',
  58         'validate', 'gst', 'validate', f)]
  59 endforeach
  60
  61 validate_sources = gstvalidate_headers + gstvalidate_sources
  62 hotdoc = import('hotdoc')
  63 plugins_doc = []
  64 libs_doc = [hotdoc.generate_doc('gst-devtools',
  65     project_version: apiversion,
  66     sitemap: 'sitemap.txt',
  67     index: 'index.md',
  68     gi_c_sources: validate_sources,
  69     gi_c_source_filters: validate_excludes,
  70     gi_index: 'gi-index.md',
  71     gi_smart_index: true,
  72     gi_sources: [validate_gir[0].full_path()],
  73     disable_incremental_build: true,
  74     dependencies : [validate_dep],
  75     depends: validate_gir[0],
  76 )]