meson.build

   1 project('gstreamer-vaapi', 'c',
   2   version : '1.13.90',
   3   meson_version : '>= 0.36.0',
   4   default_options : [ 'warning_level=1',
   5                       'buildtype=debugoptimized' ])
   6
   7 gst_version = meson.project_version()
   8 version_arr = gst_version.split('.')
   9 gst_version_major = version_arr[0].to_int()
  10 gst_version_minor = version_arr[1].to_int()
  11 gst_version_micro = version_arr[2].to_int()
  12  if version_arr.length() == 4
  13   gst_version_nano = version_arr[3].to_int()
  14 else
  15   gst_version_nano = 0
  16 endif
  17
  18 libva_req = ['>= 0.30.4', '!= 0.99.0']
  19 glib_req = '>= 2.40.0'
  20 gst_req = '>= @0@.@1@.0'.format(gst_version_major, gst_version_minor)
  21
  22 cc = meson.get_compiler('c')
  23
  24 # Symbol visibility
  25 if cc.has_argument('-fvisibility=hidden')
  26   add_project_arguments('-fvisibility=hidden', language: 'c')
  27 endif
  28
  29 # Disable strict aliasing
  30 if cc.has_argument('-fno-strict-aliasing')
  31   add_project_arguments('-fno-strict-aliasing', language: 'c')
  32 endif
  33
  34 # Mandatory GST deps
  35 libm = cc.find_library('m', required : false)
  36 gst_dep = dependency('gstreamer-1.0', version : gst_req,
  37   fallback : ['gstreamer', 'gst_dep'])
  38 gstbase_dep = dependency('gstreamer-base-1.0', version : gst_req,
  39   fallback : ['gstreamer', 'gst_base_dep'])
  40 gstpbutils_dep = dependency('gstreamer-pbutils-1.0', version : gst_req,
  41     fallback : ['gst-plugins-base', 'pbutils_dep'])
  42 gstallocators_dep = dependency('gstreamer-allocators-1.0', version : gst_req,
  43     fallback : ['gst-plugins-base', 'allocators_dep'])
  44 gstvideo_dep = dependency('gstreamer-video-1.0', version : gst_req,
  45     fallback : ['gst-plugins-base', 'video_dep'])
  46 gstcodecparsers_dep = dependency('gstreamer-codecparsers-1.0', version : gst_req,
  47     fallback : ['gst-plugins-bad', 'gstcodecparsers_dep'])
  48 gstgl_dep = dependency('gstreamer-gl-1.0', version : gst_req,
  49     fallback : ['gst-plugins-base', 'gstgl_dep'], required: false)
  50 gmodule_dep = dependency('gmodule-2.0', required: false)
  51 libva_dep = dependency('libva', version: libva_req)
  52
  53 libva_drm_dep = dependency('libva-drm', version: '>= 0.33.0', required: false)
  54 libva_wayland_dep = dependency('libva-wayland', version: '>= 0.33.0', required: false)
  55 libva_x11_dep = dependency('libva-x11', version: '>= 0.31.0', required: false)
  56 libdrm_dep = dependency('libdrm', required: false)
  57 libudev_dep = dependency('libudev', required: false)
  58 egl_dep = dependency('egl', required: false)
  59 gl_dep = dependency('gl', required: false)
  60 glesv2_dep = dependency('glesv2', required: false)
  61 glesv3_dep = dependency('glesv3', required: false)
  62 libdl_dep = cc.find_library('dl', rqeuired: false)
  63 wayland_client_dep = dependency('wayland-client', required: false)
  64 x11_dep = dependency('x11', required: false)
  65 xrandr_dep = dependency('xrandr', required: false)
  66 xrender_dep = dependency('xrender', required: false)
  67
  68 GLES_VERSION_MASK = 0
  69 GLES_VERSION_MASK += gl_dep.found() ? 1 : 0
  70 GLES_VERSION_MASK += glesv2_dep.found() ? 4 : 0
  71 GLES_VERSION_MASK += glesv3_dep.found() ? 8 : 0
  72
  73 USE_ENCODERS = libva_dep.version().version_compare('>= 0.34.0') and get_option('with_encoders') != 'no'
  74 USE_H265_DECODER = cc.has_header('va/va_dec_hevc.h', dependencies: libva_dep, prefix: '#include <va/va.h>')
  75 USE_H265_ENCODER = USE_ENCODERS and cc.has_header('va/va_enc_hevc.h', dependencies: libva_dep, prefix: '#include <va/va.h>')
  76 USE_JPEG_DECODER = cc.has_header('va/va_dec_jpeg.h', dependencies: libva_dep, prefix: '#include <va/va.h>')
  77 USE_JPEG_ENCODER = USE_ENCODERS and cc.has_header('va/va_enc_jpeg.h', dependencies: libva_dep, prefix: '#include <va/va.h>')
  78 USE_VP8_DECODER = cc.has_header('va/va_dec_vp8.h', dependencies: libva_dep, prefix: '#include <va/va.h>')
  79 USE_VP8_ENCODER = USE_ENCODERS and cc.has_header('va/va_enc_vp8.h', dependencies: libva_dep, prefix: '#include <va/va.h>')
  80 USE_VP9_DECODER = cc.has_header('va/va_dec_vp9.h', dependencies: libva_dep, prefix: '#include <va/va.h>')
  81 USE_VP9_ENCODER = USE_ENCODERS and cc.has_header('va/va_enc_vp9.h', dependencies: libva_dep, prefix: '#include <va/va.h>')
  82
  83 USE_VPP = cc.has_header('va/va_vpp.h', dependencies: libva_dep, prefix: '#include <va/va_vpp.h>')
  84
  85 USE_DRM = libva_drm_dep.found() and libdrm_dep.found() and libudev_dep.found() and get_option('with_drm') != 'no'
  86 USE_EGL = gmodule_dep.found() and egl_dep.found() and GLES_VERSION_MASK != 0 and get_option('with_egl') != 'no'
  87 USE_GLX = libva_x11_dep.found() and x11_dep.found() and gl_dep.found() and libdl_dep.found() and get_option('with_glx') != 'no'
  88 USE_WAYLAND = libva_wayland_dep.found() and wayland_client_dep.found() and get_option('with_wayland') != 'no'
  89 USE_X11 = libva_x11_dep.found() and x11_dep.found() and get_option('with_x11') != 'no'
  90
  91 cdata = configuration_data()
  92 cdata.set('GST_API_VERSION_S', '"@0@.@1@"'.format(gst_version_major, gst_version_minor))
  93 cdata.set('PACKAGE', '"gstreamer-vaapi"')
  94 cdata.set('VERSION', '"@0@"'.format(gst_version))
  95 cdata.set('PACKAGE_VERSION', '"@0@"'.format(gst_version))
  96 cdata.set('PACKAGE_NAME', '"GStreamer VA-API Plug-ins"')
  97 cdata.set('PACKAGE_STRING', '"GStreamer VA-API Plug-ins @0@"'.format(gst_version))
  98 cdata.set('PACKAGE_BUGREPORT', '"http://bugzilla.gnome.org/enter_bug.cgi?product=GStreamer"')
  99 cdata.set10('USE_DRM', USE_DRM)
 100 cdata.set10('USE_EGL', USE_EGL)
 101 cdata.set10('USE_ENCODERS', USE_ENCODERS)
 102 cdata.set10('USE_GLX', USE_GLX)
 103 cdata.set10('USE_H265_DECODER', USE_H265_DECODER)
 104 cdata.set10('USE_H265_ENCODER', USE_H265_ENCODER)
 105 cdata.set10('USE_JPEG_DECODER', USE_JPEG_DECODER)
 106 cdata.set10('USE_JPEG_ENCODER', USE_JPEG_ENCODER)
 107 cdata.set10('USE_VP8_DECODER', USE_VP8_DECODER)
 108 cdata.set10('USE_VP8_ENCODER', USE_VP8_ENCODER)
 109 cdata.set10('USE_VP9_DECODER', USE_VP9_DECODER)
 110 cdata.set10('USE_VP9_ENCODER', USE_VP9_ENCODER)
 111 cdata.set10('USE_WAYLAND', USE_WAYLAND)
 112 cdata.set10('USE_X11', USE_X11)
 113 cdata.set10('HAVE_XKBLIB', cc.has_header('X11/XKBlib.h', dependencies: x11_dep))
 114 cdata.set10('HAVE_XRANDR', xrandr_dep.found())
 115 cdata.set10('HAVE_XRENDER', xrender_dep.found())
 116 cdata.set10('USE_VA_VPP', USE_VPP)
 117 cdata.set10('USE_GST_GL_HELPERS', gstgl_dep.found())
 118 cdata.set('GLES_VERSION_MASK', GLES_VERSION_MASK)
 119 runcmd = run_command('pkg-config', '--variable=driverdir', 'libva')
 120 if runcmd.returncode() == 0
 121   cdata.set('VA_DRIVERS_PATH', '"@0@"'.format(runcmd.stdout().strip()))
 122 endif
 123
 124 if libva_dep.version().version_compare('< 0.38.0')
 125   check_headers = [
 126     [USE_H265_DECODER, 'HAVE_VA_VA_DEC_HEVC_H'],
 127     [USE_H265_ENCODER, 'HAVE_VA_VA_ENC_HEVC_H'],
 128     [USE_JPEG_DECODER, 'HAVE_VA_VA_DEC_JPEG_H'],
 129     [USE_JPEG_ENCODER, 'HAVE_VA_VA_ENC_JPEG_H'],
 130     [USE_VP8_DECODER, 'HAVE_VA_VA_DEC_VP8_H'],
 131     [USE_VP8_ENCODER, 'HAVE_VA_VA_ENC_VP8_H'],
 132     [USE_VP9_DECODER, 'HAVE_VA_VA_DEC_VP9_H'],
 133     [USE_VP9_ENCODER, 'HAVE_VA_VA_DEC_VP9_H'],
 134     [USE_VPP, 'HAVE_VA_VA_VPP_H'],
 135   ]
 136   foreach h : check_headers
 137     if h.get(0)
 138       cdata.set(h.get(1), 1)
 139     endif
 140   endforeach
 141
 142   if USE_ENCODERS
 143     check_headers = [
 144       ['HAVE_VA_VA_ENC_MPEG2_H', 'va/va_enc_mpeg2.h'],
 145       ['HAVE_VA_VA_ENC_H264_H', 'va/va_enc_h264.h'],
 146     ]
 147     foreach h : check_headers
 148       if cc.has_header(h.get(1), dependencies: libva_dep, prefix: '#include <va/va.h>')
 149         cdata.set(h.get(0), 1)
 150       endif
 151     endforeach
 152   endif
 153 endif
 154
 155 api_version = '1.0'
 156 soversion = 0
 157 # maintaining compatibility with the previous libtool versioning
 158 # current = minor * 100 + micro
 159 libversion = '@0@.@1@.0'.format(soversion, gst_version_minor * 100 + gst_version_micro)
 160
 161 plugins_install_dir = '@0@/gstreamer-1.0'.format(get_option('libdir'))
 162
 163 configure_file(configuration: cdata, output: 'config.h')
 164 gstreamer_vaapi_args = ['-DHAVE_CONFIG_H']
 165 configinc = include_directories('.')
 166 libsinc = include_directories('gst-libs')
 167
 168 subdir('gst-libs')
 169 subdir('gst')
 170 #subdir('tests')
 171
 172 python3 = import('python3').find_python()
 173 run_command(python3, '-c', 'import shutil; shutil.copy("hooks/pre-commit.hook", ".git/hooks/pre-commit")')