meson.build

   1 project('gstreamer-full', 'c',
   2   version : '1.21.0.1',
   3   meson_version : '>= 0.60.0',
   4   default_options : ['buildtype=debugoptimized',
   5                      # Needed due to https://github.com/mesonbuild/meson/issues/1889,
   6                      # but this can cause problems in the future. Remove it
   7                      # when it's no longer necessary.
   8                      'cpp_std=c++14'])
   9
  10 apiversion = '1.0'
  11 gst_version = '>= @0@'.format(meson.project_version())
  12
  13 build_system = build_machine.system()
  14 cc = meson.get_compiler('c')
  15
  16 fs = import('fs')
  17 gnome = import('gnome')
  18 pkgconfig = import('pkgconfig')
  19 python3 = import('python').find_installation()
  20 # Ensure that we're not being run from inside the development environment
  21 # because that will confuse meson, and it might find the already-built
  22 # gstreamer. It's fine if people run `ninja` as long as it doesn't run
  23 # reconfigure because ninja doesn't care about the env.
  24 ensure_not_devenv = '''
  25 import os
  26 assert('GST_ENV' not in os.environ)
  27 '''
  28 cmdres = run_command(python3, '-c', ensure_not_devenv, check: false)
  29 if cmdres.returncode() != 0
  30   error('Do not run `ninja reconfigure` or `meson` for gst-build inside the development environment, you will run into problems')
  31 endif
  32
  33 # Install gst-indent pre-commit hook
  34 run_command(python3, '-c', 'import shutil; shutil.copy("scripts/git-hooks/multi-pre-commit.hook", ".git/hooks/pre-commit")', check: false)
  35
  36 # Ensure that the user does not have Strawberry Perl in PATH, since it ships
  37 # with a pkg-config.bat and broken pkgconfig files for libffi and zlib. Will
  38 # cause a build error, such as in
  39 # https://gitlab.freedesktop.org/gstreamer/gst-build/-/issues/41
  40 ensure_no_strawberry_perl = '''
  41 import os
  42 assert(r'Strawberry\perl\bin' not in os.environ['PATH'])
  43 '''
  44 if build_system == 'windows' and meson.version().version_compare('<0.60.0')
  45   cmdres = run_command(python3, '-c', ensure_no_strawberry_perl, check: false)
  46   if cmdres.returncode() != 0
  47     error('You have Strawberry Perl in PATH which is known to cause build issues with Meson < 0.60.0. Please remove it from PATH, uninstall it, or upgrade Meson.')
  48   endif
  49 endif
  50
  51 # On macOS, you have to run "Install Certificates.command" otherwise Python
  52 # doesn't have access to the latest SSL CA Certificates, and Meson will fail to
  53 # download wrap files from websites that use, for example, Let's Encrypt.
  54 # We already recommend this in the README, but add a warning here as well.
  55 # Can't make this an error because the user might be using XCode's Python
  56 # 3 which doesn't have this script.
  57 if build_system == 'darwin'
  58   python3_cacert_file = python3.get_path('data') / 'etc/openssl/cert.pem'
  59   install_cert_cmd = '/Applications/Python @0@/Install Certificates.command'.format(python3.language_version())
  60   if not fs.is_symlink(python3_cacert_file) and fs.is_file(install_cert_cmd)
  61     warning('Please run "@0@" so that Python has access to the latest SSL certificates. Meson might fail to download some wraps without it.'.format(install_cert_cmd))
  62   endif
  63 endif
  64
  65 documented_projects = ''
  66 # Make it possible to use msys2 built zlib which fails
  67 # when not using the mingw toolchain as it uses unistd.h
  68 if not meson.is_subproject() and cc.get_id() == 'msvc'
  69   uname = find_program('uname', required: false)
  70   if uname.found()
  71     ret = run_command(uname, '-o', check: false)
  72     if ret.returncode() == 0 and ret.stdout().to_lower() == 'msys'
  73       ret = run_command(uname, '-r', check: false)
  74       # The kernel version returned by uname is actually the msys version
  75       if ret.returncode() == 0 and ret.stdout().startswith('2')
  76         # If a system zlib is found, disable UNIX features in zlib.h and zconf.h
  77         if cc.find_library('z').found()
  78           add_global_arguments('-DZ_SOLO', language: 'c')
  79         endif
  80       endif
  81     endif
  82   endif
  83 endif
  84
  85 # Ensure that MSVC interprets all source code as UTF-8. Only do this when we're
  86 # not a subproject, because subprojects are not allowed to call
  87 # add_global_arguments().
  88 if not meson.is_subproject() and cc.get_id() == 'msvc'
  89   add_global_arguments(
  90       cc.get_supported_arguments(['/utf-8']), # set the input encoding to utf-8
  91       language: ['c', 'cpp'])
  92 endif
  93
  94 building_full = get_option('default_library') == 'static'
  95 tools_option = 'tools=auto'
  96 if building_full and not get_option('tools').disabled()
  97   # Do not build subprojects tools when we build them against gst-full
  98   tools_option = 'tools=disabled'
  99 endif
 100
 101 # Ordered list of subprojects (dict has no ordering guarantees)
 102 subprojects = [
 103   ['gstreamer', {'build-hotdoc': true, 'subproject_options': [tools_option]}],
 104   ['gst-plugins-base', {'option': get_option('base'), 'build-hotdoc': true}],
 105   ['gst-plugins-good', {'option': get_option('good'), 'build-hotdoc': true}],
 106   ['libnice', { 'option': get_option('libnice'), 'match_gst_version': false}],
 107   ['gst-plugins-bad', { 'option': get_option('bad'), 'build-hotdoc': true}],
 108   ['gst-plugins-ugly', { 'option': get_option('ugly'), 'build-hotdoc': true}],
 109   ['gst-libav', { 'option': get_option('libav'), 'build-hotdoc': true}],
 110   ['gst-rtsp-server', { 'option': get_option('rtsp_server'), 'build-hotdoc': true}],
 111   ['gst-devtools', { 'option': get_option('devtools'), 'build-hotdoc': true, 'subproject_options': [tools_option]}],
 112   ['gst-integration-testsuites', { 'option': get_option('devtools') }],
 113   ['gst-editing-services', { 'option': get_option('ges'), 'build-hotdoc': true, 'subproject_options': [tools_option]}],
 114   ['gstreamer-vaapi', { 'option': get_option('vaapi'), 'build-hotdoc': true}],
 115   ['gst-omx', { 'option': get_option('omx'), 'build-hotdoc': true}],
 116   ['gstreamer-sharp', { 'option': get_option('sharp') }],
 117   ['pygobject', { 'option': get_option('python'), 'match_gst_version': false, 'sysdep': 'pygobject-3.0', 'sysdep_version': '>= 3.8' }],
 118   ['gst-python', { 'option': get_option('python')}],
 119   ['gst-examples', { 'option': get_option('gst-examples'), 'match_gst_versions': false}],
 120   ['gst-plugins-rs', { 'option': get_option('rs'), 'match_gst_version': false}],
 121 ]
 122
 123 symlink = '''
 124 import os
 125
 126 os.symlink(os.path.join('@1@', 'subprojects', '@0@'),
 127   os.path.join('@1@', '@0@'))
 128 '''
 129
 130 if build_system == 'windows'
 131   subproject('win-flex-bison-binaries')
 132   subproject('win-nasm')
 133 elif build_system == 'darwin'
 134   subproject('macos-bison-binary')
 135 endif
 136
 137 orc_subproject = subproject('orc', required: get_option('orc'))
 138
 139 foreach custom_subproj: get_option('custom_subprojects').split(',')
 140     if custom_subproj != ''
 141         message ('Adding custom subproject ' + custom_subproj)
 142         subprojects += [[custom_subproj, {'match_gst_version': false}]]
 143     endif
 144 endforeach
 145
 146
 147 subprojects_names = []
 148 plugins_doc_caches = []
 149 orc_update_targets = []
 150 all_plugins = []
 151 all_tools = {}
 152 # Using a list and not a dict to keep the ordering to build the chain of `gir`
 153 # dependencies
 154 all_libraries = []
 155 foreach sp : subprojects
 156   project_name = sp[0]
 157   build_infos = sp[1]
 158   is_required = build_infos.get('option', true)
 159   sysdep = build_infos.get('sysdep', '')
 160   sysdep_version = build_infos.get('sysdep_version', '')
 161   match_gst_version = build_infos.get('match_gst_version', true)
 162   default_options =  build_infos.get('subproject_options', [])
 163
 164   if match_gst_version
 165     subproj = subproject(project_name, version: gst_version, required: is_required, default_options: default_options)
 166   elif sysdep != ''
 167       sysdep_dep = dependency(sysdep, version: sysdep_version, required: false, default_options: default_options)
 168       if not sysdep_dep.found()
 169         subproj = subproject(project_name, required: is_required, default_options: default_options)
 170       endif
 171   else
 172     subproj = subproject(project_name, required: is_required, default_options: default_options)
 173   endif
 174
 175   if subproj.found()
 176     plugins = subproj.get_variable('plugins', [])
 177     all_plugins += plugins
 178     all_libraries += subproj.get_variable('libraries', [])
 179     if not get_option('tools').disabled()
 180       all_tools += subproj.get_variable('gst_tools', {})
 181     endif
 182
 183     orc_update_targets += subproj.get_variable('orc_update_targets', [])
 184
 185     subprojects_names += [project_name]
 186
 187     if not meson.is_cross_build() and build_infos.get('build-hotdoc', false)
 188       if plugins.length() > 0
 189         plugins_doc_caches += [subproj.get_variable('plugins_doc_dep', [])]
 190       endif
 191       if documented_projects != ''
 192         documented_projects += ','
 193       endif
 194       documented_projects  += project_name
 195     endif
 196   endif
 197 endforeach
 198
 199 # Check if we need to also build glib-networking for TLS modules
 200 glib_dep = dependency('glib-2.0')
 201 if glib_dep.type_name() == 'internal'
 202   subproject('glib-networking', required : get_option('tls'),
 203              default_options: ['gnutls=auto', 'openssl=auto'])
 204 endif
 205
 206 plugins_doc_dep = custom_target('plugins-doc-cache',
 207   command: [python3, '-c', 'print("Built all doc caches")'],
 208   input: plugins_doc_caches,
 209   output: 'plugins_doc_caches',
 210   capture: true,
 211 )
 212
 213 if meson.is_cross_build() or build_machine.system() == 'windows'
 214     if get_option('doc').enabled()
 215         error('Documentation enabled but building the doc while cross building or building on windows is not supported yet.')
 216     endif
 217
 218     documented_projects = ''
 219     message('Documentation not built as building the documentation while cross building or building on windows is not supported yet.')
 220 else
 221   hotdoc_p = find_program('hotdoc', required : get_option('doc'))
 222   if not hotdoc_p.found()
 223     documented_projects = ''
 224     message('Not building documentation as hotdoc was not found')
 225   endif
 226 endif
 227
 228 write_file_contents = '''
 229 import os
 230 import sys
 231
 232 assert len(sys.argv) >= 3
 233 fname = sys.argv[1]
 234 contents = sys.argv[2]
 235
 236 with open(fname, 'w') as f:
 237     f.write(contents)
 238 '''
 239
 240 configure_file(
 241   output : 'GstDocumentedSubprojects',
 242   command : [python3,
 243              '-c', write_file_contents,
 244              '@OUTPUT@',
 245              documented_projects]
 246 )
 247
 248 if documented_projects != ''
 249   subproject('gst-docs', required: get_option('doc').enabled())
 250   message('Gst docs subprojects: ' + documented_projects)
 251 endif
 252
 253 all_plugins_paths = []
 254 all_plugins_dirs = []
 255 foreach plugin: all_plugins
 256   all_plugins_paths += plugin.full_path()
 257   all_plugins_dirs += fs.parent(plugin.full_path())
 258 endforeach
 259 # Work around meson bug: https://github.com/mesonbuild/meson/pull/6770
 260 pathsep = host_machine.system() == 'windows' ? ';' : ':'
 261 all_plugins_paths = pathsep.join(all_plugins_paths)
 262
 263 devenv = environment()
 264 if not building_full
 265   devenv.prepend('GST_PLUGIN_PATH', all_plugins_dirs)
 266 else
 267   # Make sure the current build directory is first in PATH so we prefer tools
 268   # built here that links on gst-full instead instead of those built in
 269   # subprojects.
 270   devenv.prepend('PATH', meson.current_build_dir())
 271 endif
 272 devenv.set('CURRENT_GST', meson.current_source_dir())
 273 devenv.set('GST_VERSION', meson.project_version())
 274 devenv.set('GST_ENV', 'gst-' + meson.project_version())
 275 devenv.set('GST_REGISTRY', meson.current_build_dir() / 'registry.dat')
 276 devenv.set('GST_PLUGIN_SYSTEM_PATH', '')
 277 meson.add_devenv(devenv)
 278
 279 generate_plugins_paths = find_program('scripts/generate_plugins_path.py')
 280 configure_file(
 281   output : 'GstPluginsPath.json',
 282   command : [generate_plugins_paths,
 283              '@OUTPUT@',
 284              all_plugins_paths]
 285 )
 286
 287 if building_full
 288   cdata = configuration_data()
 289   cdata.set_quoted('GST_API_VERSION', apiversion)
 290   cdata.set_quoted('GETTEXT_PACKAGE', 'gstreamer-full-1.0')
 291   cdata.set_quoted('PACKAGE_VERSION', gst_version)
 292   cdata.set_quoted('GST_PACKAGE_ORIGIN', get_option('package-origin'))
 293   configure_file(output : 'config.h', configuration : cdata)
 294   configinc = include_directories('.')
 295   gst_c_args = ['-DHAVE_CONFIG_H']
 296
 297   # Generate a .c file which declare and register all built plugins
 298   plugins_names = []
 299   foreach plugin: all_plugins
 300     plugins_names += plugin.full_path()
 301   endforeach
 302   all_plugin_names = ';'.join(plugins_names)
 303
 304   static_plugins = get_option('gst-full-plugins')
 305   if static_plugins == '*'
 306     static_plugins = all_plugin_names
 307   endif
 308   generate_init_static_plugins = find_program('scripts/generate_init_static_plugins.py')
 309   init_static_plugins_c = configure_file(
 310     output: 'gstinitstaticplugins.c',
 311     command : [generate_init_static_plugins,
 312                '-o ' + '@OUTPUT@',
 313                '-p ' + static_plugins,
 314                '-e ' + get_option('gst-full-elements'),
 315                '-t ' + get_option('gst-full-typefind-functions'),
 316                '-d ' + get_option('gst-full-device-providers'),
 317                '-T ' + get_option('gst-full-dynamic-types')
 318                ]
 319   )
 320
 321   gstfull_link_args = cc.get_supported_link_arguments(['-Wl,-Bsymbolic-functions'])
 322
 323   # Get a list of libraries that needs to be exposed in the ABI.
 324   exposed_libs = []
 325   exposed_deps = []
 326   exposed_girs = []
 327   incdir_deps = []
 328   wanted_libs = ['gstreamer-1.0'] + get_option('gst-full-libraries')
 329   all_libs = '*' in wanted_libs
 330
 331   foreach pkgname_library : all_libraries
 332     pkg_name = pkgname_library[0]
 333     lib_def = pkgname_library[1]
 334
 335     if pkg_name in wanted_libs or all_libs
 336       if lib_def.has_key('lib')
 337         exposed_deps += dependency(pkg_name)
 338         incdir_deps += dependency(pkg_name).partial_dependency(includes: true, sources: true)
 339         exposed_libs += [lib_def['lib']]
 340       endif
 341
 342       if lib_def.has_key('gir')
 343         exposed_girs += lib_def['gir']
 344       endif
 345     endif
 346   endforeach
 347
 348   # glib and gobject are part of our public API. If we are using glib from the
 349   # system then our pkg-config file must require it. If we built it as
 350   # subproject then we need to link_whole it.
 351   glib_deps = []
 352   glib_dep = dependency('glib-2.0')
 353   gobject_dep = dependency('gobject-2.0')
 354   if gobject_dep.type_name() == 'internal'
 355     glib_subproject = subproject('glib')
 356     exposed_libs += glib_subproject.get_variable('libglib')
 357     exposed_libs += glib_subproject.get_variable('libgobject')
 358     incdir_deps += [
 359       glib_dep.partial_dependency(includes: true),
 360       gobject_dep.partial_dependency(includes: true),
 361     ]
 362   else
 363     glib_deps = [glib_dep, gobject_dep]
 364   endif
 365
 366   link_deps = []
 367   if get_option('gst-full-version-script') != ''
 368     symbol_map = meson.current_source_dir() / get_option('gst-full-version-script')
 369     link_arg = '-Wl,--version-script=' + symbol_map
 370     if cc.has_link_argument(link_arg)
 371       gstfull_link_args += link_arg
 372       link_deps += symbol_map
 373     elif cc.get_id() == 'msvc'
 374       warning('FIXME: Provide a def file to publish the public symbols')
 375     else
 376       warning('FIXME: Linker does not support the supplied version script (' + symbol_map + '), please disable the "gst-full-version-script" option')
 377     endif
 378   endif
 379
 380   # Build both shared and static library
 381   gstfull = both_libraries('gstreamer-full-1.0',
 382     init_static_plugins_c,
 383     link_with : all_plugins,
 384     link_args: gstfull_link_args,
 385     link_whole : exposed_libs,
 386     dependencies : incdir_deps + glib_deps,
 387     link_depends : link_deps,
 388     install : true,
 389   )
 390
 391   gst_full_dep = declare_dependency(link_with: gstfull.get_shared_lib(),
 392     dependencies : incdir_deps + glib_deps,
 393     include_directories: include_directories('.')
 394   )
 395
 396   gst_full_libs_private = cc.get_supported_link_arguments(['-Wl,--undefined=gst_init_static_plugins'])
 397   if gst_full_libs_private == []
 398     warning('The compiler does not support `-Wl,--undefined` linker flag. The method `gst_init_static_plugins` might be dropped during the link stage of an application using libgstreamer-full-1.0.a, preventing plugins registration.')
 399   endif
 400
 401   if not get_option('introspection').disabled()
 402     built_girs = {}
 403     foreach gir: exposed_girs
 404       includes = []
 405       foreach include: gir.get('includes', [])
 406         includes += [built_girs.get(include, include)]
 407       endforeach
 408
 409       gir += {
 410         'includes': includes,
 411         'extra_args': gir.get('extra_args', []) + ['--add-include-path=' + meson.current_build_dir()],
 412         'install': true,
 413       }
 414       built_girs += {gir.get('namespace') + '-' + gir.get('nsversion'): gnome.generate_gir(gstfull, kwargs: gir)[0]}
 415     endforeach
 416   endif
 417
 418   pkgconfig.generate(gstfull,
 419     requires: glib_deps,
 420     libraries_private: gst_full_libs_private,
 421     subdirs : 'gstreamer-1.0')
 422   meson.override_dependency('gstreamer-full-1.0', gst_full_dep)
 423
 424   if not get_option('tools').disabled()
 425     foreach tool, data: all_tools
 426       exe_name = '@0@-@1@'.format(tool, apiversion)
 427       extra_args = data.get('extra_c_args', [])
 428       sources = data.get('files')
 429       deps = []
 430       foreach d : data.get('deps', [])
 431         if d not in exposed_deps
 432           deps += d
 433         endif
 434       endforeach
 435
 436       executable(exe_name,
 437         sources,
 438         install: true,
 439         include_directories : [configinc],
 440         dependencies : [gst_full_dep] + deps,
 441         c_args: extra_args + gst_c_args + ['-DG_LOG_DOMAIN="@0@"'.format(exe_name)],
 442       )
 443
 444       if data.has_key('man_page')
 445         install_man(data.get('man_page'))
 446       endif
 447
 448     endforeach
 449   endif
 450 endif
 451
 452 message('Building subprojects: ' + ', '.join(subprojects_names))
 453
 454 setenv = find_program('gst-env.py')
 455
 456 devenv_cmd = [setenv, '--builddir=@0@'.format(meson.global_build_root()),
 457               '--srcdir=@0@'.format(meson.global_source_root())]
 458
 459 subdir('tests')
 460 subdir('ci/fuzzing')
 461
 462 if meson.can_run_host_binaries() and build_machine.system() == 'linux' and host_machine.system() == 'windows'
 463   # FIXME: Ideally we could get the wrapper directly from meson
 464   devenv_cmd += ['--wine', host_machine.cpu_family() == 'x86_64' ? 'wine64' : 'wine32']
 465   sysroot = meson.get_cross_property('sys_root')
 466   if sysroot != ''
 467     # Logic from meson
 468     devenv_cmd += ['--winepath', 'Z:' + join_paths(sysroot, 'bin')]
 469   endif
 470 endif
 471
 472 run_target('devenv', command : devenv_cmd)
 473
 474 if orc_subproject.found() and orc_update_targets.length() > 0
 475   alias_target('update-orc-dist', orc_update_targets)
 476 endif
 477
 478 dotnet_format = find_program('dotnet-format', required: false)
 479 if dotnet_format.found()
 480     run_target('csharp_format_check',
 481         command: [join_paths(meson.current_source_dir(), 'scripts', 'format-csharp'),
 482             '--check'
 483         ],
 484     )
 485     run_target('csharp_format_apply',
 486         command: [join_paths(meson.current_source_dir(), 'scripts', 'format-csharp'),
 487         ],
 488     )
 489 endif
 490
 491 summary({
 492   'gstreamer-full library': building_full,
 493 }, section: 'Build options', bool_yn: true, list_sep: '  ')
 494
 495 gst_tools = []
 496 foreach tool, data: all_tools
 497   gst_tools += tool
 498 endforeach
 499
 500 summary({
 501     'Tools': gst_tools,
 502 }, section: 'Build options', list_sep: ', ')