meson.build

   1 project('gst-plugins-base', 'c',
   2   version : '1.15.0.1',
   3   meson_version : '>= 0.47',
   4   default_options : [ 'warning_level=1',
   5                       'buildtype=debugoptimized' ])
   6
   7 gst_version = meson.project_version()
   8 version_arr = gst_version.split('.')
   9 gst_version_major = version_arr[0].to_int()
  10 gst_version_minor = version_arr[1].to_int()
  11 gst_version_micro = version_arr[2].to_int()
  12 if version_arr.length() == 4
  13   gst_version_nano = version_arr[3].to_int()
  14 else
  15   gst_version_nano = 0
  16 endif
  17 gst_version_is_dev = gst_version_minor % 2 == 1 and gst_version_micro < 90
  18
  19 have_cxx = add_languages('cpp', required : false)
  20 have_objc = add_languages('objc', required : false)
  21
  22 glib_req = '>= 2.40.0'
  23 orc_req = '>= 0.4.24'
  24 gst_req = '>= @0@.@1@.0'.format(gst_version_major, gst_version_minor)
  25
  26 api_version = '1.0'
  27 soversion = 0
  28 # maintaining compatibility with the previous libtool versioning
  29 # current = minor * 100 + micro
  30 curversion = gst_version_minor * 100 + gst_version_micro
  31 libversion = '@0@.@1@.0'.format(soversion, curversion)
  32 osxversion = curversion + 1
  33
  34 plugins_install_dir = join_paths(get_option('libdir'), 'gstreamer-1.0')
  35
  36 cc = meson.get_compiler('c')
  37 host_system = host_machine.system()
  38
  39 if cc.get_id() == 'msvc'
  40   # Ignore several spurious warnings for things gstreamer does very commonly
  41   # If a warning is completely useless and spammy, use '/wdXXXX' to suppress it
  42   # If a warning is harmless but hard to fix, use '/woXXXX' so it's shown once
  43   # NOTE: Only add warnings here if you are sure they're spurious
  44   add_project_arguments(
  45       '/wd4018', # implicit signed/unsigned conversion
  46       '/wd4146', # unary minus on unsigned (beware INT_MIN)
  47       '/wd4244', # lossy type conversion (e.g. double -> int)
  48       '/wd4305', # truncating type conversion (e.g. double -> float)
  49       cc.get_supported_arguments(['/utf-8']), # set the input encoding to utf-8
  50       language : 'c')
  51   # Disable SAFESEH with MSVC for plugins and libs that use external deps that
  52   # are built with MinGW
  53   noseh_link_args = ['/SAFESEH:NO']
  54 else
  55   noseh_link_args = []
  56 endif
  57
  58 if cc.has_link_argument('-Wl,-Bsymbolic-functions')
  59   add_project_link_arguments('-Wl,-Bsymbolic-functions', language : 'c')
  60 endif
  61
  62 core_conf = configuration_data()
  63
  64 # Symbol visibility
  65 if cc.get_id() == 'msvc'
  66   export_define = '__declspec(dllexport) extern'
  67 elif cc.has_argument('-fvisibility=hidden')
  68   add_project_arguments('-fvisibility=hidden', language: 'c')
  69   export_define = 'extern __attribute__ ((visibility ("default")))'
  70 else
  71   export_define = 'extern'
  72 endif
  73
  74 # Passing this through the command line would be too messy
  75 core_conf.set('GST_API_EXPORT', export_define)
  76
  77 # Disable strict aliasing
  78 if cc.has_argument('-fno-strict-aliasing')
  79   add_project_arguments('-fno-strict-aliasing', language: 'c')
  80 endif
  81
  82 # Define G_DISABLE_DEPRECATED for development versions
  83 if gst_version_is_dev
  84   message('Disabling deprecated GLib API')
  85   add_project_arguments('-DG_DISABLE_DEPRECATED', language: 'c')
  86 endif
  87
  88 cast_checks = get_option('gobject-cast-checks')
  89 if cast_checks.disabled() or (cast_checks.auto() and not gst_version_is_dev)
  90   message('Disabling GLib cast checks')
  91   add_project_arguments('-DG_DISABLE_CAST_CHECKS', language: 'c')
  92 endif
  93
  94 glib_asserts = get_option('glib-asserts')
  95 if glib_asserts.disabled() or (glib_asserts.auto() and not gst_version_is_dev)
  96   message('Disabling GLib asserts')
  97   add_project_arguments('-DG_DISABLE_ASSERT', language: 'c')
  98 endif
  99
 100 glib_checks = get_option('glib-checks')
 101 if glib_checks.disabled() or (glib_checks.auto() and not gst_version_is_dev)
 102   message('Disabling GLib checks')
 103   add_project_arguments('-DG_DISABLE_CHECKS', language: 'c')
 104 endif
 105
 106 check_headers = [
 107   ['HAVE_DLFCN_H', 'dlfcn.h'],
 108   ['HAVE_EMMINTRIN_H', 'emmintrin.h'],
 109   ['HAVE_INTTYPES_H', 'inttypes.h'],
 110   ['HAVE_MEMORY_H', 'memory.h'],
 111   ['HAVE_PROCESS_H', 'process.h'],
 112   ['HAVE_SMMINTRIN_H', 'smmintrin.h'],
 113   ['HAVE_STDINT_H', 'stdint.h'],
 114   ['HAVE_STDLIB_H', 'stdlib.h'],
 115   ['HAVE_STRINGS_H', 'strings.h'],
 116   ['HAVE_STRING_H', 'string.h'],
 117   ['HAVE_SYS_SOCKET_H', 'sys/socket.h'],
 118   ['HAVE_SYS_STAT_H', 'sys/stat.h'],
 119   ['HAVE_SYS_TYPES_H', 'sys/types.h'],
 120   ['HAVE_SYS_WAIT_H', 'sys/wait.h'],
 121   ['HAVE_UNISTD_H', 'unistd.h'],
 122   ['HAVE_WINSOCK2_H', 'winsock2.h'],
 123   ['HAVE_XMMINTRIN_H', 'xmmintrin.h'],
 124   ['HAVE_LINUX_DMA_BUF_H', 'linux/dma-buf.h'],
 125 ]
 126 foreach h : check_headers
 127   if cc.has_header(h.get(1))
 128     core_conf.set(h.get(0), 1)
 129   endif
 130 endforeach
 131
 132 check_functions = [
 133   ['HAVE_DCGETTEXT', 'dcgettext', '#include<libintl.h>'],
 134   ['HAVE_GMTIME_R', 'gmtime_r', '#include<time.h>'],
 135   ['HAVE_LRINTF', 'lrintf', '#include<math.h>'],
 136   ['HAVE_MMAP', 'mmap', '#include<sys/mman.h>'],
 137   ['HAVE_LOG2', 'log2', '#include<math.h>'],
 138 ]
 139
 140 libm = cc.find_library('m', required : false)
 141 foreach f : check_functions
 142   if cc.has_function(f.get(1), prefix : f.get(2), dependencies : libm)
 143     core_conf.set(f.get(0), 1)
 144   endif
 145 endforeach
 146
 147 core_conf.set('SIZEOF_CHAR', cc.sizeof('char'))
 148 core_conf.set('SIZEOF_INT', cc.sizeof('int'))
 149 core_conf.set('SIZEOF_LONG', cc.sizeof('long'))
 150 core_conf.set('SIZEOF_SHORT', cc.sizeof('short'))
 151 core_conf.set('SIZEOF_VOIDP', cc.sizeof('void*'))
 152
 153 core_conf.set_quoted('GETTEXT_PACKAGE', 'gst-plugins-base-1.0')
 154 core_conf.set_quoted('LOCALEDIR', join_paths(get_option('prefix'), get_option('localedir')))
 155 core_conf.set_quoted('PACKAGE', 'gst-plugins-base')
 156 core_conf.set_quoted('VERSION', gst_version)
 157 core_conf.set_quoted('PACKAGE_VERSION', gst_version)
 158 core_conf.set_quoted('GST_API_VERSION', api_version)
 159 core_conf.set_quoted('GST_DATADIR', join_paths(get_option('prefix'), get_option('datadir')))
 160 core_conf.set_quoted('GST_LICENSE', 'LGPL')
 161
 162 install_plugins_helper = get_option('install_plugins_helper')
 163 if install_plugins_helper == ''
 164   install_plugins_helper = join_paths(get_option('prefix'),
 165                                       get_option('libexecdir'),
 166                                       'gst-install-plugins-helper')
 167 endif
 168 core_conf.set_quoted('GST_INSTALL_PLUGINS_HELPER', install_plugins_helper)
 169
 170 warning_flags = [
 171   '-Wmissing-declarations',
 172   '-Wredundant-decls',
 173   '-Wundef',
 174   '-Wwrite-strings',
 175   '-Wformat',
 176   '-Wformat-nonliteral',
 177   '-Wformat-security',
 178   '-Winit-self',
 179   '-Wmissing-include-dirs',
 180   '-Waddress',
 181   '-Wno-multichar',
 182   '-Wvla',
 183   '-Wpointer-arith',
 184 ]
 185
 186 warning_c_flags = [
 187   '-Wmissing-prototypes',
 188   '-Wdeclaration-after-statement',
 189 ]
 190
 191 warning_cxx_flags = [
 192   '-Waggregate-return',
 193 ]
 194
 195 if have_cxx
 196   cxx = meson.get_compiler('cpp')
 197   foreach extra_arg : warning_cxx_flags
 198     if cxx.has_argument (extra_arg)
 199       add_project_arguments([extra_arg], language: 'cpp')
 200     endif
 201   endforeach
 202 endif
 203
 204 foreach extra_arg : warning_flags
 205   if cc.has_argument (extra_arg)
 206     add_project_arguments([extra_arg], language: 'c')
 207   endif
 208   if have_cxx and cxx.has_argument (extra_arg)
 209     add_project_arguments([extra_arg], language: 'cpp')
 210   endif
 211 endforeach
 212
 213 foreach extra_arg : warning_c_flags
 214   if cc.has_argument (extra_arg)
 215     add_project_arguments([extra_arg], language: 'c')
 216   endif
 217 endforeach
 218
 219 # GStreamer package name and origin url
 220 gst_package_name = get_option('package-name')
 221 if gst_package_name == ''
 222   if gst_version_nano == 0
 223     gst_package_name = 'GStreamer Base Plug-ins source release'
 224   elif gst_version_nano == 1
 225     gst_package_name = 'GStreamer Base Plug-ins git'
 226   else
 227     gst_package_name = 'GStreamer Base Plug-ins prerelease'
 228   endif
 229 endif
 230 core_conf.set_quoted('GST_PACKAGE_NAME', gst_package_name)
 231 core_conf.set_quoted('GST_PACKAGE_ORIGIN', get_option('package-origin'))
 232
 233 # FIXME: These should be configure options
 234 core_conf.set_quoted('DEFAULT_VIDEOSINK', 'autovideosink')
 235 core_conf.set_quoted('DEFAULT_AUDIOSINK', 'autoaudiosink')
 236
 237 # Set whether the audioresampling method should be detected at runtime
 238 core_conf.set('AUDIORESAMPLE_FORMAT_' + get_option('audioresample_format').to_upper(), true)
 239
 240 gst_plugins_base_args = ['-DHAVE_CONFIG_H']
 241 if get_option('default_library') == 'static'
 242   gst_plugins_base_args += ['-DGST_STATIC_COMPILATION']
 243 endif
 244
 245 # X11 checks are for sys/ and tests/
 246 x11_dep = dependency('x11', required : get_option('x11'))
 247 # GLib checks are for the entire project
 248 # Almost everything that uses glib also uses gobject
 249 glib_deps = [dependency('glib-2.0', version : glib_req, fallback: ['glib', 'libglib_dep']),
 250              dependency('gobject-2.0', fallback: ['glib', 'libgobject_dep'])]
 251 # GIO is used by the GIO plugin, and by the TCP, SDP, and RTSP plugins
 252 gio_dep = dependency('gio-2.0', fallback: ['glib', 'libgio_dep'])
 253 giounix_dep = dependency('gio-unix-2.0', version : glib_req, required : host_system != 'windows',
 254                          fallback: ['glib', 'libgiounix_dep'])
 255 gmodule_dep = dependency('gmodule-no-export-2.0',
 256                          fallback: ['glib', 'libgmodule_dep'])
 257
 258 # some of the examples can use gdk-pixbuf and GTK+3
 259 gdk_pixbuf_dep = dependency('gdk-pixbuf-2.0', required : get_option('examples'))
 260 gtk_dep = dependency('gtk+-3.0', version : '>= 3.10', required : get_option('examples'))
 261 # TODO: https://github.com/mesonbuild/meson/issues/3941
 262 if not get_option('x11').disabled()
 263   gtk_x11_dep = dependency('gtk+-x11-3.0', version : '>= 3.10', required : get_option('examples'))
 264 else
 265   gtk_x11_dep = dependency('', required : false)
 266 endif
 267 # gtk+ quartz backend is only available on macOS
 268 if host_system == 'darwin'
 269   gtk_quartz_dep = dependency('gtk+-quartz-3.0', version : '>= 3.10', required : get_option('examples'))
 270 else
 271   gtk_quartz_dep = dependency('', required : false)
 272 endif
 273
 274 core_conf.set('HAVE_X', x11_dep.found())
 275 core_conf.set('HAVE_GIO_UNIX_2_0', giounix_dep.found())
 276
 277 if gio_dep.type_name() == 'pkgconfig'
 278     core_conf.set_quoted('GIO_MODULE_DIR',
 279         gio_dep.get_pkgconfig_variable('giomoduledir'))
 280     core_conf.set_quoted('GIO_LIBDIR',
 281         gio_dep.get_pkgconfig_variable('libdir'))
 282     core_conf.set_quoted('GIO_PREFIX',
 283         gio_dep.get_pkgconfig_variable('prefix'))
 284 else
 285     core_conf.set_quoted('GIO_MODULE_DIR', join_paths(get_option('prefix'),
 286       get_option('libdir'), 'gio/modules'))
 287     core_conf.set_quoted('GIO_LIBDIR', join_paths(get_option('prefix'),
 288       get_option('libdir')))
 289     core_conf.set_quoted('GIO_PREFIX', get_option('prefix'))
 290 endif
 291
 292 configinc = include_directories('.')
 293 libsinc = include_directories('gst-libs')
 294
 295 # To use the subproject make subprojects directory
 296 # and put gstreamer meson git there (symlinking is fine)
 297 gst_dep = dependency('gstreamer-1.0', version : gst_req,
 298   fallback : ['gstreamer', 'gst_dep'])
 299 gst_base_dep = dependency('gstreamer-base-1.0', version : gst_req,
 300   fallback : ['gstreamer', 'gst_base_dep'])
 301 gst_net_dep = dependency('gstreamer-net-1.0', version : gst_req,
 302   fallback : ['gstreamer', 'gst_net_dep'])
 303 gst_check_dep = dependency('gstreamer-check-1.0', version : gst_req,
 304   required : get_option('tests'),
 305   fallback : ['gstreamer', 'gst_check_dep'])
 306 gst_controller_dep = dependency('gstreamer-controller-1.0', version : gst_req,
 307   fallback : ['gstreamer', 'gst_controller_dep'])
 308
 309 have_orcc = false
 310 orcc_args = []
 311 # Used by various libraries/elements that use Orc code
 312 orc_dep = dependency('orc-0.4', version : orc_req, required : get_option('orc'))
 313 orcc = find_program('orcc', required : get_option('orc'))
 314 if orc_dep.found() and orcc.found()
 315   have_orcc = true
 316   orcc_args = [orcc, '--include', 'glib.h']
 317   core_conf.set('HAVE_ORC', 1)
 318 else
 319   message('Orc Compiler not found or disabled, will use backup C code')
 320   core_conf.set('DISABLE_ORC', 1)
 321 endif
 322
 323 # Used to build SSE* things in audio-resampler
 324 sse_args = '-msse'
 325 sse2_args = '-msse2'
 326 sse41_args = '-msse4.1'
 327
 328 have_sse = cc.has_argument(sse_args)
 329 have_sse2 = cc.has_argument(sse2_args)
 330 have_sse41 = cc.has_argument(sse41_args)
 331
 332 if gst_dep.type_name() == 'internal'
 333     gst_proj = subproject('gstreamer')
 334
 335     if not gst_proj.get_variable('gst_debug')
 336         message('GStreamer debug system is disabled')
 337         add_project_arguments('-Wno-unused', language: 'c')
 338     else
 339         message('GStreamer debug system is enabled')
 340     endif
 341 else
 342     # We can't check that in the case of subprojects as we won't
 343     # be able to build against an internal dependency (which is not built yet)
 344     if not cc.compiles('''
 345 #include <gst/gstconfig.h>
 346 #ifdef GST_DISABLE_GST_DEBUG
 347 #error "debugging disabled, make compiler fail"
 348 #endif''' , dependencies: gst_dep)
 349         message('GStreamer debug system is disabled')
 350         add_project_arguments('-Wno-unused', language: 'c')
 351     else
 352         message('GStreamer debug system is enabled')
 353     endif
 354 endif
 355
 356 gir = find_program('g-ir-scanner', required : get_option('introspection'))
 357 gnome = import('gnome')
 358 build_gir = gir.found() and not meson.is_cross_build()
 359 gir_init_section = [ '--add-init-section=extern void gst_init(gint*,gchar**);' + \
 360     'g_setenv("GST_REGISTRY_DISABLE", "yes", TRUE);' + \
 361     'g_setenv("GST_REGISTRY_1.0", "@0@", TRUE);'.format(meson.current_build_dir() + '/gir_empty_registry.reg') + \
 362     'g_setenv("GST_PLUGIN_PATH_1_0", "", TRUE);' + \
 363     'g_setenv("GST_PLUGIN_SYSTEM_PATH_1_0", "", TRUE);' + \
 364     'gst_init(NULL,NULL);' ]
 365
 366 pkgconfig = import('pkgconfig')
 367 plugins_pkgconfig_install_dir = join_paths(plugins_install_dir, 'pkgconfig')
 368 if get_option('default_library') == 'shared'
 369   # If we don't build static plugins there is no need to generate pc files
 370   plugins_pkgconfig_install_dir = disabler()
 371 endif
 372
 373 subdir('gst-libs')
 374 subdir('gst')
 375 subdir('ext')
 376 subdir('sys')
 377 if not get_option('tools').disabled()
 378   subdir('tools')
 379 endif
 380 subdir('tests')
 381 subdir('pkgconfig')
 382
 383 # xgettext is optional (on Windows for instance)
 384 if find_program('xgettext', required : get_option('nls')).found()
 385   core_conf.set('ENABLE_NLS', 1)
 386   subdir('po')
 387 endif
 388
 389 if build_machine.system() == 'windows'
 390   message('Disabling gtk-doc while building on Windows')
 391 else
 392   if find_program('gtkdoc-scan', required : get_option('gtk_doc')).found()
 393     subdir('docs')
 394   else
 395     message('Not building documentation as gtk-doc was not found')
 396   endif
 397 endif
 398
 399 # Use core_conf after all subdirs have set values
 400 configure_file(output : 'config.h', configuration : core_conf)
 401
 402 python3 = import('python').find_installation()
 403 run_command(python3, '-c', 'import shutil; shutil.copy("hooks/pre-commit.hook", ".git/hooks/pre-commit")')