subprojects/gst-devtools/debug-viewer/meson.build

   1 python3.install_sources (
   2     'GstDebugViewer/Main.py',
   3     'GstDebugViewer/Data.py',
   4     subdir: 'GstDebugViewer')
   5
   6 python3.install_sources (
   7     'GstDebugViewer/GUI/columns.py',
   8     'GstDebugViewer/GUI/__init__.py',
   9     'GstDebugViewer/GUI/models.py',
  10     'GstDebugViewer/GUI/filters.py',
  11     'GstDebugViewer/GUI/colors.py',
  12     'GstDebugViewer/GUI/window.py',
  13     'GstDebugViewer/GUI/app.py',
  14     subdir: 'GstDebugViewer/GUI')
  15
  16 python3.install_sources (
  17     'GstDebugViewer/Plugins/__init__.py',
  18     'GstDebugViewer/Plugins/FindBar.py',
  19     'GstDebugViewer/Plugins/Timeline.py',
  20     subdir: 'GstDebugViewer/Plugins')
  21
  22 python3.install_sources (
  23     'GstDebugViewer/Common/Main.py',
  24     'GstDebugViewer/Common/utils.py',
  25     'GstDebugViewer/Common/__init__.py',
  26     'GstDebugViewer/Common/generictreemodel.py',
  27     'GstDebugViewer/Common/Data.py',
  28     'GstDebugViewer/Common/GUI.py',
  29     subdir: 'GstDebugViewer/Common')
  30
  31 if find_program('msgfmt', required : get_option('nls')).found()
  32   # Desktop launcher and description file.
  33   desktop_file = i18n.merge_file(
  34     input: 'org.freedesktop.GstDebugViewer.desktop.in',
  35     output: 'org.freedesktop.GstDebugViewer.desktop',
  36     type: 'desktop',
  37     po_dir: 'po',
  38     install: true,
  39     install_dir: join_paths(get_option('datadir'), 'applications'),
  40   )
  41
  42   # Appdata file.
  43   appdata_file = i18n.merge_file(
  44     input: 'org.freedesktop.GstDebugViewer.appdata.xml.in',
  45     output: 'org.freedesktop.GstDebugViewer.appdata.xml',
  46     po_dir: 'po',
  47     install: true,
  48     install_dir: join_paths(get_option('datadir'), 'metainfo'),
  49   )
  50 else
  51   install_data('org.freedesktop.GstDebugViewer.desktop.in',
  52     rename: 'org.freedesktop.GstDebugViewer.desktop',
  53     install_dir: join_paths(get_option('datadir'), 'applications'))
  54   install_data('org.freedesktop.GstDebugViewer.appdata.xml.in',
  55     rename: 'org.freedesktop.GstDebugViewer.appdata.xml',
  56     install_dir: join_paths(get_option('datadir'), 'metainfo'))
  57 endif
  58
  59 cdata = configuration_data()
  60 cdata.set('LIBDIR', join_paths(get_option('prefix'), get_option('libdir')))
  61 cdata.set('DATADIR', join_paths(get_option('prefix'), get_option('datadir')))
  62 cdata.set('VERSION', meson.project_version())
  63
  64 configure_file(input: 'gst-debug-viewer',
  65                output: 'gst-debug-viewer',
  66                configuration: cdata,
  67                install_dir: get_option('bindir'))
  68
  69 init_file = configure_file(
  70     input: 'GstDebugViewer/__init__.py',
  71     output: '__init__.py',
  72     configuration: cdata)
  73 python3.install_sources (init_file, subdir: 'GstDebugViewer')
  74
  75 pkgdatadir = join_paths(get_option('datadir'), meson.project_name())
  76 icondir = join_paths(get_option('datadir'), 'icons/hicolor')
  77
  78 subdir('data')
  79
  80
  81 if run_command(python3, '-c', 'import gi; gi.require_version("Gtk", "3.0")', check: false).returncode() == 0
  82   test('gst-debug-viewer', python3, args: ['-m', 'unittest'],
  83       workdir: meson.current_source_dir())
  84 endif