meson.build

   1 project('gstreamer-vaapi', 'c',
   2   version : '1.13.0.1',
   3   meson_version : '>= 0.36.0',
   4   default_options : [ 'warning_level=1',
   5                       'buildtype=debugoptimized' ])
   6
   7 gst_version = meson.project_version()
   8 version_arr = gst_version.split('.')
   9 gst_version_major = version_arr[0]
  10 gst_version_minor = version_arr[1]
  11 gst_version_micro = version_arr[2]
  12 if version_arr.length() == 4
  13   gst_version_nano = version_arr[3]
  14 else
  15   gst_version_nano = 0
  16 endif
  17
  18 libva_req = ['>= 0.30.4', '!= 0.99.0']
  19 glib_req = '>= 2.40.0'
  20 gst_req = '>= @0@.@1@.0'.format(gst_version_major, gst_version_minor)
  21
  22 # Mandatory GST deps
  23 cc = meson.get_compiler('c')
  24
  25 libm = cc.find_library('m', required : false)
  26 gst_dep = dependency('gstreamer-1.0', version : gst_req,
  27   fallback : ['gstreamer', 'gst_dep'])
  28 gstbase_dep = dependency('gstreamer-base-1.0', version : gst_req,
  29   fallback : ['gstreamer', 'gst_base_dep'])
  30 gstpbutils_dep = dependency('gstreamer-pbutils-1.0', version : gst_req,
  31     fallback : ['gst-plugins-base', 'pbutils_dep'])
  32 gstallocators_dep = dependency('gstreamer-allocators-1.0', version : gst_req,
  33     fallback : ['gst-plugins-base', 'allocators_dep'])
  34 gstvideo_dep = dependency('gstreamer-video-1.0', version : gst_req,
  35     fallback : ['gst-plugins-base', 'video_dep'])
  36 gstcodecparsers_dep = dependency('gstreamer-codecparsers-1.0', version : gst_req,
  37     fallback : ['gst-plugins-bad', 'gstcodecparsers_dep'])
  38 gstgl_dep = dependency('gstreamer-gl-1.0', version : gst_req,
  39     fallback : ['gst-plugins-bad', 'gstgl_dep'], required: false)
  40 gmodule_dep = dependency('gmodule-2.0', required: false)
  41 libva_dep = dependency('libva', version: libva_req)
  42
  43 libva_drm_dep = dependency('libva-drm', version: '>= 0.33.0', required: false)
  44 libva_wayland_dep = dependency('libva-wayland', version: '>= 0.33.0', required: false)
  45 libva_x11_dep = dependency('libva-x11', version: '>= 0.31.0', required: false)
  46 libdrm_dep = dependency('libdrm', required: false)
  47 libudev_dep = dependency('libudev', required: false)
  48 egl_dep = dependency('egl', required: false)
  49 gl_dep = dependency('gl', required: false)
  50 glesv2_dep = dependency('glesv2', required: false)
  51 glesv3_dep = dependency('glesv3', required: false)
  52 libdl_dep = cc.find_library('dl', rqeuired: false)
  53 wayland_client_dep = dependency('wayland-client', required: false)
  54 x11_dep = dependency('x11', required: false)
  55 xrandr_dep = dependency('xrandr', required: false)
  56 xrender_dep = dependency('xrender', required: false)
  57
  58 GLES_VERSION_MASK = 0
  59 GLES_VERSION_MASK += gl_dep.found() ? 1 : 0
  60 GLES_VERSION_MASK += glesv2_dep.found() ? 4 : 0
  61 GLES_VERSION_MASK += glesv3_dep.found() ? 8 : 0
  62
  63 USE_ENCODERS = libva_dep.version().version_compare('>= 0.34.0') and get_option('with_encoders') != 'no'
  64 USE_H265_DECODER = cc.has_header('va/va_dec_hevc.h', dependencies: libva_dep, prefix: '#include <va/va.h>')
  65 USE_H265_ENCODER = USE_ENCODERS and cc.has_header('va/va_enc_hevc.h', dependencies: libva_dep, prefix: '#include <va/va.h>')
  66 USE_JPEG_DECODER = cc.has_header('va/va_dec_jpeg.h', dependencies: libva_dep, prefix: '#include <va/va.h>')
  67 USE_JPEG_ENCODER = USE_ENCODERS and cc.has_header('va/va_enc_jpeg.h', dependencies: libva_dep, prefix: '#include <va/va.h>')
  68 USE_VP8_DECODER = cc.has_header('va/va_dec_vp8.h', dependencies: libva_dep, prefix: '#include <va/va.h>')
  69 USE_VP8_ENCODER = USE_ENCODERS and cc.has_header('va/va_enc_vp8.h', dependencies: libva_dep, prefix: '#include <va/va.h>')
  70 USE_VP9_DECODER = cc.has_header('va/va_dec_vp9.h', dependencies: libva_dep, prefix: '#include <va/va.h>')
  71 USE_VP9_ENCODER = USE_ENCODERS and cc.has_header('va/va_enc_vp9.h', dependencies: libva_dep, prefix: '#include <va/va.h>')
  72
  73 USE_DRM = libva_drm_dep.found() and libdrm_dep.found() and libudev_dep.found() and get_option('with_drm') != 'no'
  74 USE_EGL = gmodule_dep.found() and egl_dep.found() and GLES_VERSION_MASK != 0 and get_option('with_egl') != 'no'
  75 USE_GLX = libva_x11_dep.found() and x11_dep.found() and gl_dep.found() and libdl_dep.found() and get_option('with_glx') != 'no'
  76 USE_WAYLAND = libva_wayland_dep.found() and wayland_client_dep.found() and get_option('with_wayland') != 'no'
  77 USE_X11 = libva_x11_dep.found() and x11_dep.found() and get_option('with_x11') != 'no'
  78
  79 cdata = configuration_data()
  80 cdata.set('GST_API_VERSION_S', '"@0@.@1@"'.format(gst_version_major, gst_version_minor))
  81 cdata.set('PACKAGE', '"gstreamer-vaapi"')
  82 cdata.set('VERSION', '"@0@"'.format(gst_version))
  83 cdata.set('PACKAGE_VERSION', '"@0@"'.format(gst_version))
  84 cdata.set('PACKAGE_NAME', '"GStreamer VA-API Plug-ins"')
  85 cdata.set('PACKAGE_STRING', '"GStreamer VA-API Plug-ins @0@"'.format(gst_version))
  86 cdata.set('PACKAGE_BUGREPORT', '"http://bugzilla.gnome.org/enter_bug.cgi?product=GStreamer"')
  87 cdata.set10('USE_DRM', USE_DRM)
  88 cdata.set10('USE_EGL', USE_EGL)
  89 cdata.set10('USE_ENCODERS', USE_ENCODERS)
  90 cdata.set10('USE_GLX', USE_GLX)
  91 cdata.set10('USE_H265_DECODER', USE_H265_DECODER)
  92 cdata.set10('USE_H265_ENCODER', USE_H265_ENCODER)
  93 cdata.set10('USE_JPEG_DECODER', USE_JPEG_DECODER)
  94 cdata.set10('USE_JPEG_ENCODER', USE_JPEG_ENCODER)
  95 cdata.set10('USE_VP8_DECODER', USE_VP8_DECODER)
  96 cdata.set10('USE_VP8_ENCODER', USE_VP8_ENCODER)
  97 cdata.set10('USE_VP9_DECODER', USE_VP9_DECODER)
  98 cdata.set10('USE_VP9_ENCODER', USE_VP9_ENCODER)
  99 cdata.set10('USE_WAYLAND', USE_WAYLAND)
 100 cdata.set10('USE_X11', USE_X11)
 101 cdata.set10('HAVE_XKBLIB', cc.has_header('X11/XKBlib.h', dependencies: x11_dep))
 102 cdata.set10('HAVE_XRANDR', xrandr_dep.found())
 103 cdata.set10('HAVE_XRENDER', xrender_dep.found())
 104 cdata.set10('USE_VA_VPP', true)
 105 cdata.set10('USE_GST_GL_HELPERS', gstgl_dep.found())
 106 cdata.set('GLES_VERSION_MASK', GLES_VERSION_MASK)
 107 runcmd = run_command('pkg-config', '--variable=driverdir', 'libva')
 108 if runcmd.returncode() == 0
 109   cdata.set('VA_DRIVERS_PATH', '"@0@"'.format(runcmd.stdout().strip()))
 110 endif
 111
 112 api_version = '1.0'
 113 soversion = 0
 114 # maintaining compatibility with the previous libtool versioning
 115 # current = minor * 100 + micro
 116 libversion = '@0@.@1@.0'.format(soversion, gst_version_minor.to_int() * 100 + gst_version_micro.to_int())
 117
 118 plugins_install_dir = '@0@/gstreamer-1.0'.format(get_option('libdir'))
 119
 120 configure_file(configuration: cdata, output: 'config.h')
 121 gstreamer_vaapi_args = ['-DHAVE_CONFIG_H']
 122 configinc = include_directories('.')
 123 libsinc = include_directories('gst-libs')
 124
 125 subdir('gst-libs')
 126 subdir('gst')
 127 #subdir('tests')
 128
 129 python3 = import('python3').find_python()
 130 run_command(python3, '-c', 'import shutil; shutil.copy("hooks/pre-commit.hook", ".git/hooks/pre-commit")')