meson.build

   1 project('gst-plugins-base', 'c', 'cpp',
   2   version : '1.11.2.1',
   3   meson_version : '>= 0.36.0',
   4   default_options : [ 'warning_level=1',
   5                       'buildtype=debugoptimized' ])
   6
   7 gst_version = meson.project_version()
   8 version_arr = gst_version.split('.')
   9 gst_version_major = version_arr[0]
  10 gst_version_minor = version_arr[1]
  11 gst_version_micro = version_arr[2]
  12 if version_arr.length() == 4
  13   gst_version_nano = version_arr[3]
  14 else
  15   gst_version_nano = 0
  16 endif
  17
  18 glib_req = '>= 2.40.0'
  19 orc_req = '>= 0.4.24'
  20 gst_req = '>= @0@.@1@.0'.format(gst_version_major, gst_version_minor)
  21
  22 api_version = '1.0'
  23 soversion = 0
  24 # maintaining compatibility with the previous libtool versioning
  25 # current = minor * 100 + micro
  26 # FIXME: should be able to convert string to int somehow so we can just do maths
  27 libversion = '@0@.@1@.0'.format(soversion, gst_version_minor.to_int() * 100 + gst_version_micro.to_int())
  28
  29 plugins_install_dir = '@0@/gstreamer-1.0'.format(get_option('libdir'))
  30
  31 cc = meson.get_compiler('c')
  32
  33 if cc.get_id() == 'msvc'
  34   # Ignore several spurious warnings for things gstreamer does very commonly
  35   # If a warning is completely useless and spammy, use '/wdXXXX' to suppress it
  36   # If a warning is harmless but hard to fix, use '/woXXXX' so it's shown once
  37   # NOTE: Only add warnings here if you are sure they're spurious
  38   add_project_arguments(
  39       '/wd4018', # implicit signed/unsigned conversion
  40       '/wd4146', # unary minus on unsigned (beware INT_MIN)
  41       '/wd4244', # lossy type conversion (e.g. double -> int)
  42       '/wd4305', # truncating type conversion (e.g. double -> float)
  43       language : 'c')
  44   # Disable SAFESEH with MSVC for plugins and libs that use external deps that
  45   # are built with MinGW
  46   noseh_link_args = ['/SAFESEH:NO']
  47 else
  48   noseh_link_args = []
  49 endif
  50
  51 core_conf = configuration_data()
  52 check_headers = [
  53   ['HAVE_DLFCN_H', 'dlfcn.h'],
  54   ['HAVE_EMMINTRIN_H', 'emmintrin.h'],
  55   ['HAVE_INTTYPES_H', 'inttypes.h'],
  56   ['HAVE_MEMORY_H', 'memory.h'],
  57   ['HAVE_PROCESS_H', 'process.h'],
  58   ['HAVE_SMMINTRIN_H', 'smmintrin.h'],
  59   ['HAVE_STDINT_H', 'stdint.h'],
  60   ['HAVE_STDLIB_H', 'stdlib.h'],
  61   ['HAVE_STRINGS_H', 'strings.h'],
  62   ['HAVE_STRING_H', 'string.h'],
  63   ['HAVE_SYS_SOCKET_H', 'sys/socket.h'],
  64   ['HAVE_SYS_STAT_H', 'sys/stat.h'],
  65   ['HAVE_SYS_TYPES_H', 'sys/types.h'],
  66   ['HAVE_SYS_WAIT_H', 'sys/wait.h'],
  67   ['HAVE_UNISTD_H', 'unistd.h'],
  68   ['HAVE_WINSOCK2_H', 'winsock2.h'],
  69   ['HAVE_XMMINTRIN_H', 'xmmintrin.h'],
  70 ]
  71 foreach h : check_headers
  72   if cc.has_header(h.get(1))
  73     core_conf.set(h.get(0), 1)
  74   endif
  75 endforeach
  76
  77 check_functions = [
  78   ['HAVE_DCGETTEXT', 'dcgettext', '#include<libintl.h>'],
  79   ['HAVE_GMTIME_R', 'gmtime_r', '#include<time.h>'],
  80   ['HAVE_LRINTF', 'lrintf', '#include<math.h>'],
  81   ['HAVE_MMAP', 'mmap', '#include<sys/mman.h>'],
  82   ['HAVE_LOG2', 'log2', '#include<math.h>'],
  83 ]
  84
  85 libm = cc.find_library('m', required : false)
  86 foreach f : check_functions
  87   if cc.has_function(f.get(1), prefix : f.get(2), dependencies : libm)
  88     core_conf.set(f.get(0), 1)
  89   endif
  90 endforeach
  91
  92 core_conf.set('SIZEOF_CHAR', cc.sizeof('char'))
  93 core_conf.set('SIZEOF_INT', cc.sizeof('int'))
  94 core_conf.set('SIZEOF_LONG', cc.sizeof('long'))
  95 core_conf.set('SIZEOF_SHORT', cc.sizeof('short'))
  96 core_conf.set('SIZEOF_VOIDP', cc.sizeof('void*'))
  97
  98 core_conf.set('GETTEXT_PACKAGE', '"gst-plugins-base-1.0"')
  99 core_conf.set('PACKAGE', '"gst-plugins-base"')
 100 core_conf.set('VERSION', '"@0@"'.format(gst_version))
 101 core_conf.set('PACKAGE_VERSION', '"@0@"'.format(gst_version))
 102 core_conf.set('GST_PACKAGE_NAME', '"GStreamer Base Plug-ins"')
 103 core_conf.set('GST_PACKAGE_ORIGIN', '"Unknown package origin"')
 104 core_conf.set('GST_API_VERSION', '"@0@"'.format(api_version))
 105 core_conf.set('GST_INSTALL_PLUGINS_HELPER', '"/FIXME"')
 106 core_conf.set('GST_DATADIR', '"/FIXME"')
 107 core_conf.set('GST_LICENSE', '"LGPL"')
 108 # FIXME: These should be configure options
 109 core_conf.set('DEFAULT_VIDEOSINK', '"autovideosink"')
 110 core_conf.set('DEFAULT_AUDIOSINK', '"autoaudiosink"')
 111
 112 # Set whether the audioresampling method should be detected at runtime
 113 core_conf.set('AUDIORESAMPLE_FORMAT_' + get_option('audioresample_format').to_upper(), true)
 114
 115 gst_plugins_base_args = ['-DHAVE_CONFIG_H']
 116 if get_option('default_library') == 'static'
 117   gst_plugins_base_args += ['-DGST_STATIC_COMPILATION']
 118 endif
 119
 120 # X11 checks are for sys/ and tests/
 121 x11_dep = dependency('x11', required : false)
 122 # GLib checks are for the entire project
 123 giounix_dep = dependency('gio-unix-2.0', version : glib_req, required : false)
 124 # Almost everything that uses glib also uses gobject
 125 glib_deps = [dependency('glib-2.0', version : glib_req),
 126              dependency('gobject-2.0', version : glib_req)]
 127 gio_dep = dependency('gio-2.0', version : glib_req)
 128
 129 core_conf.set('HAVE_X', x11_dep.found())
 130 core_conf.set('HAVE_GIO_UNIX_2_0', giounix_dep.found())
 131
 132 runcmd = run_command('pkg-config', '--variable=giomoduledir', 'gio-2.0')
 133 if runcmd.returncode() == 0
 134   core_conf.set('GIO_MODULE_DIR', '"@0@"'.format(runcmd.stdout().strip()))
 135 endif
 136 runcmd = run_command('pkg-config', '--variable=libdir', 'gio-2.0')
 137 if runcmd.returncode() == 0
 138   core_conf.set('GIO_LIBDIR', '"@0@"'.format(runcmd.stdout().strip()))
 139 endif
 140 runcmd = run_command('pkg-config', '--variable=prefix', 'gio-2.0')
 141 if runcmd.returncode() == 0
 142   core_conf.set('GIO_PREFIX', '"@0@"'.format(runcmd.stdout().strip()))
 143 endif
 144
 145 configinc = include_directories('.')
 146 libsinc = include_directories('gst-libs')
 147
 148 # To use the subproject make subprojects directory
 149 # and put gstreamer meson git there (symlinking is fine)
 150 gst_dep = dependency('gstreamer-1.0', version : gst_req,
 151   fallback : ['gstreamer', 'gst_dep'])
 152 gst_base_dep = dependency('gstreamer-base-1.0', version : gst_req,
 153   fallback : ['gstreamer', 'gst_base_dep'])
 154 gst_net_dep = dependency('gstreamer-net-1.0', version : gst_req,
 155   fallback : ['gstreamer', 'gst_net_dep'])
 156 if host_machine.system() != 'windows'
 157   gst_check_dep = dependency('gstreamer-check-1.0', version : gst_req,
 158     fallback : ['gstreamer', 'gst_check_dep'])
 159 endif
 160 gst_controller_dep = dependency('gstreamer-controller-1.0', version : gst_req,
 161   fallback : ['gstreamer', 'gst_controller_dep'])
 162
 163 vs_module_defs_dir = meson.current_source_dir() + '/win32/common/'
 164
 165 # Used by the *_mkenum.py helper scripts
 166 glib_mkenums = find_program('glib-mkenums')
 167
 168 have_orcc = false
 169 orcc_args = []
 170 if get_option('use_orc') != 'no'
 171   need_orc = get_option('use_orc') == 'yes'
 172   # Used by various libraries/elements that use Orc code
 173   orc_dep = dependency('orc-0.4', version : orc_req, required : need_orc)
 174   orcc = find_program('orcc', required : need_orc)
 175   if orc_dep.found() and orcc.found()
 176     have_orcc = true
 177     orcc_args = [orcc, '--include', 'glib.h']
 178     core_conf.set('HAVE_ORC', 1)
 179   else
 180     message('Orc Compiler not found, will use backup C code')
 181     core_conf.set('DISABLE_ORC', 1)
 182   endif
 183 else
 184   core_conf.set('DISABLE_ORC', 1)
 185 endif
 186
 187 # Used to build SSE* things in audio-resampler
 188 sse_args = '-msse'
 189 sse2_args = '-msse2'
 190 sse41_args = '-msse4.1'
 191
 192 have_sse = cc.has_argument(sse_args)
 193 have_sse2 = cc.has_argument(sse2_args)
 194 have_sse41 = cc.has_argument(sse41_args)
 195
 196 # FIXME: Meson should have a way for portably adding -fPIC when needed for use
 197 # with static libraries that are linked into shared libraries. Or, it should
 198 # add it by default with an option to turn it off if needed.
 199 pic_args = ['-fPIC']
 200 if host_machine.system() == 'windows'
 201   pic_args = []
 202 endif
 203
 204 if gst_dep.type_name() == 'internal'
 205     gst_proj = subproject('gstreamer')
 206
 207     if gst_proj.get_variable('disable_gst_debug')
 208         message('GStreamer debug system is disabled')
 209         add_project_arguments('-Wno-unused', language: 'c')
 210     else
 211         message('GStreamer debug system is enabled')
 212     endif
 213 else
 214     # We can't check that in the case of subprojects as we won't
 215     # be able to build against an internal dependency (which is not built yet)
 216     if not cc.compiles('''
 217 #include <gst/gstconfig.h>
 218 #ifdef GST_DISABLE_GST_DEBUG
 219 #error "debugging disabled, make compiler fail"
 220 #endif''' , dependencies: gst_dep)
 221         message('GStreamer debug system is disabled')
 222         add_project_arguments('-Wno-unused', language: 'c')
 223     else
 224         message('GStreamer debug system is enabled')
 225     endif
 226 endif
 227
 228 gir = find_program('g-ir-scanner', required : false)
 229 gnome = import('gnome')
 230 build_gir = gir.found() and not meson.is_cross_build() and not get_option('disable_introspection')
 231 gir_init_section = [ '--add-init-section=extern void gst_init(gint*,gchar**);' + \
 232     'g_setenv("GST_REGISTRY_1.0", "@0@", TRUE);'.format(meson.current_build_dir() + '/gir_empty_registry.reg') + \
 233     'g_setenv("GST_PLUGIN_PATH_1_0", "", TRUE);' + \
 234     'g_setenv("GST_PLUGIN_SYSTEM_PATH_1_0", "", TRUE);' + \
 235     'gst_init(NULL,NULL);' ]
 236
 237 subdir('gst-libs')
 238 subdir('gst')
 239 subdir('ext')
 240 subdir('sys')
 241 subdir('tools')
 242 subdir('tests')
 243 subdir('pkgconfig')
 244
 245 if build_machine.system() == 'windows'
 246   message('Disabling gtk-doc while building on Windows')
 247 elif get_option('disable_gtkdoc')
 248   message('gtk-doc is disabled via options')
 249 else
 250   if find_program('gtkdoc-scan', required : false).found()
 251     subdir('docs')
 252   else
 253     message('Not building documentation as gtk-doc was not found')
 254   endif
 255 endif
 256
 257 # Use core_conf after all subdirs have set values
 258 configure_file(input : 'config.h.meson',
 259   output : 'config.h',
 260   configuration : core_conf)
 261
 262 python3 = find_program('python3')
 263 run_command(python3, '-c', 'import shutil; shutil.copy("hooks/pre-commit.hook", ".git/hooks/pre-commit")')