pkgconfig/meson.build

   1 pkgconf = configuration_data()
   2
   3 pkgconf.set('prefix', get_option('prefix'))
   4 pkgconf.set('exec_prefix', '${prefix}')
   5 pkgconf.set('libdir', '${prefix}/@0@'.format(get_option('libdir')))
   6 pkgconf.set('includedir', '${prefix}/@0@'.format(get_option('includedir')))
   7 pkgconf.set('GST_API_VERSION', apiversion)
   8 pkgconf.set('VERSION', gst_version)
   9
  10 # needed for generating -uninstalled.pc files
  11 pkgconf.set('abs_top_builddir', join_paths(meson.current_build_dir(), '..'))
  12 pkgconf.set('abs_top_srcdir', join_paths(meson.current_source_dir(), '..'))
  13 pkgconf.set('gstlibdir', join_paths(meson.build_root(), libgst.outdir()))
  14 pkgconf.set('checklibdir', join_paths(meson.build_root(), gst_check.outdir()))
  15 pkgconf.set('baselibdir', join_paths(meson.build_root(), gst_base.outdir()))
  16 pkgconf.set('controllerlibdir', join_paths(meson.build_root(), gst_controller.outdir()))
  17 pkgconf.set('netlibdir', join_paths(meson.build_root(), gst_net.outdir()))
  18
  19 pkg_install_dir = '@0@/pkgconfig'.format(get_option('libdir'))
  20
  21 pkg_files = ['gstreamer-base',
  22   'gstreamer-check',
  23   'gstreamer-controller',
  24   'gstreamer-net',
  25   'gstreamer'
  26 ]
  27
  28 foreach p : pkg_files
  29   infile = p + '.pc.in'
  30   outfile = p + '-1.0.pc'
  31   configure_file(input : infile,
  32     output : outfile,
  33     configuration : pkgconf,
  34     install_dir : pkg_install_dir)
  35
  36   infile = p + '-uninstalled.pc.in'
  37   outfile = p + '-1.0-uninstalled.pc'
  38   configure_file(input : infile,
  39     output : outfile,
  40     configuration : pkgconf)
  41 endforeach