meson.build

   1 project('gstreamer-vaapi', 'c',
   2   version : '1.13.0.1',
   3   meson_version : '>= 0.36.0',
   4   default_options : [ 'warning_level=1',
   5                       'buildtype=debugoptimized' ])
   6
   7 gst_version = meson.project_version()
   8 version_arr = gst_version.split('.')
   9 gst_version_major = version_arr[0]
  10 gst_version_minor = version_arr[1]
  11 gst_version_micro = version_arr[2]
  12 if version_arr.length() == 4
  13   gst_version_nano = version_arr[3]
  14 else
  15   gst_version_nano = 0
  16 endif
  17
  18 glib_req = '>= 2.40.0'
  19 gst_req = '>= @0@.@1@.0'.format(gst_version_major, gst_version_minor)
  20
  21 # Mandatory GST deps
  22 cc = meson.get_compiler('c')
  23
  24 libm = cc.find_library('m', required : false)
  25 gst_dep = dependency('gstreamer-1.0', version : gst_req,
  26   fallback : ['gstreamer', 'gst_dep'])
  27 gstbase_dep = dependency('gstreamer-base-1.0', version : gst_req,
  28   fallback : ['gstreamer', 'gst_base_dep'])
  29 gstpbutils_dep = dependency('gstreamer-pbutils-1.0', version : gst_req,
  30     fallback : ['gst-plugins-base', 'pbutils_dep'])
  31 gstallocators_dep = dependency('gstreamer-allocators-1.0', version : gst_req,
  32     fallback : ['gst-plugins-base', 'allocators_dep'])
  33 gstvideo_dep = dependency('gstreamer-video-1.0', version : gst_req,
  34     fallback : ['gst-plugins-base', 'video_dep'])
  35 gstcodecparsers_dep = dependency('gstreamer-codecparsers-1.0', version : gst_req,
  36     fallback : ['gst-plugins-bad', 'gstcodecparsers_dep'])
  37 gstgl_dep = dependency('gstreamer-gl-1.0', version : gst_req,
  38     fallback : ['gst-plugins-bad', 'gstgl_dep'], required: false)
  39 gmodule_dep = dependency('gmodule-2.0', required: false)
  40 libva_dep = dependency('libva', version: ['>= 0.30.4', '< 0.99.0'])
  41
  42 libva_drm_dep = dependency('libva-drm', version: '>= 0.33.0', required: false)
  43 libva_wayland_dep = dependency('libva-wayland', version: '>= 0.33.0', required: false)
  44 libva_x11_dep = dependency('libva-x11', version: '>= 0.31.0', required: false)
  45 libdrm_dep = dependency('libdrm', required: false)
  46 libudev_dep = dependency('libudev', required: false)
  47 egl_dep = dependency('egl', required: false)
  48 gl_dep = dependency('gl', required: false)
  49 glesv2_dep = dependency('glesv2', required: false)
  50 glesv3_dep = dependency('glesv3', required: false)
  51 libdl_dep = cc.find_library('dl', rqeuired: false)
  52 wayland_client_dep = dependency('wayland-client', required: false)
  53 x11_dep = dependency('x11', required: false)
  54 xrandr_dep = dependency('xrandr', required: false)
  55 xrender_dep = dependency('xrender', required: false)
  56
  57 GLES_VERSION_MASK = 0
  58 GLES_VERSION_MASK += gl_dep.found() ? 1 : 0
  59 GLES_VERSION_MASK += glesv2_dep.found() ? 4 : 0
  60 GLES_VERSION_MASK += glesv3_dep.found() ? 8 : 0
  61
  62 USE_ENCODERS = libva_dep.version().version_compare('>= 0.34.0') and get_option('with_encoders') != 'no'
  63 USE_H265_DECODER = cc.has_header('va/va_dec_hevc.h', dependencies: libva_dep, prefix: '#include <va/va.h>')
  64 USE_H265_ENCODER = USE_ENCODERS and cc.has_header('va/va_enc_hevc.h', dependencies: libva_dep, prefix: '#include <va/va.h>')
  65 USE_JPEG_DECODER = cc.has_header('va/va_dec_jpeg.h', dependencies: libva_dep, prefix: '#include <va/va.h>')
  66 USE_JPEG_ENCODER = USE_ENCODERS and cc.has_header('va/va_enc_jpeg.h', dependencies: libva_dep, prefix: '#include <va/va.h>')
  67 USE_VP8_DECODER = cc.has_header('va/va_dec_vp8.h', dependencies: libva_dep, prefix: '#include <va/va.h>')
  68 USE_VP8_ENCODER = USE_ENCODERS and cc.has_header('va/va_enc_vp8.h', dependencies: libva_dep, prefix: '#include <va/va.h>')
  69 USE_VP9_DECODER = cc.has_header('va/va_dec_vp9.h', dependencies: libva_dep, prefix: '#include <va/va.h>')
  70 USE_VP9_ENCODER = USE_ENCODERS and cc.has_header('va/va_enc_vp9.h', dependencies: libva_dep, prefix: '#include <va/va.h>')
  71
  72 USE_DRM = libva_drm_dep.found() and libdrm_dep.found() and libudev_dep.found() and get_option('with_drm') != 'no'
  73 USE_EGL = gmodule_dep.found() and egl_dep.found() and GLES_VERSION_MASK != 0 and get_option('with_egl') != 'no'
  74 USE_GLX = libva_x11_dep.found() and x11_dep.found() and gl_dep.found() and libdl_dep.found() and get_option('with_glx') != 'no'
  75 USE_WAYLAND = libva_wayland_dep.found() and wayland_client_dep.found() and get_option('with_wayland') != 'no'
  76 USE_X11 = libva_x11_dep.found() and x11_dep.found() and get_option('with_x11') != 'no'
  77
  78 cdata = configuration_data()
  79 cdata.set('GST_API_VERSION_S', '"@0@.@1@"'.format(gst_version_major, gst_version_minor))
  80 cdata.set('PACKAGE', '"gstreamer-vaapi"')
  81 cdata.set('VERSION', '"@0@"'.format(gst_version))
  82 cdata.set('PACKAGE_VERSION', '"@0@"'.format(gst_version))
  83 cdata.set('PACKAGE_NAME', '"GStreamer VA-API Plug-ins"')
  84 cdata.set('PACKAGE_STRING', '"GStreamer VA-API Plug-ins @0@"'.format(gst_version))
  85 cdata.set('PACKAGE_BUGREPORT', '"http://bugzilla.gnome.org/enter_bug.cgi?product=GStreamer"')
  86 cdata.set10('USE_DRM', USE_DRM)
  87 cdata.set10('USE_EGL', USE_EGL)
  88 cdata.set10('USE_ENCODERS', USE_ENCODERS)
  89 cdata.set10('USE_GLX', USE_GLX)
  90 cdata.set10('USE_H265_DECODER', USE_H265_DECODER)
  91 cdata.set10('USE_H265_ENCODER', USE_H265_ENCODER)
  92 cdata.set10('USE_JPEG_DECODER', USE_JPEG_DECODER)
  93 cdata.set10('USE_JPEG_ENCODER', USE_JPEG_ENCODER)
  94 cdata.set10('USE_VP8_DECODER', USE_VP8_DECODER)
  95 cdata.set10('USE_VP8_ENCODER', USE_VP8_ENCODER)
  96 cdata.set10('USE_VP9_DECODER', USE_VP9_DECODER)
  97 cdata.set10('USE_VP9_ENCODER', USE_VP9_ENCODER)
  98 cdata.set10('USE_WAYLAND', USE_WAYLAND)
  99 cdata.set10('USE_X11', USE_X11)
 100 cdata.set10('HAVE_XKBLIB', cc.has_header('X11/XKBlib.h', dependencies: x11_dep))
 101 cdata.set10('HAVE_XRANDR', xrandr_dep.found())
 102 cdata.set10('HAVE_XRENDER', xrender_dep.found())
 103 cdata.set10('USE_VA_VPP', true)
 104 cdata.set10('USE_GST_GL_HELPERS', gstgl_dep.found())
 105 cdata.set('GLES_VERSION_MASK', GLES_VERSION_MASK)
 106 runcmd = run_command('pkg-config', '--variable=driverdir', 'libva')
 107 if runcmd.returncode() == 0
 108   cdata.set('VA_DRIVERS_PATH', '"@0@"'.format(runcmd.stdout().strip()))
 109 endif
 110
 111 api_version = '1.0'
 112 soversion = 0
 113 # maintaining compatibility with the previous libtool versioning
 114 # current = minor * 100 + micro
 115 libversion = '@0@.@1@.0'.format(soversion, gst_version_minor.to_int() * 100 + gst_version_micro.to_int())
 116
 117 plugins_install_dir = '@0@/gstreamer-1.0'.format(get_option('libdir'))
 118
 119 configure_file(configuration: cdata, output: 'config.h')
 120 gstreamer_vaapi_args = ['-DHAVE_CONFIG_H']
 121 configinc = include_directories('.')
 122 libsinc = include_directories('gst-libs')
 123
 124 subdir('gst-libs')
 125 subdir('gst')
 126 #subdir('tests')
 127
 128 python3 = import('python3').find_python()
 129 run_command(python3, '-c', 'import shutil; shutil.copy("hooks/pre-commit.hook", ".git/hooks/pre-commit")')