meson.build

   1 project('gst-rtsp-server', 'c',
   2   version : '1.13.91',
   3   meson_version : '>= 0.33.0',
   4   default_options : ['warning_level=1', 'buildtype=debugoptimized'])
   5
   6 gst_version = meson.project_version()
   7 version_arr = gst_version.split('.')
   8 gst_version_major = version_arr[0].to_int()
   9 gst_version_minor = version_arr[1].to_int()
  10 gst_version_micro = version_arr[2].to_int()
  11  if version_arr.length() == 4
  12   gst_version_nano = version_arr[3].to_int()
  13 else
  14   gst_version_nano = 0
  15 endif
  16
  17 glib_req = '>= 2.40.0'
  18 gst_req = '>= @0@.@1@.0'.format(gst_version_major, gst_version_minor)
  19
  20 api_version = '1.0'
  21 soversion = 0
  22 # maintaining compatibility with the previous libtool versioning
  23 # current = minor * 100 + micro
  24 libversion = '@0@.@1@.0'.format(soversion, gst_version_minor * 100 + gst_version_micro)
  25
  26 plugins_install_dir = '@0@/gstreamer-1.0'.format(get_option('libdir'))
  27
  28 cc = meson.get_compiler('c')
  29
  30 # Symbol visibility
  31 if cc.has_argument('-fvisibility=hidden')
  32   add_project_arguments('-fvisibility=hidden', language: 'c')
  33 endif
  34
  35 # Disable strict aliasing
  36 if cc.has_argument('-fno-strict-aliasing')
  37   add_project_arguments('-fno-strict-aliasing', language: 'c')
  38 endif
  39
  40 cdata = configuration_data()
  41 cdata.set_quoted('GETTEXT_PACKAGE', 'gst-rtsp-server-1.0')
  42 cdata.set_quoted('PACKAGE', 'gst-rtsp-server')
  43 cdata.set_quoted('VERSION', gst_version)
  44 cdata.set_quoted('PACKAGE_VERSION', gst_version)
  45 cdata.set_quoted('GST_API_VERSION', api_version)
  46 cdata.set_quoted('GST_LICENSE', 'LGPL')
  47
  48 # FIXME: ENABLE_NLS (currently also missing from autotools build)
  49 # cdata.set('ENABLE_NLS', true)
  50 # cdata.set_quoted('LOCALEDIR', join_paths(get_option('prefix'), get_option('localedir')))
  51
  52 # GStreamer package name and origin url
  53 gst_package_name = get_option('with-package-name')
  54 if gst_package_name == ''
  55   if gst_version_nano == 0
  56     gst_package_name = 'GStreamer RTSP Server Library source release'
  57   elif gst_version_nano == 1
  58     gst_package_name = 'GStreamer RTSP Server Library git'
  59   else
  60     gst_package_name = 'GStreamer RTSP Server Library prerelease'
  61   endif
  62 endif
  63 cdata.set_quoted('GST_PACKAGE_NAME', gst_package_name)
  64 cdata.set_quoted('GST_PACKAGE_ORIGIN', get_option('with-package-origin'))
  65
  66 configure_file(output : 'config.h', configuration : cdata)
  67
  68 rtspserver_args = ['-DHAVE_CONFIG_H']
  69
  70 warning_flags = [
  71   '-Wmissing-declarations',
  72   '-Wmissing-prototypes',
  73   '-Wredundant-decls',
  74   '-Wundef',
  75   '-Wwrite-strings',
  76   '-Wformat',
  77   '-Wformat-nonliteral',
  78   '-Wformat-security',
  79   '-Wold-style-definition',
  80   '-Waggregate-return',
  81   '-Wnested-externs',
  82   '-Winit-self',
  83   '-Wmissing-include-dirs',
  84   '-Waddress',
  85   '-Wno-multichar',
  86   '-Wdeclaration-after-statement',
  87   '-Wvla',
  88   '-Wpointer-arith',
  89 ]
  90
  91 foreach extra_arg : warning_flags
  92   if cc.has_argument (extra_arg)
  93     add_project_arguments([extra_arg], language: 'c')
  94   endif
  95 endforeach
  96
  97 rtspserver_incs = include_directories('gst/rtsp-server', '.')
  98
  99 glib_dep = dependency('glib-2.0', version : glib_req,
 100   fallback: ['glib', 'libglib_dep'])
 101 gst_dep = dependency('gstreamer-1.0', version : gst_req,
 102   fallback : ['gstreamer', 'gst_dep'])
 103 gstrtsp_dep = dependency('gstreamer-rtsp-1.0', version : gst_req,
 104   fallback : ['gst-plugins-base', 'rtsp_dep'])
 105 gstrtp_dep = dependency('gstreamer-rtp-1.0', version : gst_req,
 106   fallback : ['gst-plugins-base', 'rtp_dep'])
 107 gstsdp_dep = dependency('gstreamer-sdp-1.0', version : gst_req,
 108   fallback : ['gst-plugins-base', 'sdp_dep'])
 109 gstapp_dep = dependency('gstreamer-app-1.0', version : gst_req,
 110   fallback : ['gst-plugins-base', 'app_dep'])
 111 gstnet_dep = dependency('gstreamer-net-1.0', version : gst_req,
 112   fallback : ['gstreamer', 'gst_net_dep'])
 113
 114 gir = find_program('g-ir-scanner', required : false)
 115 gnome = import('gnome')
 116 build_gir = gir.found() and not meson.is_cross_build() and not get_option('disable_introspection')
 117 gir_init_section = [ '--add-init-section=extern void gst_init(gint*,gchar**);' + \
 118     'g_setenv("GST_REGISTRY_1.0", "@0@", TRUE);'.format(meson.current_build_dir() + '/gir_empty_registry.reg') + \
 119     'g_setenv("GST_PLUGIN_PATH_1_0", "", TRUE);' + \
 120     'g_setenv("GST_PLUGIN_SYSTEM_PATH_1_0", "", TRUE);' + \
 121     'gst_init(NULL,NULL);' ]
 122
 123 subdir('gst')
 124 if get_option('tests')
 125   subdir('tests')
 126 endif
 127 if get_option('examples')
 128   subdir('examples')
 129 endif
 130 subdir('pkgconfig')