meson.build

   1 project('gst-libav', 'c', 'cpp',
   2   version : '1.9.2.1',
   3   meson_version : '>= 0.33.0',
   4   default_options : [ 'warning_level=1',
   5                       'c_std=gnu99',
   6                       'buildtype=debugoptimized' ])
   7
   8 gst_version = meson.project_version()
   9 version_arr = gst_version.split('.')
  10 gst_version_major = version_arr[0]
  11 gst_version_minor = version_arr[1]
  12
  13 libavfilter_dep = dependency('libavfilter', version: '>= 6.47.100')
  14 libavformat_dep = dependency('libavformat', version: '>= 57.41.100')
  15 libavcodec_dep = dependency('libavcodec', version: '>= 57.48.101')
  16 libavutil_dep = dependency('libavutil', version: '>= 55.28.100')
  17
  18 libav_deps = [libavfilter_dep, libavformat_dep, libavcodec_dep, libavutil_dep]
  19
  20 cc = meson.get_compiler('c')
  21
  22 check_ffmpeg_src = '''#include <libavcodec/avcodec.h>
  23 #if LIBAVCODEC_VERSION_MICRO >= 100
  24 /* FFmpeg uses 100+ as its micro version */
  25 #else
  26 #error libav provider should be FFmpeg
  27 #endif'''
  28
  29 if not cc.compiles(check_ffmpeg_src, name : 'libav is provided by FFmpeg')
  30     error('Uncompatible libavcodec found')
  31 endif
  32
  33 cdata = configuration_data()
  34 cdata.set('LIBAV_SOURCE', '"system install"')
  35 cdata.set('PACKAGE_VERSION', '"@0@"'.format(gst_version))
  36 cdata.set('PACKAGE', '"gst-libav"')
  37
  38 gst_req = '>= @0@.@1@.0'.format(gst_version_major, gst_version_minor)
  39 gst_dep = dependency('gstreamer-1.0', version : gst_req,
  40   fallback : ['gstreamer', 'gst_dep'])
  41 gstbase_dep = dependency('gstreamer-base-1.0', version : gst_req,
  42   fallback : ['gstreamer', 'gst_base_dep'])
  43
  44 gstvideo_dep = dependency('gstreamer-video-1.0', version : gst_req,
  45     fallback : ['gst-plugins-base', 'video_dep'])
  46 gstaudio_dep = dependency('gstreamer-audio-1.0', version : gst_req,
  47     fallback : ['gst-plugins-base', 'audio_dep'])
  48 gstpbutils_dep = dependency('gstreamer-pbutils-1.0', version : gst_req,
  49     fallback : ['gst-plugins-base', 'pbutils_dep'])
  50 libm = cc.find_library('m', required : false)
  51
  52 configure_file(input : 'config.h.meson',
  53   output : 'config.h',
  54   configuration : cdata)
  55
  56 gst_libav_args = ['-DHAVE_CONFIG_H', '-Wno-deprecated-declarations']
  57 configinc = include_directories('.')
  58 plugins_install_dir = '@0@/gstreamer-1.0'.format(get_option('libdir'))
  59 subdir('ext/libav/')