meson.build

   1 project('gstreamer', 'c',
   2   version : '1.15.0.1',
   3   meson_version : '>= 0.47',
   4   default_options : [ 'warning_level=1',
   5                       'buildtype=debugoptimized' ])
   6
   7 gst_version = meson.project_version()
   8 version_arr = gst_version.split('.')
   9 gst_version_major = version_arr[0].to_int()
  10 gst_version_minor = version_arr[1].to_int()
  11 gst_version_micro = version_arr[2].to_int()
  12 if version_arr.length() == 4
  13   gst_version_nano = version_arr[3].to_int()
  14 else
  15   gst_version_nano = 0
  16 endif
  17
  18 host_system = host_machine.system()
  19
  20 apiversion = '1.0'
  21 soversion = 0
  22 # maintaining compatibility with the previous libtool versioning
  23 # current = minor * 100 + micro
  24 libversion = '@0@.@1@.0'.format(soversion, gst_version_minor * 100 + gst_version_micro)
  25
  26 prefix = get_option('prefix')
  27
  28 libexecdir = get_option('libexecdir')
  29 helpers_install_dir = join_paths(libexecdir, 'gstreamer-1.0')
  30
  31 cc = meson.get_compiler('c')
  32
  33 # Ignore several spurious warnings for things gstreamer does very commonly
  34 # If a warning is completely useless and spammy, use '/wdXXXX' to suppress it
  35 # If a warning is harmless but hard to fix, use '/woXXXX' so it's shown once
  36 # NOTE: Only add warnings here if you are sure they're spurious
  37 if cc.get_id() == 'msvc'
  38   add_project_arguments(
  39       '/wd4018', # implicit signed/unsigned conversion
  40       '/wd4146', # unary minus on unsigned (beware INT_MIN)
  41       '/wd4244', # lossy type conversion (e.g. double -> int)
  42       '/wd4305', # truncating type conversion (e.g. double -> float)
  43       language : 'c')
  44 elif cc.has_link_argument('-Wl,-Bsymbolic-functions')
  45   # FIXME: Add an option for this if people ask for it
  46   add_project_link_arguments('-Wl,-Bsymbolic-functions', language : 'c')
  47 endif
  48
  49 # Symbol visibility
  50 have_visibility_hidden = cc.has_argument('-fvisibility=hidden')
  51 if have_visibility_hidden
  52   add_project_arguments('-fvisibility=hidden', language: 'c')
  53 endif
  54
  55 # Disable strict aliasing
  56 if cc.has_argument('-fno-strict-aliasing')
  57   add_project_arguments('-fno-strict-aliasing', language: 'c')
  58 endif
  59
  60 # Define G_DISABLE_DEPRECATED for development versions
  61 if gst_version_minor % 2 == 1 and gst_version_micro < 90
  62   add_project_arguments('-DG_DISABLE_DEPRECATED', language: 'c')
  63 endif
  64
  65 cdata = configuration_data()
  66 cdata.set_quoted('GST_API_VERSION', apiversion)
  67 cdata.set_quoted('GST_DATADIR', join_paths(prefix, get_option('datadir')))
  68 cdata.set_quoted('LOCALEDIR', join_paths(prefix, get_option('localedir')))
  69 cdata.set_quoted('LIBDIR', join_paths(prefix, get_option('libdir')))
  70 cdata.set_quoted('GST_API_VERSION', '1.0')
  71 cdata.set_quoted('GETTEXT_PACKAGE', 'gstreamer-1.0')
  72 cdata.set_quoted('GST_LICENSE', 'LGPL')
  73 cdata.set_quoted('PACKAGE', 'gstreamer')
  74 cdata.set_quoted('PACKAGE_NAME', 'GStreamer')
  75 cdata.set_quoted('PACKAGE_STRING', 'GStreamer @0@'.format(gst_version))
  76 cdata.set_quoted('PACKAGE_TARNAME', 'gstreamer')
  77 cdata.set_quoted('PACKAGE_BUGREPORT', 'http://bugzilla.gnome.org/enter_bug.cgi?product=GStreamer')
  78 cdata.set_quoted('PACKAGE_URL', '')
  79 cdata.set_quoted('PACKAGE_VERSION', gst_version)
  80 cdata.set_quoted('PLUGINDIR', join_paths(get_option('prefix'), get_option('libdir'), 'gstreamer-1.0'))
  81 cdata.set_quoted('VERSION', gst_version)
  82 cdata.set_quoted('GST_PLUGIN_SCANNER_INSTALLED', join_paths(prefix, helpers_install_dir, 'gst-plugin-scanner'))
  83 cdata.set_quoted('GST_PTP_HELPER_INSTALLED', join_paths(prefix, helpers_install_dir, 'gst-ptp-helper'))
  84 cdata.set_quoted('GST_PLUGIN_SCANNER_SUBDIR', libexecdir,
  85   description: 'libexecdir path component, used to find plugin-scanner on relocatable builds on windows')
  86 cdata.set('GST_DISABLE_OPTION_PARSING', not get_option('option-parsing'))
  87
  88 mem_align_opt = get_option('memory-alignment')
  89 if mem_align_opt == 'malloc'
  90   cdata.set('MEMORY_ALIGNMENT_MALLOC', 1)
  91 elif mem_align_opt == 'pagesize'
  92   cdata.set('MEMORY_ALIGNMENT_PAGESIZE', 1)
  93 else
  94   cdata.set('MEMORY_ALIGNMENT', mem_align_opt.to_int())
  95 endif
  96
  97 if host_system == 'darwin'
  98   cdata.set_quoted('GST_EXTRA_MODULE_SUFFIX', '.dylib')
  99 endif
 100
 101 if gst_version_nano > 0
 102     # Have GST_ERROR message printed when running from git
 103     cdata.set('GST_LEVEL_DEFAULT', 'GST_LEVEL_ERROR')
 104 else
 105     cdata.set('GST_LEVEL_DEFAULT', 'GST_LEVEL_NONE')
 106 endif
 107
 108 # GStreamer package name and origin url
 109 gst_package_name = get_option('package-name')
 110 if gst_package_name == ''
 111   if gst_version_nano == 0
 112     gst_package_name = 'GStreamer source release'
 113   elif gst_version_nano == 1
 114     gst_package_name = 'GStreamer git'
 115   else
 116     gst_package_name = 'GStreamer prerelease'
 117   endif
 118 endif
 119 cdata.set_quoted('GST_PACKAGE_NAME', gst_package_name)
 120 cdata.set_quoted('GST_PACKAGE_ORIGIN', get_option('package-origin'))
 121
 122 # These are only needed/used by the ABI tests
 123 host_defines = [
 124   [ 'x86', 'HAVE_CPU_I386' ],
 125   [ 'x86_64', 'HAVE_CPU_X86_64' ],
 126   [ 'arm', 'HAVE_CPU_ARM' ],
 127   [ 'aarch64', 'HAVE_CPU_AARCH64' ],
 128   [ 'mips', 'HAVE_CPU_MIPS' ],
 129   [ 'powerpc', 'HAVE_CPU_PPC' ],
 130   [ 'powerpc64', 'HAVE_CPU_PPC64' ],
 131   [ 'alpha', 'HAVE_CPU_ALPHA' ],
 132   [ 'sparc', 'HAVE_CPU_SPARC' ],
 133   [ 'ia64', 'HAVE_CPU_IA64' ],
 134   [ 'hppa', 'HAVE_CPU_HPPA' ],
 135   [ 'm68k', 'HAVE_CPU_M68K' ],
 136   [ 's390', 'HAVE_CPU_S390' ],
 137 ]
 138 foreach h : host_defines
 139   if h.get(0) == host_machine.cpu()
 140     cdata.set(h.get(1), 1)
 141   endif
 142 endforeach
 143 # FIXME: should really be called HOST_CPU or such
 144 cdata.set_quoted('TARGET_CPU', host_machine.cpu())
 145
 146 check_headers = [
 147   'dlfcn.h',
 148   'inttypes.h',
 149   'memory.h',
 150   'poll.h',
 151   'stdint.h',
 152   'stdio_ext.h',
 153   'strings.h',
 154   'string.h',
 155   'sys/param.h',
 156   'sys/poll.h',
 157   'sys/prctl.h',
 158   'sys/socket.h',
 159   'sys/stat.h',
 160   'sys/times.h',
 161   'sys/time.h',
 162   'sys/types.h',
 163   'sys/utsname.h',
 164   'sys/wait.h',
 165   'ucontext.h',
 166   'unistd.h',
 167   'valgrind/valgrind.h',
 168   'sys/resource.h',
 169 ]
 170
 171 if host_system == 'windows'
 172   check_headers += ['winsock2.h']
 173 endif
 174
 175 foreach h : check_headers
 176   if cc.has_header(h)
 177     define = 'HAVE_' + h.underscorify().to_upper()
 178     cdata.set(define, 1)
 179   endif
 180 endforeach
 181
 182 if cc.has_member('struct tm', 'tm_gmtoff', prefix : '#include <time.h>')
 183   cdata.set('HAVE_TM_GMTOFF', 1)
 184 endif
 185
 186 check_functions = [
 187   'gmtime_r',
 188   'sigaction',
 189   'getrusage',
 190   'fseeko',
 191   'ftello',
 192   'poll',
 193   'ppoll',
 194   'pselect',
 195   'getpagesize',
 196   'clock_gettime',
 197   # These are needed by libcheck
 198   'getline',
 199   'mkstemp',
 200   'alarm',
 201   'gettimeofday',
 202 ]
 203
 204 foreach f : check_functions
 205   if cc.has_function(f)
 206     define = 'HAVE_' + f.underscorify().to_upper()
 207     cdata.set(define, 1)
 208   endif
 209 endforeach
 210
 211 if cc.has_function('localtime_r', prefix : '#include<time.h>')
 212   cdata.set('HAVE_LOCALTIME_R', 1)
 213   # Needed by libcheck
 214   cdata.set('HAVE_DECL_LOCALTIME_R', 1)
 215 endif
 216
 217 if cc.links('''#include <pthread.h>
 218                int main() {
 219                  pthread_setname_np("example"); return 0;
 220                }''', name : 'pthread_setname_np(const char*)')
 221   cdata.set('HAVE_PTHREAD_SETNAME_NP_WITHOUT_TID', 1)
 222 endif
 223
 224 # Check for posix timers and the monotonic clock
 225 time_prefix = '#include <time.h>\n'
 226 if cdata.has('HAVE_UNISTD_H')
 227   time_prefix += '#include <unistd.h>'
 228 endif
 229
 230 posix_timers_src = time_prefix + '''
 231 #if !defined(_POSIX_TIMERS) || _POSIX_TIMERS < 0 || !defined(CLOCK_REALTIME)
 232 #error Either _POSIX_TIMERS or CLOCK_REALTIME not defined
 233 #endif
 234 '''
 235 if cc.compiles(posix_timers_src, name : 'posix timers from time.h')
 236   cdata.set('HAVE_POSIX_TIMERS', 1)
 237 endif
 238
 239 monotonic_clock_src = time_prefix + '''
 240 #if !defined(_POSIX_MONOTONIC_CLOCK) || _POSIX_MONOTONIC_CLOCK < 0 || !defined(CLOCK_MONOTONIC)
 241 #error Either _POSIX_MONOTONIC_CLOCK or CLOCK_MONOTONIC not defined
 242 #endif
 243 '''
 244 if cc.compiles(monotonic_clock_src, name : 'monotonic clock from time.h')
 245   cdata.set('HAVE_MONOTONIC_CLOCK', 1)
 246 endif
 247
 248 # Check for __uint128_t (gcc) by checking for 128-bit division
 249 uint128_t_src = '''int main() {
 250 static __uint128_t v1 = 100;
 251 static __uint128_t v2 = 10;
 252 static __uint128_t u;
 253 u = v1 / v2;
 254 }'''
 255 if cc.compiles(uint128_t_src, name : '__uint128_t available')
 256   cdata.set('HAVE_UINT128_T', 1)
 257 endif
 258
 259 # All supported platforms have long long now
 260 cdata.set('HAVE_LONG_LONG', 1)
 261
 262 # We only want to use the __declspec(dllexport/import) dance in GST_EXPORT when
 263 # building with MSVC
 264 if cc.get_id() == 'msvc'
 265   cdata.set('GSTCONFIG_BUILT_WITH_MSVC', 1)
 266 else
 267   cdata.set('GSTCONFIG_BUILT_WITH_MSVC', 0)
 268 endif
 269
 270 # -------------------------------------------------------------------------------------
 271 # config.h things needed by libcheck
 272 # -------------------------------------------------------------------------------------
 273 if cc.has_function('getpid')
 274   cdata.set('HAVE_GETPID', 1)
 275 elif host_system == 'windows' and cc.has_function('_getpid')
 276   cdata.set('HAVE_PROCESS_H', 1) # Used by gstreamer too
 277   cdata.set('HAVE__GETPID', 1)
 278 endif
 279 if cc.has_function('strdup')
 280   cdata.set('HAVE_DECL_STRDUP', 1)
 281 elif host_system == 'windows' and cc.has_function('_strdup')
 282   cdata.set('HAVE__STRDUP', 1) # Windows (MSVC)
 283 endif
 284 if host_system != 'windows'
 285   cdata.set('HAVE_FORK', 1)
 286 else
 287   # libcheck requires HAVE_FORK to be 0 when fork() is not available
 288   cdata.set('HAVE_FORK', 0)
 289 endif
 290 if cc.has_function('strsignal')
 291   cdata.set('HAVE_DECL_STRSIGNAL', 1)
 292 endif
 293 # Check for availability of types
 294 if not cc.has_type('clockid_t', prefix : '#include <time.h>')
 295   cdata.set('clockid_t', 'int')
 296 endif
 297 if not cc.has_type('timer_t', prefix : '#include <time.h>')
 298   cdata.set('timer_t', 'int')
 299 endif
 300 if not cc.has_members('struct timespec', 'tv_sec', 'tv_nsec',
 301                       prefix : '#include <time.h>')
 302   cdata.set('STRUCT_TIMESPEC_DEFINITION_MISSING', 1)
 303 endif
 304 if not cc.has_members('struct itimerspec', 'it_interval', 'it_value',
 305                       prefix : '#include <time.h>')
 306   cdata.set('STRUCT_ITIMERSPEC_DEFINITION_MISSING', 1)
 307 endif
 308
 309 # Platform deps; only ws2_32 and execinfo for now
 310 platform_deps = []
 311 if host_system == 'windows'
 312   platform_deps = [cc.find_library('ws2_32')]
 313 endif
 314
 315 backtrace_deps = []
 316 unwind_dep = dependency('libunwind', required : get_option('libunwind'))
 317 dw_dep = dependency('libdw', required: get_option('libunwind'))
 318 backtrace_deps = [unwind_dep, dw_dep]
 319 if unwind_dep.found()
 320   cdata.set('HAVE_UNWIND', 1)
 321   if dw_dep.found()
 322     cdata.set('HAVE_DW', 1)
 323   else
 324     message('Support for backtraces is partial only.')
 325   endif
 326 else
 327   if cc.has_function('backtrace')
 328     cdata.set('HAVE_BACKTRACE', 1)
 329   else
 330       message('NO backtraces support.')
 331   endif
 332 endif
 333
 334 if cc.has_header('execinfo.h')
 335   if cc.has_function('backtrace', prefix : '#include <execinfo.h>')
 336     cdata.set('HAVE_BACKTRACE', 1)
 337   else
 338     execinfo_dep = cc.find_library('execinfo', required : false)
 339     if execinfo_dep.found() and cc.has_function('backtrace', prefix : '#include <execinfo.h>', dependencies : execinfo_dep)
 340       cdata.set('HAVE_BACKTRACE', 1)
 341       platform_deps += execinfo_dep
 342     endif
 343   endif
 344 endif
 345
 346 gst_debug = get_option('gst_debug')
 347 if not gst_debug
 348   add_project_arguments(['-Wno-unused'], language: 'c')
 349 endif
 350
 351 warning_flags = [
 352   '-Wmissing-declarations',
 353   '-Wmissing-prototypes',
 354   '-Wredundant-decls',
 355   '-Wundef',
 356   '-Wwrite-strings',
 357   '-Wformat',
 358   '-Wformat-nonliteral',
 359   '-Wformat-security',
 360   '-Wold-style-definition',
 361   '-Winit-self',
 362   '-Wmissing-include-dirs',
 363   '-Waddress',
 364   '-Waggregate-return',
 365   '-Wno-multichar',
 366   '-Wnested-externs',
 367   '-Wdeclaration-after-statement',
 368   '-Wvla',
 369   '-Wpointer-arith',
 370 ]
 371
 372 foreach extra_arg : warning_flags
 373   if cc.has_argument (extra_arg)
 374     add_project_arguments([extra_arg], language: 'c')
 375   endif
 376 endforeach
 377
 378 # Used by the gstutils test
 379 gmp_dep = cc.find_library('gmp', required : false)
 380 cdata.set('HAVE_GMP', gmp_dep.found())
 381 gsl_dep = cc.find_library('gsl', required : false)
 382 gslcblas_dep = cc.find_library('gslcblas', required : false)
 383 cdata.set('HAVE_GSL', gsl_dep.found() and gslcblas_dep.found())
 384 test_deps = [gmp_dep, gsl_dep, gslcblas_dep]
 385
 386 # Used by gstinfo.c
 387 dl_dep = cc.find_library('dl', required : false)
 388 cdata.set('HAVE_DLADDR', cc.has_function('dladdr', dependencies : dl_dep))
 389 cdata.set('GST_ENABLE_EXTRA_CHECKS', get_option('extra-checks'))
 390 cdata.set('USE_POISONING', get_option('poisoning'))
 391
 392 configinc = include_directories('.')
 393 libsinc = include_directories('libs')
 394 privinc = include_directories('gst')
 395
 396 # Find dependencies
 397 glib_dep = dependency('glib-2.0', version : '>=2.32.0',
 398   fallback: ['glib', 'libglib_dep'])
 399 gobject_dep = dependency('gobject-2.0',
 400   fallback: ['glib', 'libgobject_dep'])
 401 gmodule_dep = dependency('gmodule-2.0',
 402   fallback: ['glib', 'libgmodule_dep'])
 403 if host_system == 'windows'
 404     gio_dep = dependency('gio-2.0',
 405         fallback: ['glib', 'libgio_dep'])
 406 else
 407     gio_dep = [dependency('gio-2.0',
 408                   fallback: ['glib', 'libgio_dep']),
 409                dependency('gio-unix-2.0',
 410                   fallback: ['glib', 'libgio_dep'])]
 411 endif
 412
 413 mathlib = cc.find_library('m', required : false)
 414 # Needed for timer_create/settime/delete
 415 # Also provides clock_gettime in glibc < 2.17
 416 rt_lib = cc.find_library('rt', required : false)
 417
 418 gir = find_program('g-ir-scanner', required : get_option('introspection'))
 419 gnome = import('gnome')
 420
 421 build_gir = gir.found() and not meson.is_cross_build()
 422
 423 gir_init_section = [ '--add-init-section=extern void gst_init(gint*,gchar**);' + \
 424     'g_setenv("GST_REGISTRY_DISABLE", "yes", TRUE);' + \
 425     'g_setenv("GST_REGISTRY_1.0", "/no/way/this/exists.reg", TRUE);' + \
 426     'g_setenv("GST_PLUGIN_PATH_1_0", "", TRUE);' + \
 427     'g_setenv("GST_PLUGIN_SYSTEM_PATH_1_0", "", TRUE);' + \
 428     'gst_init(NULL,NULL);' ]
 429
 430 gst_c_args = ['-DHAVE_CONFIG_H']
 431
 432 # FIXME: This is only needed on windows and probably breaks when
 433 # default_library = 'both'. We should add this flag to static_c_args instead
 434 # when Meson supports it: https://github.com/mesonbuild/meson/issues/3304
 435 if get_option('default_library') == 'static'
 436   gst_c_args += ['-DGST_STATIC_COMPILATION']
 437 endif
 438
 439 # Used in gst/parse/meson.build and below
 440 python3 = import('python3').find_python()
 441
 442 bashcomp_option = get_option('bash-completion')
 443 bashcomp_dep = dependency('bash-completion', version : '>= 2.0', required : bashcomp_option)
 444 bash_completions_dir = ''
 445 bash_helpers_dir = ''
 446
 447 bashcomp_found = false
 448 if bashcomp_dep.found()
 449   bashcomp_found = true
 450   bash_completions_dir = bashcomp_dep.get_pkgconfig_variable('completionsdir', define_variable: ['prefix', '.'])
 451   if bash_completions_dir == ''
 452     msg = 'Found bash-completion but the .pc file did not set \'completionsdir\'.'
 453     if bashcomp_option.enabled()
 454       error(msg)
 455     else
 456       message(msg)
 457     endif
 458     bashcomp_found = false
 459   endif
 460
 461   bash_helpers_dir = bashcomp_dep.get_pkgconfig_variable('helpersdir', define_variable: ['prefix', '.'])
 462   if bash_helpers_dir == ''
 463     msg = 'Found bash-completion, but the .pc file did not set \'helpersdir\'.'
 464     if bashcomp_option.enabled()
 465       error(msg)
 466     else
 467       message(msg)
 468     endif
 469     bashcomp_found = false
 470   endif
 471 endif
 472
 473 subdir('gst')
 474 subdir('libs')
 475 subdir('plugins')
 476 if not get_option('tools').disabled()
 477   subdir('tools')
 478 endif
 479 subdir('pkgconfig')
 480 subdir('tests')
 481 subdir('data')
 482
 483 # xgettext is optional (on Windows for instance)
 484 if find_program('xgettext', required : get_option('nls')).found()
 485   cdata.set('ENABLE_NLS', 1)
 486   subdir('po')
 487 endif
 488
 489 configure_file(output : 'config.h', configuration : cdata)
 490
 491 if build_machine.system() == 'windows'
 492   message('Disabling gtk-doc while building on Windows')
 493 else
 494   if find_program('gtkdoc-scan', required : get_option('gtk_doc')).found()
 495     subdir('docs')
 496   else
 497     message('Not building documentation as gtk-doc was not found')
 498   endif
 499 endif
 500
 501 run_command(python3, '-c', 'import shutil; shutil.copy("hooks/pre-commit.hook", ".git/hooks/pre-commit")')
 502
 503 install_data('gst-element-check-1.0.m4', install_dir : join_paths(get_option('datadir'), 'aclocal'))