meson.build

   1 project('gst-plugins-good', 'c',
   2   version : '1.17.0.1',
   3   meson_version : '>= 0.48',
   4   default_options : [ 'warning_level=1',
   5                       'buildtype=debugoptimized' ])
   6
   7 gst_version = meson.project_version()
   8 version_arr = gst_version.split('.')
   9 gst_version_major = version_arr[0].to_int()
  10 gst_version_minor = version_arr[1].to_int()
  11 gst_version_micro = version_arr[2].to_int()
  12  if version_arr.length() == 4
  13   gst_version_nano = version_arr[3].to_int()
  14 else
  15   gst_version_nano = 0
  16 endif
  17 gst_version_is_dev = gst_version_minor % 2 == 1 and gst_version_micro < 90
  18
  19 # FIXME: automagic
  20 have_cxx = add_languages('cpp', required : false)
  21
  22 glib_req = '>= 2.44.0'
  23 orc_req = '>= 0.4.17'
  24 gst_req = '>= @0@.@1@.0'.format(gst_version_major, gst_version_minor)
  25
  26 api_version = '1.0'
  27
  28 plugins_install_dir = join_paths(get_option('libdir'), 'gstreamer-1.0')
  29 plugins = []
  30
  31 cc = meson.get_compiler('c')
  32 host_system = host_machine.system()
  33
  34 if cc.get_id() == 'msvc'
  35   # Ignore several spurious warnings for things gstreamer does very commonly
  36   # If a warning is completely useless and spammy, use '/wdXXXX' to suppress it
  37   # If a warning is harmless but hard to fix, use '/woXXXX' so it's shown once
  38   # NOTE: Only add warnings here if you are sure they're spurious
  39   add_project_arguments(
  40       '/wd4018', # implicit signed/unsigned conversion
  41       '/wd4146', # unary minus on unsigned (beware INT_MIN)
  42       '/wd4244', # lossy type conversion (e.g. double -> int)
  43       '/wd4305', # truncating type conversion (e.g. double -> float)
  44       cc.get_supported_arguments(['/utf-8']), # set the input encoding to utf-8
  45       language : 'c')
  46   # Disable SAFESEH with MSVC for plugins and libs that use external deps that
  47   # are built with MinGW
  48   noseh_link_args = ['/SAFESEH:NO']
  49 else
  50   noseh_link_args = []
  51 endif
  52
  53 if cc.has_link_argument('-Wl,-Bsymbolic-functions')
  54   add_project_link_arguments('-Wl,-Bsymbolic-functions', language : 'c')
  55 endif
  56
  57 # Symbol visibility
  58 if cc.has_argument('-fvisibility=hidden')
  59   add_project_arguments('-fvisibility=hidden', language: 'c')
  60 endif
  61
  62 # Disable strict aliasing
  63 if cc.has_argument('-fno-strict-aliasing')
  64   add_project_arguments('-fno-strict-aliasing', language: 'c')
  65 endif
  66
  67 # Define G_DISABLE_DEPRECATED for development versions
  68 if gst_version_is_dev
  69   message('Disabling deprecated GLib API')
  70   add_project_arguments('-DG_DISABLE_DEPRECATED', language: 'c')
  71 endif
  72
  73 cast_checks = get_option('gobject-cast-checks')
  74 if cast_checks.disabled() or (cast_checks.auto() and not gst_version_is_dev)
  75   message('Disabling GLib cast checks')
  76   add_project_arguments('-DG_DISABLE_CAST_CHECKS', language: 'c')
  77 endif
  78
  79 glib_asserts = get_option('glib-asserts')
  80 if glib_asserts.disabled() or (glib_asserts.auto() and not gst_version_is_dev)
  81   message('Disabling GLib asserts')
  82   add_project_arguments('-DG_DISABLE_ASSERT', language: 'c')
  83 endif
  84
  85 glib_checks = get_option('glib-checks')
  86 if glib_checks.disabled() or (glib_checks.auto() and not gst_version_is_dev)
  87   message('Disabling GLib checks')
  88   add_project_arguments('-DG_DISABLE_CHECKS', language: 'c')
  89 endif
  90
  91 cdata = configuration_data()
  92
  93 check_headers = [
  94   ['HAVE_DLFCN_H', 'dlfcn.h'],
  95   ['HAVE_FCNTL_H', 'fcntl.h'],
  96   ['HAVE_INTTYPES_H', 'inttypes.h'],
  97   ['HAVE_MEMORY_H', 'memory.h'],
  98   ['HAVE_PROCESS_H', 'process.h'],
  99   ['HAVE_STDINT_H', 'stdint.h'],
 100   ['HAVE_STDLIB_H', 'stdlib.h'],
 101   ['HAVE_STRINGS_H', 'strings.h'],
 102   ['HAVE_STRING_H', 'string.h'],
 103   ['HAVE_SYS_IOCTL_H', 'sys/ioctl.h'],
 104   ['HAVE_SYS_PARAM_H', 'sys/param.h'],
 105   ['HAVE_SYS_SOCKET_H', 'sys/socket.h'],
 106   ['HAVE_SYS_STAT_H', 'sys/stat.h'],
 107   ['HAVE_SYS_TIME_H', 'sys/time.h'],
 108   ['HAVE_SYS_TYPES_H', 'sys/types.h'],
 109   ['HAVE_UNISTD_H', 'unistd.h'],
 110 ]
 111
 112 foreach h : check_headers
 113   if cc.has_header(h.get(1))
 114     cdata.set(h.get(0), 1)
 115   endif
 116 endforeach
 117
 118 check_functions = [
 119   ['HAVE_ASINH', 'asinh', '#include<math.h>'],
 120   ['HAVE_CLOCK_GETTIME', 'clock_gettime', '#include<time.h>'],
 121   ['HAVE_COSH', 'cosh', '#include<math.h>'],
 122 # check token HAVE_CPU_ALPHA
 123 # check token HAVE_CPU_ARM
 124 # check token HAVE_CPU_CRIS
 125 # check token HAVE_CPU_CRISV32
 126 # check token HAVE_CPU_HPPA
 127 # check token HAVE_CPU_I386
 128 # check token HAVE_CPU_IA64
 129 # check token HAVE_CPU_M68K
 130 # check token HAVE_CPU_MIPS
 131 # check token HAVE_CPU_PPC
 132 # check token HAVE_CPU_PPC64
 133 # check token HAVE_CPU_S390
 134 # check token HAVE_CPU_SPARC
 135 # check token HAVE_CPU_X86_64
 136   ['HAVE_DCGETTEXT', 'dcgettext', '#include<libintl.h>'],
 137 # check token HAVE_DIRECTSOUND
 138 # check token HAVE_EXPERIMENTAL
 139 # check token HAVE_EXTERNAL
 140 # check token HAVE_FPCLASS
 141 # check token HAVE_GCC_ASM
 142   ['HAVE_GETPAGESIZE', 'getpagesize', '#include<unistd.h>'],
 143 # check token HAVE_GETTEXT
 144 # check token HAVE_GST_V4L2
 145   ['HAVE_ISINF', 'isinf', '#include<math.h>'],
 146 # check token HAVE_LIBV4L2
 147   ['HAVE_MMAP', 'mmap', '#include<sys/mman.h>'],
 148   ['HAVE_MMAP64', 'mmap64', '#include<sys/mman.h>'],
 149 # check token HAVE_OSX_AUDIO
 150 # check token HAVE_OSX_VIDEO
 151 # check token HAVE_RDTSC
 152   ['HAVE_SINH', 'sinh', '#include<math.h>'],
 153 # check token HAVE_WAVEFORM
 154   ['HAVE_GMTIME_R', 'gmtime_r', '#include<time.h>'],
 155 ]
 156
 157 libm = cc.find_library('m', required : false)
 158
 159 foreach f : check_functions
 160   if cc.has_function(f.get(1), prefix : f.get(2), dependencies : libm)
 161     cdata.set(f.get(0), 1)
 162   endif
 163 endforeach
 164
 165 cdata.set('HAVE_IOS', host_system == 'ios')
 166
 167 cdata.set('SIZEOF_CHAR', cc.sizeof('char'))
 168 cdata.set('SIZEOF_INT', cc.sizeof('int'))
 169 cdata.set('SIZEOF_LONG', cc.sizeof('long'))
 170 cdata.set('SIZEOF_SHORT', cc.sizeof('short'))
 171 cdata.set('SIZEOF_VOIDP', cc.sizeof('void*'))
 172 cdata.set('SIZEOF_OFF_T', cc.sizeof('off_t'))
 173
 174 # Here be fixmes.
 175 # FIXME: check if this is correct
 176 cdata.set('HAVE_CPU_X86_64', host_machine.cpu() == 'amd64')
 177 cdata.set('HAVE_GCC_ASM', cc.get_id() != 'msvc')
 178 cdata.set_quoted('VERSION', gst_version)
 179 cdata.set_quoted('PACKAGE_VERSION', gst_version)
 180 cdata.set_quoted('GST_LICENSE', 'LGPL')
 181 cdata.set_quoted('PACKAGE', 'gst-plugins-good')
 182 cdata.set_quoted('GETTEXT_PACKAGE', 'gst-plugins-good-1.0')
 183 cdata.set_quoted('LOCALEDIR', join_paths(get_option('prefix'), get_option('localedir')))
 184
 185 warning_flags = [
 186   '-Wmissing-declarations',
 187   '-Wredundant-decls',
 188   '-Wwrite-strings',
 189   '-Winit-self',
 190   '-Wmissing-include-dirs',
 191   '-Wno-multichar',
 192   '-Wvla',
 193   '-Wpointer-arith',
 194 ]
 195
 196 warning_c_flags = [
 197   '-Wmissing-prototypes',
 198   '-Wdeclaration-after-statement',
 199   '-Wold-style-definition',
 200   '-Waggregate-return',
 201 ]
 202
 203 if have_cxx
 204   cxx = meson.get_compiler('cpp')
 205 endif
 206
 207 foreach extra_arg : warning_flags
 208   if cc.has_argument (extra_arg)
 209     add_project_arguments([extra_arg], language: 'c')
 210   endif
 211   if have_cxx and cxx.has_argument (extra_arg)
 212     add_project_arguments([extra_arg], language: 'cpp')
 213   endif
 214 endforeach
 215
 216 foreach extra_arg : warning_c_flags
 217   if cc.has_argument (extra_arg)
 218     add_project_arguments([extra_arg], language: 'c')
 219   endif
 220 endforeach
 221
 222 # GStreamer package name and origin url
 223 gst_package_name = get_option('package-name')
 224 if gst_package_name == ''
 225   if gst_version_nano == 0
 226     gst_package_name = 'GStreamer Good Plug-ins source release'
 227   elif gst_version_nano == 1
 228     gst_package_name = 'GStreamer Good Plug-ins git'
 229   else
 230     gst_package_name = 'GStreamer Good Plug-ins prerelease'
 231   endif
 232 endif
 233 cdata.set_quoted('GST_PACKAGE_NAME', gst_package_name)
 234 cdata.set_quoted('GST_PACKAGE_ORIGIN', get_option('package-origin'))
 235
 236 # Mandatory GST deps
 237 gst_dep = dependency('gstreamer-1.0', version : gst_req,
 238   fallback : ['gstreamer', 'gst_dep'])
 239 gstbase_dep = dependency('gstreamer-base-1.0', version : gst_req,
 240   fallback : ['gstreamer', 'gst_base_dep'])
 241 gstnet_dep = dependency('gstreamer-net-1.0', version : gst_req,
 242   fallback : ['gstreamer', 'gst_net_dep'])
 243 gstcontroller_dep = dependency('gstreamer-controller-1.0', version : gst_req,
 244   fallback : ['gstreamer', 'gst_controller_dep'])
 245 gstcheck_dep = dependency('gstreamer-check-1.0', version : gst_req,
 246   required : get_option('tests'),
 247   fallback : ['gstreamer', 'gst_check_dep'])
 248 gstpbutils_dep = dependency('gstreamer-pbutils-1.0', version : gst_req,
 249     fallback : ['gst-plugins-base', 'pbutils_dep'])
 250 gstallocators_dep = dependency('gstreamer-allocators-1.0', version : gst_req,
 251     fallback : ['gst-plugins-base', 'allocators_dep'])
 252 gstapp_dep = dependency('gstreamer-app-1.0', version : gst_req,
 253     fallback : ['gst-plugins-base', 'app_dep'])
 254 gstaudio_dep = dependency('gstreamer-audio-1.0', version : gst_req,
 255     fallback : ['gst-plugins-base', 'audio_dep'])
 256 gstfft_dep = dependency('gstreamer-fft-1.0', version : gst_req,
 257     fallback : ['gst-plugins-base', 'fft_dep'])
 258 gstriff_dep = dependency('gstreamer-riff-1.0', version : gst_req,
 259     fallback : ['gst-plugins-base', 'riff_dep'])
 260 gstrtp_dep = dependency('gstreamer-rtp-1.0', version : gst_req,
 261     fallback : ['gst-plugins-base', 'rtp_dep'])
 262 gstrtsp_dep = dependency('gstreamer-rtsp-1.0', version : gst_req,
 263     fallback : ['gst-plugins-base', 'rtsp_dep'])
 264 gstsdp_dep = dependency('gstreamer-sdp-1.0', version : gst_req,
 265     fallback : ['gst-plugins-base', 'sdp_dep'])
 266 gsttag_dep = dependency('gstreamer-tag-1.0', version : gst_req,
 267     fallback : ['gst-plugins-base', 'tag_dep'])
 268 gstvideo_dep = dependency('gstreamer-video-1.0', version : gst_req,
 269     fallback : ['gst-plugins-base', 'video_dep'])
 270
 271 # GStreamer OpenGL
 272 # FIXME: automagic
 273 gstgl_dep = dependency('gstreamer-gl-1.0', version : gst_req,
 274     fallback : ['gst-plugins-base', 'gstgl_dep'], required: false)
 275
 276 have_gstgl = gstgl_dep.found()
 277
 278 if have_gstgl
 279   if gstgl_dep.type_name() == 'pkgconfig'
 280     gst_gl_apis = gstgl_dep.get_pkgconfig_variable('gl_apis').split()
 281     gst_gl_winsys = gstgl_dep.get_pkgconfig_variable('gl_winsys').split()
 282     gst_gl_platforms = gstgl_dep.get_pkgconfig_variable('gl_platforms').split()
 283   else
 284     gstbase = subproject('gst-plugins-base')
 285     gst_gl_apis = gstbase.get_variable('enabled_gl_apis')
 286     gst_gl_winsys = gstbase.get_variable('enabled_gl_winsys')
 287     gst_gl_platforms = gstbase.get_variable('enabled_gl_platforms')
 288   endif
 289
 290   message('GStreamer OpenGL window systems: @0@'.format(' '.join(gst_gl_winsys)))
 291   message('GStreamer OpenGL platforms: @0@'.format(' '.join(gst_gl_platforms)))
 292   message('GStreamer OpenGL apis: @0@'.format(' '.join(gst_gl_apis)))
 293
 294   foreach ws : ['x11', 'wayland', 'android', 'cocoa', 'eagl', 'win32', 'dispmanx', 'viv_fb']
 295     set_variable('gst_gl_have_window_@0@'.format(ws), gst_gl_winsys.contains(ws))
 296   endforeach
 297
 298   foreach p : ['glx', 'egl', 'cgl', 'eagl', 'wgl']
 299     set_variable('gst_gl_have_platform_@0@'.format(p), gst_gl_platforms.contains(p))
 300   endforeach
 301
 302   foreach api : ['gl', 'gles2']
 303     set_variable('gst_gl_have_api_@0@'.format(api), gst_gl_apis.contains(api))
 304   endforeach
 305 endif
 306
 307 zlib_dep = dependency('zlib', required : false)
 308 if not zlib_dep.found()
 309   zlib_dep = cc.find_library('z', required : false)
 310   if not zlib_dep.found() or not cc.has_header('zlib.h')
 311     zlib_dep = subproject('zlib').get_variable('zlib_dep')
 312   endif
 313 endif
 314 cdata.set('HAVE_ZLIB', true)
 315
 316 glib_deps = [dependency('glib-2.0', version : glib_req, fallback: ['glib', 'libglib_dep']),
 317              dependency('gobject-2.0', fallback: ['glib', 'libgobject_dep'])]
 318 gio_dep = dependency('gio-2.0', fallback: ['glib', 'libgio_dep'])
 319
 320 gst_plugins_good_args = ['-DHAVE_CONFIG_H']
 321 configinc = include_directories('.')
 322 libsinc = include_directories('gst-libs')
 323
 324 have_orcc = false
 325 orcc_args = []
 326 # Used by various libraries/elements that use Orc code
 327 orc_dep = dependency('orc-0.4', version : orc_req, required : get_option('orc'),
 328     fallback : ['orc', 'orc_dep'])
 329 orcc = find_program('orcc', required : get_option('orc'))
 330 if orc_dep.found() and orcc.found()
 331   have_orcc = true
 332   orcc_args = [orcc, '--include', 'glib.h']
 333   cdata.set('HAVE_ORC', 1)
 334 else
 335   message('Orc Compiler not found, will use backup C code')
 336   cdata.set('DISABLE_ORC', 1)
 337 endif
 338
 339 # Disable compiler warnings for unused variables and args if gst debug system is disabled
 340 if gst_dep.type_name() == 'internal'
 341   gst_debug_disabled = not subproject('gstreamer').get_variable('gst_debug')
 342 else
 343   # We can't check that in the case of subprojects as we won't
 344   # be able to build against an internal dependency (which is not built yet)
 345   gst_debug_disabled = cc.has_header_symbol('gst/gstconfig.h', 'GST_DISABLE_GST_DEBUG', dependencies: gst_dep)
 346 endif
 347
 348 if gst_debug_disabled
 349   message('GStreamer debug system is disabled')
 350   if cc.has_argument('-Wno-unused')
 351     add_project_arguments('-Wno-unused', language: 'c')
 352   endif
 353   if have_cxx and cxx.has_argument ('-Wno-unused')
 354     add_project_arguments('-Wno-unused', language: 'cpp')
 355   endif
 356 else
 357   message('GStreamer debug system is enabled')
 358 endif
 359
 360 presetdir = join_paths(get_option('datadir'), 'gstreamer-' + api_version, 'presets')
 361
 362 python3 = import('python').find_installation()
 363 pkgconfig = import('pkgconfig')
 364 plugins_pkgconfig_install_dir = join_paths(plugins_install_dir, 'pkgconfig')
 365 if get_option('default_library') == 'shared'
 366   # If we don't build static plugins there is no need to generate pc files
 367   plugins_pkgconfig_install_dir = disabler()
 368 endif
 369
 370 subdir('gst')
 371 subdir('sys')
 372 subdir('ext')
 373 subdir('tests')
 374 subdir('docs')
 375
 376 # xgettext is optional (on Windows for instance)
 377 if find_program('xgettext', required : get_option('nls')).found()
 378   cdata.set('ENABLE_NLS', 1)
 379   subdir('po')
 380 endif
 381
 382 configure_file(output : 'config.h', configuration : cdata)
 383
 384 run_command(python3, '-c', 'import shutil; shutil.copy("hooks/pre-commit.hook", ".git/hooks/pre-commit")')