meson.build

   1 project('gstreamer-vaapi', 'c',
   2   version : '1.15.0.1',
   3   meson_version : '>= 0.46.0',
   4   default_options : [ 'warning_level=1',
   5                       'buildtype=debugoptimized' ])
   6
   7 gst_version = meson.project_version()
   8 version_arr = gst_version.split('.')
   9 gst_version_major = version_arr[0].to_int()
  10 gst_version_minor = version_arr[1].to_int()
  11 gst_version_micro = version_arr[2].to_int()
  12  if version_arr.length() == 4
  13   gst_version_nano = version_arr[3].to_int()
  14 else
  15   gst_version_nano = 0
  16 endif
  17
  18 libva_req = ['>= 0.30.4', '!= 0.99.0']
  19 glib_req = '>= 2.40.0'
  20 gst_req = '>= @0@.@1@.0'.format(gst_version_major, gst_version_minor)
  21
  22 cc = meson.get_compiler('c')
  23
  24 if cc.has_link_argument('-Wl,-Bsymbolic-functions')
  25   add_project_link_arguments('-Wl,-Bsymbolic-functions', language : 'c')
  26 endif
  27
  28 # Symbol visibility
  29 if cc.has_argument('-fvisibility=hidden')
  30   add_project_arguments('-fvisibility=hidden', language: 'c')
  31 endif
  32
  33 # Disable strict aliasing
  34 if cc.has_argument('-fno-strict-aliasing')
  35   add_project_arguments('-fno-strict-aliasing', language: 'c')
  36 endif
  37
  38 # Mandatory GST deps
  39 libm = cc.find_library('m', required : false)
  40 gst_dep = dependency('gstreamer-1.0', version : gst_req,
  41   fallback : ['gstreamer', 'gst_dep'])
  42 gstbase_dep = dependency('gstreamer-base-1.0', version : gst_req,
  43   fallback : ['gstreamer', 'gst_base_dep'])
  44 gstpbutils_dep = dependency('gstreamer-pbutils-1.0', version : gst_req,
  45     fallback : ['gst-plugins-base', 'pbutils_dep'])
  46 gstallocators_dep = dependency('gstreamer-allocators-1.0', version : gst_req,
  47     fallback : ['gst-plugins-base', 'allocators_dep'])
  48 gstvideo_dep = dependency('gstreamer-video-1.0', version : gst_req,
  49     fallback : ['gst-plugins-base', 'video_dep'])
  50 gstcodecparsers_dep = dependency('gstreamer-codecparsers-1.0', version : gst_req,
  51     fallback : ['gst-plugins-bad', 'gstcodecparsers_dep'])
  52 gstgl_dep = dependency('gstreamer-gl-1.0', version : gst_req,
  53     fallback : ['gst-plugins-base', 'gstgl_dep'], required: false)
  54 gmodule_dep = dependency('gmodule-2.0', required: false)
  55 libva_dep = dependency('libva', version: libva_req)
  56
  57 libva_drm_dep = dependency('libva-drm', version: '>= 0.33.0', required: false)
  58 libva_wayland_dep = dependency('libva-wayland', version: '>= 0.33.0', required: false)
  59 libva_x11_dep = dependency('libva-x11', version: '>= 0.31.0', required: false)
  60 libdrm_dep = dependency('libdrm', required: false)
  61 libudev_dep = dependency('libudev', required: false)
  62 egl_dep = dependency('egl', required: false)
  63 gl_dep = dependency('gl', required: false)
  64 glesv2_dep = dependency('glesv2', required: false)
  65 libdl_dep = cc.find_library('dl', required: false)
  66 wayland_client_dep = dependency('wayland-client', required: false)
  67 x11_dep = dependency('x11', required: false)
  68 xrandr_dep = dependency('xrandr', required: false)
  69 xrender_dep = dependency('xrender', required: false)
  70
  71 GLES_VERSION_MASK = gl_dep.found() ? 1 : 0
  72 if glesv2_dep.found()
  73   if (cc.has_header('GLES2/gl2.h', dependencies: glesv2_dep) and
  74       cc.has_header('GLES2/gl2ext.h', dependencies: glesv2_dep))
  75     GLES_VERSION_MASK += 4
  76   endif
  77   if (cc.has_header('GLES3/gl3.h', dependencies: glesv2_dep) and
  78       cc.has_header('GLES3/gl3ext.h', dependencies: glesv2_dep) and
  79       cc.has_header('GLES2/gl2ext.h', dependencies: glesv2_dep))
  80     GLES_VERSION_MASK += 8
  81   endif
  82 endif
  83
  84 USE_ENCODERS = libva_dep.version().version_compare('>= 0.34.0') and get_option('with_encoders') != 'no'
  85 USE_H265_DECODER = cc.has_header('va/va_dec_hevc.h', dependencies: libva_dep, prefix: '#include <va/va.h>')
  86 USE_H265_ENCODER = USE_ENCODERS and cc.has_header('va/va_enc_hevc.h', dependencies: libva_dep, prefix: '#include <va/va.h>')
  87 USE_JPEG_DECODER = cc.has_header('va/va_dec_jpeg.h', dependencies: libva_dep, prefix: '#include <va/va.h>')
  88 USE_JPEG_ENCODER = USE_ENCODERS and cc.has_header('va/va_enc_jpeg.h', dependencies: libva_dep, prefix: '#include <va/va.h>')
  89 USE_VP8_DECODER = cc.has_header('va/va_dec_vp8.h', dependencies: libva_dep, prefix: '#include <va/va.h>')
  90 USE_VP8_ENCODER = USE_ENCODERS and cc.has_header('va/va_enc_vp8.h', dependencies: libva_dep, prefix: '#include <va/va.h>')
  91 USE_VP9_DECODER = cc.has_header('va/va_dec_vp9.h', dependencies: libva_dep, prefix: '#include <va/va.h>')
  92 USE_VP9_ENCODER = USE_ENCODERS and cc.has_header('va/va_enc_vp9.h', dependencies: libva_dep, prefix: '#include <va/va.h>')
  93
  94 USE_VPP = cc.has_header('va/va_vpp.h', dependencies: libva_dep, prefix: '#include <va/va_vpp.h>')
  95
  96 USE_DRM = libva_drm_dep.found() and libdrm_dep.found() and libudev_dep.found() and get_option('with_drm') != 'no'
  97 USE_EGL = gmodule_dep.found() and egl_dep.found() and GLES_VERSION_MASK != 0 and get_option('with_egl') != 'no'
  98 USE_GLX = libva_x11_dep.found() and x11_dep.found() and gl_dep.found() and libdl_dep.found() and get_option('with_glx') != 'no'
  99 USE_WAYLAND = libva_wayland_dep.found() and wayland_client_dep.found() and get_option('with_wayland') != 'no'
 100 USE_X11 = libva_x11_dep.found() and x11_dep.found() and get_option('with_x11') != 'no'
 101
 102 driverdir = libva_dep.get_pkgconfig_variable('driverdir')
 103 if driverdir == ''
 104   driverdir = '@0@/@1@/@2@'.format(get_option('prefix'), get_option('libdir'), 'dri')
 105 endif
 106
 107 cdata = configuration_data()
 108 cdata.set('GST_API_VERSION_S', '"@0@.@1@"'.format(gst_version_major, gst_version_minor))
 109 cdata.set('PACKAGE', '"gstreamer-vaapi"')
 110 cdata.set('VERSION', '"@0@"'.format(gst_version))
 111 cdata.set('PACKAGE_VERSION', '"@0@"'.format(gst_version))
 112 cdata.set('PACKAGE_NAME', '"GStreamer VA-API Plug-ins"')
 113 cdata.set('PACKAGE_STRING', '"GStreamer VA-API Plug-ins @0@"'.format(gst_version))
 114 cdata.set('PACKAGE_BUGREPORT', '"http://bugzilla.gnome.org/enter_bug.cgi?product=GStreamer"')
 115 cdata.set('VA_DRIVERS_PATH', '"@0@"'.format(driverdir))
 116 cdata.set10('USE_DRM', USE_DRM)
 117 cdata.set10('USE_EGL', USE_EGL)
 118 cdata.set10('USE_ENCODERS', USE_ENCODERS)
 119 cdata.set10('USE_GLX', USE_GLX)
 120 cdata.set10('USE_H265_DECODER', USE_H265_DECODER)
 121 cdata.set10('USE_H265_ENCODER', USE_H265_ENCODER)
 122 cdata.set10('USE_JPEG_DECODER', USE_JPEG_DECODER)
 123 cdata.set10('USE_JPEG_ENCODER', USE_JPEG_ENCODER)
 124 cdata.set10('USE_VP8_DECODER', USE_VP8_DECODER)
 125 cdata.set10('USE_VP8_ENCODER', USE_VP8_ENCODER)
 126 cdata.set10('USE_VP9_DECODER', USE_VP9_DECODER)
 127 cdata.set10('USE_VP9_ENCODER', USE_VP9_ENCODER)
 128 cdata.set10('USE_WAYLAND', USE_WAYLAND)
 129 cdata.set10('USE_X11', USE_X11)
 130 cdata.set10('HAVE_XKBLIB', cc.has_header('X11/XKBlib.h', dependencies: x11_dep))
 131 cdata.set10('HAVE_XRANDR', xrandr_dep.found())
 132 cdata.set10('HAVE_XRENDER', xrender_dep.found())
 133 cdata.set10('USE_VA_VPP', USE_VPP)
 134 cdata.set10('USE_GST_GL_HELPERS', gstgl_dep.found())
 135 cdata.set('USE_GLES_VERSION_MASK', GLES_VERSION_MASK)
 136
 137 if libva_dep.version().version_compare('< 0.38.0')
 138   check_headers = [
 139     [USE_H265_DECODER, 'HAVE_VA_VA_DEC_HEVC_H'],
 140     [USE_H265_ENCODER, 'HAVE_VA_VA_ENC_HEVC_H'],
 141     [USE_JPEG_DECODER, 'HAVE_VA_VA_DEC_JPEG_H'],
 142     [USE_JPEG_ENCODER, 'HAVE_VA_VA_ENC_JPEG_H'],
 143     [USE_VP8_DECODER, 'HAVE_VA_VA_DEC_VP8_H'],
 144     [USE_VP8_ENCODER, 'HAVE_VA_VA_ENC_VP8_H'],
 145     [USE_VP9_DECODER, 'HAVE_VA_VA_DEC_VP9_H'],
 146     [USE_VP9_ENCODER, 'HAVE_VA_VA_DEC_VP9_H'],
 147     [USE_VPP, 'HAVE_VA_VA_VPP_H'],
 148   ]
 149   foreach h : check_headers
 150     if h.get(0)
 151       cdata.set(h.get(1), 1)
 152     endif
 153   endforeach
 154
 155   if USE_ENCODERS
 156     check_headers = [
 157       ['HAVE_VA_VA_ENC_MPEG2_H', 'va/va_enc_mpeg2.h'],
 158       ['HAVE_VA_VA_ENC_H264_H', 'va/va_enc_h264.h'],
 159     ]
 160     foreach h : check_headers
 161       if cc.has_header(h.get(1), dependencies: libva_dep, prefix: '#include <va/va.h>')
 162         cdata.set(h.get(0), 1)
 163       endif
 164     endforeach
 165   endif
 166 endif
 167
 168 api_version = '1.0'
 169 soversion = 0
 170 # maintaining compatibility with the previous libtool versioning
 171 # current = minor * 100 + micro
 172 curversion = gst_version_minor * 100 + gst_version_micro
 173 libversion = '@0@.@1@.0'.format(soversion, curversion)
 174 osxversion = curversion + 1
 175
 176 plugins_install_dir = '@0@/gstreamer-1.0'.format(get_option('libdir'))
 177
 178 configure_file(configuration: cdata, output: 'config.h')
 179 gstreamer_vaapi_args = ['-DHAVE_CONFIG_H']
 180 configinc = include_directories('.')
 181 libsinc = include_directories('gst-libs')
 182
 183 subdir('gst-libs')
 184 subdir('gst')
 185 #subdir('tests')
 186
 187 python3 = import('python3').find_python()
 188 run_command(python3, '-c', 'import shutil; shutil.copy("hooks/pre-commit.hook", ".git/hooks/pre-commit")')