Move GstAggregator from -bad to core
[platform/upstream/gstreamer.git] / pkgconfig / meson.build
1 pkgconf = configuration_data()
2
3 pkgconf.set('prefix', join_paths(get_option('prefix')))
4 pkgconf.set('exec_prefix', '${prefix}')
5 pkgconf.set('libdir', '${prefix}/@0@'.format(get_option('libdir')))
6 pkgconf.set('includedir', '${prefix}/@0@'.format(get_option('includedir')))
7 pkgconf.set('GST_API_VERSION', apiversion)
8 pkgconf.set('VERSION', gst_version)
9 pkgconf.set('LIBM', mathlib.found() ? '-lm' : '')
10
11 # Requires.private
12 pkgconf.set('UNWIND_REQUIRE', cdata.has('HAVE_UNWIND') ? 'libunwind' : '')
13 pkgconf.set('DW_REQUIRE', cdata.has('HAVE_DW') ? 'libdw' : '')
14
15 # needed for generating -uninstalled.pc files
16 pkgconf.set('abs_top_builddir', join_paths(meson.current_build_dir(), '..'))
17 pkgconf.set('abs_top_srcdir', join_paths(meson.current_source_dir(), '..'))
18 pkgconf.set('gstlibdir', join_paths(meson.build_root(), libgst.outdir()))
19 pkgconf.set('baselibdir', join_paths(meson.build_root(), gst_base.outdir()))
20 pkgconf.set('controllerlibdir', join_paths(meson.build_root(), gst_controller.outdir()))
21 pkgconf.set('netlibdir', join_paths(meson.build_root(), gst_net.outdir()))
22
23 pkg_install_dir = '@0@/pkgconfig'.format(get_option('libdir'))
24
25 pkg_files = ['gstreamer-base',
26   'gstreamer-controller',
27   'gstreamer-net',
28   'gstreamer'
29 ]
30
31 if host_machine.system() != 'windows'
32     pkgconf.set('checklibdir', join_paths(meson.build_root(), gst_check.outdir()))
33     pkg_files += ['gstreamer-check']
34 endif
35
36 foreach p : pkg_files
37   infile = p + '.pc.in'
38   outfile = p + '-1.0.pc'
39   configure_file(input : infile,
40     output : outfile,
41     configuration : pkgconf,
42     install_dir : pkg_install_dir)
43
44   infile = p + '-uninstalled.pc.in'
45   outfile = p + '-1.0-uninstalled.pc'
46   configure_file(input : infile,
47     output : outfile,
48     configuration : pkgconf)
49 endforeach