meson.build

   1 project('gstreamer', 'c',
   2   version : '1.15.0.1',
   3   meson_version : '>= 0.47',
   4   default_options : [ 'warning_level=1',
   5                       'buildtype=debugoptimized' ])
   6
   7 gst_version = meson.project_version()
   8 version_arr = gst_version.split('.')
   9 gst_version_major = version_arr[0].to_int()
  10 gst_version_minor = version_arr[1].to_int()
  11 gst_version_micro = version_arr[2].to_int()
  12 if version_arr.length() == 4
  13   gst_version_nano = version_arr[3].to_int()
  14 else
  15   gst_version_nano = 0
  16 endif
  17
  18 host_system = host_machine.system()
  19
  20 apiversion = '1.0'
  21 soversion = 0
  22 # maintaining compatibility with the previous libtool versioning
  23 # current = minor * 100 + micro
  24 libversion = '@0@.@1@.0'.format(soversion, gst_version_minor * 100 + gst_version_micro)
  25
  26 prefix = get_option('prefix')
  27
  28 libexecdir = get_option('libexecdir')
  29 helpers_install_dir = join_paths(libexecdir, 'gstreamer-1.0')
  30
  31 cc = meson.get_compiler('c')
  32
  33 # Ignore several spurious warnings for things gstreamer does very commonly
  34 # If a warning is completely useless and spammy, use '/wdXXXX' to suppress it
  35 # If a warning is harmless but hard to fix, use '/woXXXX' so it's shown once
  36 # NOTE: Only add warnings here if you are sure they're spurious
  37 if cc.get_id() == 'msvc'
  38   add_project_arguments(
  39       '/wd4018', # implicit signed/unsigned conversion
  40       '/wd4146', # unary minus on unsigned (beware INT_MIN)
  41       '/wd4244', # lossy type conversion (e.g. double -> int)
  42       '/wd4305', # truncating type conversion (e.g. double -> float)
  43       language : 'c')
  44 elif cc.has_link_argument('-Wl,-Bsymbolic-functions')
  45   # FIXME: Add an option for this if people ask for it
  46   add_project_link_arguments('-Wl,-Bsymbolic-functions', language : 'c')
  47 endif
  48
  49 # Symbol visibility
  50 have_visibility_hidden = cc.has_argument('-fvisibility=hidden')
  51 if have_visibility_hidden
  52   add_project_arguments('-fvisibility=hidden', language: 'c')
  53 endif
  54
  55 # Disable strict aliasing
  56 if cc.has_argument('-fno-strict-aliasing')
  57   add_project_arguments('-fno-strict-aliasing', language: 'c')
  58 endif
  59
  60 cdata = configuration_data()
  61 cdata.set_quoted('GST_API_VERSION', apiversion)
  62 cdata.set_quoted('GST_DATADIR', join_paths(prefix, get_option('datadir')))
  63 cdata.set_quoted('LOCALEDIR', join_paths(prefix, get_option('localedir')))
  64 cdata.set_quoted('LIBDIR', join_paths(prefix, get_option('libdir')))
  65 cdata.set_quoted('GST_API_VERSION', '1.0')
  66 cdata.set_quoted('GETTEXT_PACKAGE', 'gstreamer-1.0')
  67 cdata.set_quoted('GST_LICENSE', 'LGPL')
  68 cdata.set_quoted('PACKAGE', 'gstreamer')
  69 cdata.set_quoted('PACKAGE_NAME', 'GStreamer')
  70 cdata.set_quoted('PACKAGE_STRING', 'GStreamer @0@'.format(gst_version))
  71 cdata.set_quoted('PACKAGE_TARNAME', 'gstreamer')
  72 cdata.set_quoted('PACKAGE_BUGREPORT', 'http://bugzilla.gnome.org/enter_bug.cgi?product=GStreamer')
  73 cdata.set_quoted('PACKAGE_URL', '')
  74 cdata.set_quoted('PACKAGE_VERSION', gst_version)
  75 cdata.set_quoted('PLUGINDIR', join_paths(get_option('prefix'), get_option('libdir'), 'gstreamer-1.0'))
  76 cdata.set_quoted('VERSION', gst_version)
  77 cdata.set_quoted('GST_PLUGIN_SCANNER_INSTALLED', join_paths(prefix, helpers_install_dir, 'gst-plugin-scanner'))
  78 cdata.set_quoted('GST_PTP_HELPER_INSTALLED', join_paths(prefix, helpers_install_dir, 'gst-ptp-helper'))
  79 cdata.set_quoted('GST_PLUGIN_SCANNER_SUBDIR', libexecdir,
  80   description: 'libexecdir path component, used to find plugin-scanner on relocatable builds on windows')
  81 cdata.set('GST_DISABLE_OPTION_PARSING', not get_option('option-parsing'))
  82
  83 mem_align_opt = get_option('memory-alignment')
  84 if mem_align_opt == 'malloc'
  85   cdata.set('MEMORY_ALIGNMENT_MALLOC', 1)
  86 elif mem_align_opt == 'pagesize'
  87   cdata.set('MEMORY_ALIGNMENT_PAGESIZE', 1)
  88 else
  89   cdata.set('MEMORY_ALIGNMENT', mem_align_opt.to_int())
  90 endif
  91
  92 if host_system == 'darwin'
  93   cdata.set_quoted('GST_EXTRA_MODULE_SUFFIX', '.dylib')
  94 endif
  95
  96 if gst_version_nano > 0
  97     # Have GST_ERROR message printed when running from git
  98     cdata.set('GST_LEVEL_DEFAULT', 'GST_LEVEL_ERROR')
  99 else
 100     cdata.set('GST_LEVEL_DEFAULT', 'GST_LEVEL_NONE')
 101 endif
 102
 103 # GStreamer package name and origin url
 104 gst_package_name = get_option('package-name')
 105 if gst_package_name == ''
 106   if gst_version_nano == 0
 107     gst_package_name = 'GStreamer source release'
 108   elif gst_version_nano == 1
 109     gst_package_name = 'GStreamer git'
 110   else
 111     gst_package_name = 'GStreamer prerelease'
 112   endif
 113 endif
 114 cdata.set_quoted('GST_PACKAGE_NAME', gst_package_name)
 115 cdata.set_quoted('GST_PACKAGE_ORIGIN', get_option('package-origin'))
 116
 117 # These are only needed/used by the ABI tests
 118 host_defines = [
 119   [ 'x86', 'HAVE_CPU_I386' ],
 120   [ 'x86_64', 'HAVE_CPU_X86_64' ],
 121   [ 'arm', 'HAVE_CPU_ARM' ],
 122   [ 'aarch64', 'HAVE_CPU_AARCH64' ],
 123   [ 'mips', 'HAVE_CPU_MIPS' ],
 124   [ 'powerpc', 'HAVE_CPU_PPC' ],
 125   [ 'powerpc64', 'HAVE_CPU_PPC64' ],
 126   [ 'alpha', 'HAVE_CPU_ALPHA' ],
 127   [ 'sparc', 'HAVE_CPU_SPARC' ],
 128   [ 'ia64', 'HAVE_CPU_IA64' ],
 129   [ 'hppa', 'HAVE_CPU_HPPA' ],
 130   [ 'm68k', 'HAVE_CPU_M68K' ],
 131   [ 's390', 'HAVE_CPU_S390' ],
 132 ]
 133 foreach h : host_defines
 134   if h.get(0) == host_machine.cpu()
 135     cdata.set(h.get(1), 1)
 136   endif
 137 endforeach
 138 # FIXME: should really be called HOST_CPU or such
 139 cdata.set_quoted('TARGET_CPU', host_machine.cpu())
 140
 141 check_headers = [
 142   'dlfcn.h',
 143   'inttypes.h',
 144   'memory.h',
 145   'poll.h',
 146   'stdint.h',
 147   'stdio_ext.h',
 148   'strings.h',
 149   'string.h',
 150   'sys/param.h',
 151   'sys/poll.h',
 152   'sys/prctl.h',
 153   'sys/socket.h',
 154   'sys/stat.h',
 155   'sys/times.h',
 156   'sys/time.h',
 157   'sys/types.h',
 158   'sys/utsname.h',
 159   'sys/wait.h',
 160   'ucontext.h',
 161   'unistd.h',
 162   'valgrind/valgrind.h',
 163   'sys/resource.h',
 164 ]
 165
 166 if host_system == 'windows'
 167   check_headers += ['winsock2.h']
 168 endif
 169
 170 foreach h : check_headers
 171   if cc.has_header(h)
 172     define = 'HAVE_' + h.underscorify().to_upper()
 173     cdata.set(define, 1)
 174   endif
 175 endforeach
 176
 177 if cc.has_member('struct tm', 'tm_gmtoff', prefix : '#include <time.h>')
 178   cdata.set('HAVE_TM_GMTOFF', 1)
 179 endif
 180
 181 check_functions = [
 182   'gmtime_r',
 183   'sigaction',
 184   'getrusage',
 185   'fseeko',
 186   'ftello',
 187   'poll',
 188   'ppoll',
 189   'pselect',
 190   'getpagesize',
 191   'clock_gettime',
 192   # These are needed by libcheck
 193   'getline',
 194   'mkstemp',
 195   'alarm',
 196   'gettimeofday',
 197 ]
 198
 199 foreach f : check_functions
 200   if cc.has_function(f)
 201     define = 'HAVE_' + f.underscorify().to_upper()
 202     cdata.set(define, 1)
 203   endif
 204 endforeach
 205
 206 if cc.has_function('localtime_r', prefix : '#include<time.h>')
 207   cdata.set('HAVE_LOCALTIME_R', 1)
 208   # Needed by libcheck
 209   cdata.set('HAVE_DECL_LOCALTIME_R', 1)
 210 endif
 211
 212 if cc.links('''#include <pthread.h>
 213                int main() {
 214                  pthread_setname_np("example"); return 0;
 215                }''', name : 'pthread_setname_np(const char*)')
 216   cdata.set('HAVE_PTHREAD_SETNAME_NP_WITHOUT_TID', 1)
 217 endif
 218
 219 # Check for posix timers and the monotonic clock
 220 time_prefix = '#include <time.h>\n'
 221 if cdata.has('HAVE_UNISTD_H')
 222   time_prefix += '#include <unistd.h>'
 223 endif
 224
 225 posix_timers_src = time_prefix + '''
 226 #if !defined(_POSIX_TIMERS) || _POSIX_TIMERS < 0 || !defined(CLOCK_REALTIME)
 227 #error Either _POSIX_TIMERS or CLOCK_REALTIME not defined
 228 #endif
 229 '''
 230 if cc.compiles(posix_timers_src, name : 'posix timers from time.h')
 231   cdata.set('HAVE_POSIX_TIMERS', 1)
 232 endif
 233
 234 monotonic_clock_src = time_prefix + '''
 235 #if !defined(_POSIX_MONOTONIC_CLOCK) || _POSIX_MONOTONIC_CLOCK < 0 || !defined(CLOCK_MONOTONIC)
 236 #error Either _POSIX_MONOTONIC_CLOCK or CLOCK_MONOTONIC not defined
 237 #endif
 238 '''
 239 if cc.compiles(monotonic_clock_src, name : 'monotonic clock from time.h')
 240   cdata.set('HAVE_MONOTONIC_CLOCK', 1)
 241 endif
 242
 243 # Check for __uint128_t (gcc) by checking for 128-bit division
 244 uint128_t_src = '''int main() {
 245 static __uint128_t v1 = 100;
 246 static __uint128_t v2 = 10;
 247 static __uint128_t u;
 248 u = v1 / v2;
 249 }'''
 250 if cc.compiles(uint128_t_src, name : '__uint128_t available')
 251   cdata.set('HAVE_UINT128_T', 1)
 252 endif
 253
 254 # All supported platforms have long long now
 255 cdata.set('HAVE_LONG_LONG', 1)
 256
 257 # We only want to use the __declspec(dllexport/import) dance in GST_EXPORT when
 258 # building with MSVC
 259 if cc.get_id() == 'msvc'
 260   cdata.set('GSTCONFIG_BUILT_WITH_MSVC', 1)
 261 else
 262   cdata.set('GSTCONFIG_BUILT_WITH_MSVC', 0)
 263 endif
 264
 265 # -------------------------------------------------------------------------------------
 266 # config.h things needed by libcheck
 267 # -------------------------------------------------------------------------------------
 268 if cc.has_function('getpid')
 269   cdata.set('HAVE_GETPID', 1)
 270 elif host_system == 'windows' and cc.has_function('_getpid')
 271   cdata.set('HAVE_PROCESS_H', 1) # Used by gstreamer too
 272   cdata.set('HAVE__GETPID', 1)
 273 endif
 274 if cc.has_function('strdup')
 275   cdata.set('HAVE_DECL_STRDUP', 1)
 276 elif host_system == 'windows' and cc.has_function('_strdup')
 277   cdata.set('HAVE__STRDUP', 1) # Windows (MSVC)
 278 endif
 279 if host_system != 'windows'
 280   cdata.set('HAVE_FORK', 1)
 281 else
 282   # libcheck requires HAVE_FORK to be 0 when fork() is not available
 283   cdata.set('HAVE_FORK', 0)
 284 endif
 285 if cc.has_function('strsignal')
 286   cdata.set('HAVE_DECL_STRSIGNAL', 1)
 287 endif
 288 # Check for availability of types
 289 if not cc.has_type('clockid_t', prefix : '#include <time.h>')
 290   cdata.set('clockid_t', 'int')
 291 endif
 292 if not cc.has_type('timer_t', prefix : '#include <time.h>')
 293   cdata.set('timer_t', 'int')
 294 endif
 295 if not cc.has_members('struct timespec', 'tv_sec', 'tv_nsec',
 296                       prefix : '#include <time.h>')
 297   cdata.set('STRUCT_TIMESPEC_DEFINITION_MISSING', 1)
 298 endif
 299 if not cc.has_members('struct itimerspec', 'it_interval', 'it_value',
 300                       prefix : '#include <time.h>')
 301   cdata.set('STRUCT_ITIMERSPEC_DEFINITION_MISSING', 1)
 302 endif
 303
 304 # Platform deps; only ws2_32 and execinfo for now
 305 platform_deps = []
 306 if host_system == 'windows'
 307   platform_deps = [cc.find_library('ws2_32')]
 308 endif
 309
 310 backtrace_deps = []
 311 unwind_dep = dependency('libunwind', required : get_option('libunwind'))
 312 dw_dep = dependency('libdw', required: get_option('libunwind'))
 313 backtrace_deps = [unwind_dep, dw_dep]
 314 if unwind_dep.found()
 315   cdata.set('HAVE_UNWIND', 1)
 316   if dw_dep.found()
 317     cdata.set('HAVE_DW', 1)
 318   else
 319     message('Support for backtraces is partial only.')
 320   endif
 321 else
 322   if cc.has_function('backtrace')
 323     cdata.set('HAVE_BACKTRACE', 1)
 324   else
 325       message('NO backtraces support.')
 326   endif
 327 endif
 328
 329 if cc.has_header('execinfo.h')
 330   if cc.has_function('backtrace', prefix : '#include <execinfo.h>')
 331     cdata.set('HAVE_BACKTRACE', 1)
 332   else
 333     execinfo_dep = cc.find_library('execinfo', required : false)
 334     if execinfo_dep.found() and cc.has_function('backtrace', prefix : '#include <execinfo.h>', dependencies : execinfo_dep)
 335       cdata.set('HAVE_BACKTRACE', 1)
 336       platform_deps += execinfo_dep
 337     endif
 338   endif
 339 endif
 340
 341 gst_debug = get_option('gst_debug')
 342 if not gst_debug
 343   add_project_arguments(['-Wno-unused'], language: 'c')
 344 endif
 345
 346 warning_flags = [
 347   '-Wmissing-declarations',
 348   '-Wmissing-prototypes',
 349   '-Wredundant-decls',
 350   '-Wundef',
 351   '-Wwrite-strings',
 352   '-Wformat',
 353   '-Wformat-nonliteral',
 354   '-Wformat-security',
 355   '-Wold-style-definition',
 356   '-Winit-self',
 357   '-Wmissing-include-dirs',
 358   '-Waddress',
 359   '-Waggregate-return',
 360   '-Wno-multichar',
 361   '-Wnested-externs',
 362   '-Wdeclaration-after-statement',
 363   '-Wvla',
 364   '-Wpointer-arith',
 365 ]
 366
 367 foreach extra_arg : warning_flags
 368   if cc.has_argument (extra_arg)
 369     add_project_arguments([extra_arg], language: 'c')
 370   endif
 371 endforeach
 372
 373 # Used by the gstutils test
 374 gmp_dep = cc.find_library('gmp', required : false)
 375 cdata.set('HAVE_GMP', gmp_dep.found())
 376 gsl_dep = cc.find_library('gsl', required : false)
 377 gslcblas_dep = cc.find_library('gslcblas', required : false)
 378 cdata.set('HAVE_GSL', gsl_dep.found() and gslcblas_dep.found())
 379 test_deps = [gmp_dep, gsl_dep, gslcblas_dep]
 380
 381 # Used by gstinfo.c
 382 dl_dep = cc.find_library('dl', required : false)
 383 cdata.set('HAVE_DLADDR', cc.has_function('dladdr', dependencies : dl_dep))
 384 cdata.set('GST_ENABLE_EXTRA_CHECKS', get_option('extra-checks'))
 385 cdata.set('USE_POISONING', get_option('poisoning'))
 386
 387 configinc = include_directories('.')
 388 libsinc = include_directories('libs')
 389 privinc = include_directories('gst')
 390
 391 # Find dependencies
 392 glib_dep = dependency('glib-2.0', version : '>=2.32.0',
 393   fallback: ['glib', 'libglib_dep'])
 394 gobject_dep = dependency('gobject-2.0',
 395   fallback: ['glib', 'libgobject_dep'])
 396 gmodule_dep = dependency('gmodule-2.0',
 397   fallback: ['glib', 'libgmodule_dep'])
 398 if host_system == 'windows'
 399     gio_dep = dependency('gio-2.0',
 400         fallback: ['glib', 'libgio_dep'])
 401 else
 402     gio_dep = [dependency('gio-2.0',
 403                   fallback: ['glib', 'libgio_dep']),
 404                dependency('gio-unix-2.0',
 405                   fallback: ['glib', 'libgio_dep'])]
 406 endif
 407
 408 mathlib = cc.find_library('m', required : false)
 409 # Needed for timer_create/settime/delete
 410 # Also provides clock_gettime in glibc < 2.17
 411 rt_lib = cc.find_library('rt', required : false)
 412
 413 gir = find_program('g-ir-scanner', required : get_option('introspection'))
 414 gnome = import('gnome')
 415
 416 build_gir = gir.found() and not meson.is_cross_build()
 417
 418 gir_init_section = [ '--add-init-section=extern void gst_init(gint*,gchar**);' + \
 419     'g_setenv("GST_REGISTRY_DISABLE", "yes", TRUE);' + \
 420     'g_setenv("GST_REGISTRY_1.0", "/no/way/this/exists.reg", TRUE);' + \
 421     'g_setenv("GST_PLUGIN_PATH_1_0", "", TRUE);' + \
 422     'g_setenv("GST_PLUGIN_SYSTEM_PATH_1_0", "", TRUE);' + \
 423     'gst_init(NULL,NULL);' ]
 424
 425 gst_c_args = ['-DHAVE_CONFIG_H']
 426
 427 # FIXME: This is only needed on windows and probably breaks when
 428 # default_library = 'both'. We should add this flag to static_c_args instead
 429 # when Meson supports it: https://github.com/mesonbuild/meson/issues/3304
 430 if get_option('default_library') == 'static'
 431   gst_c_args += ['-DGST_STATIC_COMPILATION']
 432 endif
 433
 434 # Used in gst/parse/meson.build and below
 435 python3 = import('python3').find_python()
 436
 437 bashcomp_option = get_option('bash-completion')
 438 bashcomp_dep = dependency('bash-completion', version : '>= 2.0', required : bashcomp_option)
 439 bash_completions_dir = ''
 440 bash_helpers_dir = ''
 441
 442 bashcomp_found = false
 443 if bashcomp_dep.found()
 444   bashcomp_found = true
 445   bash_completions_dir = bashcomp_dep.get_pkgconfig_variable('completionsdir', define_variable: ['prefix', '.'])
 446   if bash_completions_dir == ''
 447     msg = 'Found bash-completion but the .pc file did not set \'completionsdir\'.'
 448     if bashcomp_option.enabled()
 449       error(msg)
 450     else
 451       message(msg)
 452     endif
 453     bashcomp_found = false
 454   endif
 455
 456   bash_helpers_dir = bashcomp_dep.get_pkgconfig_variable('helpersdir', define_variable: ['prefix', '.'])
 457   if bash_helpers_dir == ''
 458     msg = 'Found bash-completion, but the .pc file did not set \'helpersdir\'.'
 459     if bashcomp_option.enabled()
 460       error(msg)
 461     else
 462       message(msg)
 463     endif
 464     bashcomp_found = false
 465   endif
 466 endif
 467
 468 subdir('gst')
 469 subdir('libs')
 470 subdir('plugins')
 471 if not get_option('tools').disabled()
 472   subdir('tools')
 473 endif
 474 subdir('pkgconfig')
 475 subdir('tests')
 476 subdir('data')
 477
 478 # xgettext is optional (on Windows for instance)
 479 if find_program('xgettext', required : get_option('nls')).found()
 480   cdata.set('ENABLE_NLS', 1)
 481   subdir('po')
 482 endif
 483
 484 configure_file(output : 'config.h', configuration : cdata)
 485
 486 if build_machine.system() == 'windows'
 487   message('Disabling gtk-doc while building on Windows')
 488 else
 489   if find_program('gtkdoc-scan', required : get_option('gtk_doc')).found()
 490     subdir('docs')
 491   else
 492     message('Not building documentation as gtk-doc was not found')
 493   endif
 494 endif
 495
 496 run_command(python3, '-c', 'import shutil; shutil.copy("hooks/pre-commit.hook", ".git/hooks/pre-commit")')
 497
 498 install_data('gst-element-check-1.0.m4', install_dir : join_paths(get_option('datadir'), 'aclocal'))