pkgconfig/meson.build

   1 pkgconf = configuration_data()
   2
   3 pkgconf.set('prefix', get_option('prefix'))
   4 pkgconf.set('exec_prefix', '${prefix}')
   5 pkgconf.set('libdir', '${prefix}/@0@'.format(get_option('libdir')))
   6 pkgconf.set('includedir', '${prefix}/@0@'.format(get_option('includedir')))
   7 pkgconf.set('GST_API_VERSION', api_version)
   8 pkgconf.set('VERSION', gst_version)
   9
  10 # needed for generating -uninstalled.pc files
  11 pkgconf.set('abs_top_builddir', join_paths(meson.current_build_dir(), '..'))
  12 pkgconf.set('abs_top_srcdir', join_paths(meson.current_source_dir(), '..'))
  13 pkgconf.set('audiolibdir', join_paths(meson.build_root(), gstbadaudio.outdir()))
  14 pkgconf.set('baselibdir', join_paths(meson.build_root(), gstbadbase.outdir()))
  15 pkgconf.set('videolibdir', join_paths(meson.build_root(), gstbadvideo.outdir()))
  16 pkgconf.set('codecparserslibdir', join_paths(meson.build_root(), gstcodecparsers.outdir()))
  17 pkgconf.set('insertbinlibdir', join_paths(meson.build_root(), gstinsertbin.outdir()))
  18 pkgconf.set('mpegtslibdir', join_paths(meson.build_root(), gstmpegts.outdir()))
  19 pkgconf.set('playerlibdir', join_paths(meson.build_root(), gstplayer.outdir()))
  20 pkgconf.set('basecamerabinsrclibdir', join_paths(meson.build_root(), gstbasecamerabin.outdir()))
  21 pkgconf.set('photographylibdir', join_paths(meson.build_root(), gstphotography.outdir()))
  22
  23 pkg_install_dir = '@0@/pkgconfig'.format(get_option('libdir'))
  24
  25 pkg_libs = [
  26   'bad-audio',
  27   'bad-base',
  28   'bad-video',
  29   'codecparsers',
  30   'insertbin',
  31   'mpegts',
  32   'player',
  33   'plugins-bad',
  34 ]
  35
  36 # XXX: requires the meson.build to be parsed/executed after gst-libs/gl/meson.build
  37 if build_gstgl
  38   pkgconf.set('gllibdir', join_paths(meson.build_root(), gstgl.outdir()))
  39   pkg_libs += 'gl'
  40   pkgconf.set('GL_APIS', ' '.join(enabled_gl_apis))
  41   pkgconf.set('GL_WINDOWS', ' '.join(enabled_gl_winsys))
  42   pkgconf.set('GL_PLATFORMS', ' '.join(enabled_gl_platforms))
  43 endif
  44
  45 if use_wayland
  46     pkgconf.set('waylandlibdir', join_paths(meson.build_root(), gstwayland.outdir()))
  47     pkg_libs += 'wayland'
  48 endif
  49
  50 foreach p : pkg_libs
  51   infile = 'gstreamer-@0@.pc.in'.format(p)
  52   outfile = 'gstreamer-@0@-@1@.pc'.format(p, api_version)
  53   configure_file(input : infile,
  54     output : outfile,
  55     configuration : pkgconf,
  56     install_dir : pkg_install_dir)
  57
  58   infile = 'gstreamer-@0@-uninstalled.pc.in'.format(p)
  59   outfile = 'gstreamer-@0@-@1@-uninstalled.pc'.format(p, api_version)
  60   configure_file(input : infile,
  61     output : outfile,
  62     configuration : pkgconf)
  63 endforeach