meson.build

   1 project('gstreamer', 'c',
   2   version : '1.13.0.1',
   3   meson_version : '>= 0.40.1',
   4   default_options : [ 'warning_level=1',
   5                       'buildtype=debugoptimized' ])
   6
   7 gst_version = meson.project_version()
   8 version_arr = gst_version.split('.')
   9 gst_version_major = version_arr[0]
  10 gst_version_minor = version_arr[1]
  11 gst_version_micro = version_arr[2]
  12 if version_arr.length() == 4
  13   gst_version_nano = version_arr[3].to_int()
  14 else
  15   gst_version_nano = 0
  16 endif
  17
  18 host_system = host_machine.system()
  19
  20 apiversion = '1.0'
  21 soversion = 0
  22 # maintaining compatibility with the previous libtool versioning
  23 # current = minor * 100 + micro
  24 libversion = '@0@.@1@.0'.format(soversion, gst_version_minor.to_int() * 100 + gst_version_micro.to_int())
  25
  26 prefix = get_option('prefix')
  27 libtype = get_option('library_format')
  28
  29 libexecdir = get_option('libexecdir')
  30 helpers_install_dir = join_paths(libexecdir, 'gstreamer-1.0')
  31
  32 cc = meson.get_compiler('c')
  33
  34 # Ignore several spurious warnings for things gstreamer does very commonly
  35 # If a warning is completely useless and spammy, use '/wdXXXX' to suppress it
  36 # If a warning is harmless but hard to fix, use '/woXXXX' so it's shown once
  37 # NOTE: Only add warnings here if you are sure they're spurious
  38 if cc.get_id() == 'msvc'
  39   add_project_arguments(
  40       '/wd4018', # implicit signed/unsigned conversion
  41       '/wd4146', # unary minus on unsigned (beware INT_MIN)
  42       '/wd4244', # lossy type conversion (e.g. double -> int)
  43       '/wd4305', # truncating type conversion (e.g. double -> float)
  44       language : 'c')
  45 elif cc.has_argument('-Wl,-Bsymbolic-functions')
  46   # FIXME: Add an option for this if people ask for it
  47   add_project_link_arguments('-Wl,-Bsymbolic-functions', language : 'c')
  48   # FIXME: Add FATAL_WARNINGS from configure.ac
  49 endif
  50
  51 cdata = configuration_data()
  52 cdata.set_quoted('GST_API_VERSION', apiversion)
  53 cdata.set_quoted('GST_DATADIR', join_paths(prefix, get_option('datadir')))
  54 cdata.set_quoted('LOCALEDIR', join_paths(prefix, get_option('localedir')))
  55 cdata.set_quoted('LIBDIR', join_paths(prefix, get_option('libdir')))
  56 cdata.set_quoted('GST_API_VERSION', '1.0')
  57 cdata.set_quoted('GETTEXT_PACKAGE', 'gstreamer-1.0')
  58 cdata.set_quoted('GST_LICENSE', 'LGPL')
  59 cdata.set_quoted('PACKAGE', 'gstreamer')
  60 cdata.set_quoted('PACKAGE_NAME', 'GStreamer')
  61 cdata.set_quoted('PACKAGE_STRING', 'GStreamer @0@'.format(gst_version))
  62 cdata.set_quoted('PACKAGE_TARNAME', 'gstreamer')
  63 cdata.set_quoted('PACKAGE_BUGREPORT', 'http://bugzilla.gnome.org/enter_bug.cgi?product=GStreamer')
  64 cdata.set_quoted('PACKAGE_URL', '')
  65 cdata.set_quoted('PACKAGE_VERSION', gst_version)
  66 cdata.set_quoted('PLUGINDIR', join_paths(get_option('prefix'), get_option('libdir'), 'gstreamer-1.0'))
  67 cdata.set_quoted('VERSION', gst_version)
  68 # FIXME: --with-memory-alignment],[8,N,malloc,pagesize (default is 32)]) option
  69 cdata.set('MEMORY_ALIGNMENT_MALLOC', 1)
  70 cdata.set_quoted('GST_PLUGIN_SCANNER_INSTALLED', join_paths(prefix, helpers_install_dir, 'gst-plugin-scanner'))
  71 cdata.set_quoted('GST_PTP_HELPER_INSTALLED', join_paths(prefix, helpers_install_dir, 'gst-ptp-helper'))
  72 cdata.set_quoted('GST_PLUGIN_SCANNER_SUBDIR', libexecdir,
  73   description: 'libexecdir path component, used to find plugin-scanner on relocatable builds on windows')
  74
  75 if gst_version_nano > 0
  76     # Have GST_ERROR message printed when running from git
  77     cdata.set('GST_LEVEL_DEFAULT', 'GST_LEVEL_ERROR')
  78 else
  79     cdata.set('GST_LEVEL_DEFAULT', 'GST_LEVEL_NONE')
  80 endif
  81
  82 # GStreamer package name and origin url
  83 gst_package_name = get_option('with-package-name')
  84 if gst_package_name == ''
  85   if gst_version_nano == 0
  86     gst_package_name = 'GStreamer source release'
  87   elif gst_version_nano == 1
  88     gst_package_name = 'GStreamer git'
  89   else
  90     gst_package_name = 'GStreamer prerelease'
  91   endif
  92 endif
  93 cdata.set_quoted('GST_PACKAGE_NAME', gst_package_name)
  94 cdata.set_quoted('GST_PACKAGE_ORIGIN', get_option('with-package-origin'))
  95
  96 # These are only needed/used by the ABI tests
  97 host_defines = [
  98   [ 'x86', 'HAVE_CPU_I386' ],
  99   [ 'x86_64', 'HAVE_CPU_X86_64' ],
 100   [ 'arm', 'HAVE_CPU_ARM' ],
 101   [ 'aarch64', 'HAVE_CPU_AARCH64' ],
 102   [ 'mips', 'HAVE_CPU_MIPS' ],
 103   [ 'powerpc', 'HAVE_CPU_PPC' ],
 104   [ 'powerpc64', 'HAVE_CPU_PPC64' ],
 105   [ 'alpha', 'HAVE_CPU_ALPHA' ],
 106   [ 'sparc', 'HAVE_CPU_SPARC' ],
 107   [ 'ia64', 'HAVE_CPU_IA64' ],
 108   [ 'hppa', 'HAVE_CPU_HPPA' ],
 109   [ 'm68k', 'HAVE_CPU_M68K' ],
 110   [ 's390', 'HAVE_CPU_S390' ],
 111 ]
 112 foreach h : host_defines
 113   if h.get(0) == host_machine.cpu()
 114     cdata.set(h.get(1), 1)
 115   endif
 116 endforeach
 117 # FIXME: should really be called HOST_CPU or such
 118 cdata.set_quoted('TARGET_CPU', host_machine.cpu())
 119
 120 check_headers = [
 121   'dlfcn.h',
 122   'inttypes.h',
 123   'memory.h',
 124   'poll.h',
 125   'stdint.h',
 126   'stdio_ext.h',
 127   'strings.h',
 128   'string.h',
 129   'sys/param.h',
 130   'sys/poll.h',
 131   'sys/prctl.h',
 132   'sys/socket.h',
 133   'sys/stat.h',
 134   'sys/times.h',
 135   'sys/time.h',
 136   'sys/types.h',
 137   'sys/utsname.h',
 138   'sys/wait.h',
 139   'ucontext.h',
 140   'unistd.h',
 141   'valgrind/valgrind.h',
 142   'sys/resource.h',
 143 ]
 144
 145 if host_machine.system() == 'windows'
 146   check_headers += ['winsock2.h']
 147 endif
 148
 149 foreach h : check_headers
 150   if cc.has_header(h)
 151     define = 'HAVE_' + h.underscorify().to_upper()
 152     cdata.set(define, 1)
 153   endif
 154 endforeach
 155
 156 if cc.has_member('struct tm', 'tm_gmtoff', prefix : '#include <time.h>')
 157   cdata.set('HAVE_TM_GMTOFF', 1)
 158 endif
 159
 160 check_functions = [
 161   'gmtime_r',
 162   'sigaction',
 163   'getrusage',
 164   'fseeko',
 165   'ftello',
 166   'poll',
 167   'ppoll',
 168   'pselect',
 169   'getpagesize',
 170   'clock_gettime',
 171   # These are needed by libcheck
 172   'getline',
 173   'mkstemp',
 174   'alarm',
 175   'gettimeofday',
 176 ]
 177
 178 foreach f : check_functions
 179   if cc.has_function(f)
 180     define = 'HAVE_' + f.underscorify().to_upper()
 181     cdata.set(define, 1)
 182   endif
 183 endforeach
 184
 185 if cc.has_function('localtime_r', prefix : '#include<time.h>')
 186   cdata.set('HAVE_LOCALTIME_R', 1)
 187   # Needed by libcheck
 188   cdata.set('HAVE_DECL_LOCALTIME_R', 1)
 189 endif
 190
 191 if cc.links('''#include <pthread.h>
 192                int main() {
 193                  pthread_setname_np("example"); return 0;
 194                }''', name : 'pthread_setname_np(const char*)')
 195   cdata.set('HAVE_PTHREAD_SETNAME_NP_WITHOUT_TID', 1)
 196 endif
 197
 198 # Check for posix timers and the monotonic clock
 199 time_prefix = '#include <time.h>\n'
 200 if cdata.has('HAVE_UNISTD_H')
 201   time_prefix += '#include <unistd.h>'
 202 endif
 203
 204 posix_timers_src = time_prefix + '''
 205 #if !defined(_POSIX_TIMERS) || _POSIX_TIMERS < 0 || !defined(CLOCK_REALTIME)
 206 #error Either _POSIX_TIMERS or CLOCK_REALTIME not defined
 207 #endif
 208 '''
 209 if cc.compiles(posix_timers_src, prefix : time_prefix, name : 'posix timers from time.h')
 210   cdata.set('HAVE_POSIX_TIMERS', 1)
 211 endif
 212
 213 monotonic_clock_src = time_prefix + '''
 214 #if !defined(_POSIX_MONOTONIC_CLOCK) || _POSIX_MONOTONIC_CLOCK < 0 || !defined(CLOCK_MONOTONIC)
 215 #error Either _POSIX_MONOTONIC_CLOCK or CLOCK_MONOTONIC not defined
 216 #endif
 217 '''
 218 if cc.compiles(monotonic_clock_src, prefix : time_prefix, name : 'monotonic clock from time.h')
 219   cdata.set('HAVE_MONOTONIC_CLOCK', 1)
 220 endif
 221
 222 # Check for __uint128_t (gcc) by checking for 128-bit division
 223 uint128_t_src = '''int main() {
 224 static __uint128_t v1 = 100;
 225 static __uint128_t v2 = 10;
 226 static __uint128_t u;
 227 u = v1 / v2;
 228 }'''
 229 if cc.compiles(uint128_t_src, name : '__uint128_t available')
 230   cdata.set('HAVE_UINT128_T', 1)
 231 endif
 232
 233 # All supported platforms have long long now
 234 cdata.set('HAVE_LONG_LONG', 1)
 235
 236 # We only want to use the __declspec(dllexport/import) dance in GST_EXPORT when
 237 # building with MSVC
 238 if cc.get_id() == 'msvc'
 239   cdata.set('GSTCONFIG_BUILT_WITH_MSVC', 1)
 240 else
 241   cdata.set('GSTCONFIG_BUILT_WITH_MSVC', 0)
 242 endif
 243
 244 # -------------------------------------------------------------------------------------
 245 # config.h things needed by libcheck
 246 # -------------------------------------------------------------------------------------
 247 if cc.has_function('getpid')
 248   cdata.set('HAVE_GETPID', 1)
 249 elif host_system == 'windows' and cc.has_function('_getpid')
 250   cdata.set('HAVE_PROCESS_H', 1) # Used by gstreamer too
 251   cdata.set('HAVE__GETPID', 1)
 252 endif
 253 if cc.has_function('strdup')
 254   cdata.set('HAVE_DECL_STRDUP', 1)
 255 elif host_system == 'windows' and cc.has_function('_strdup')
 256   cdata.set('HAVE__STRDUP', 1) # Windows (MSVC)
 257 endif
 258 if host_machine.system() != 'windows'
 259   cdata.set('HAVE_FORK', 1)
 260 else
 261   # libcheck requires HAVE_FORK to be 0 when fork() is not available
 262   cdata.set('HAVE_FORK', 0)
 263 endif
 264 if cc.has_function('strsignal')
 265   cdata.set('HAVE_DECL_STRSIGNAL', 1)
 266 endif
 267 # Check for availability of types
 268 if not cc.has_type('clockid_t', prefix : '#include <time.h>')
 269   cdata.set('clockid_t', 'int')
 270 endif
 271 if not cc.has_type('timer_t', prefix : '#include <time.h>')
 272   cdata.set('timer_t', 'int')
 273 endif
 274 if not cc.has_members('struct timespec', 'tv_sec', 'tv_nsec',
 275                       prefix : '#include <time.h>')
 276   cdata.set('STRUCT_TIMESPEC_DEFINITION_MISSING', 1)
 277 endif
 278 if not cc.has_members('struct itimerspec', 'it_interval', 'it_value',
 279                       prefix : '#include <time.h>')
 280   cdata.set('STRUCT_ITIMERSPEC_DEFINITION_MISSING', 1)
 281 endif
 282
 283 # Platform deps; only ws2_32 and execinfo for now
 284 platform_deps = []
 285 if host_machine.system() == 'windows'
 286   platform_deps = [cc.find_library('ws2_32')]
 287 endif
 288
 289 backtrace_deps = []
 290 if not get_option('disable_libunwind')
 291   unwind_dep = dependency('libunwind', required : false)
 292   dw_dep = dependency('libdw', required: false)
 293   backtrace_deps = [unwind_dep, dw_dep]
 294   if unwind_dep.found()
 295     cdata.set('HAVE_UNWIND', 1)
 296     if dw_dep.found()
 297       cdata.set('HAVE_DW', 1)
 298     else
 299       message('Support for backtraces is partial only.')
 300     endif
 301   else
 302     if cc.has_function('backtrace')
 303       cdata.set('HAVE_BACKTRACE', 1)
 304     else
 305         message('NO backtraces support.')
 306     endif
 307   endif
 308 endif
 309
 310 if cc.has_header('execinfo.h')
 311   if cc.has_function('backtrace', prefix : '#include <execinfo.h>')
 312     cdata.set('HAVE_BACKTRACE', 1)
 313   else
 314     execinfo_dep = cc.find_library('execinfo', required : false)
 315     if execinfo_dep.found() and cc.has_function('backtrace', prefix : '#include <execinfo.h>', dependencies : execinfo_dep)
 316       cdata.set('HAVE_BACKTRACE', 1)
 317       platform_deps += execinfo_dep
 318     endif
 319   endif
 320 endif
 321
 322 disable_gst_debug = get_option('disable_gst_debug')
 323 if get_option('disable_gst_debug')
 324     cdata.set('GST_DISABLE_GST_DEBUG_DEFINE', '#define GST_DISABLE_GST_DEBUG 1')
 325   add_project_arguments(['-Wno-unused'], language: 'c')
 326 endif
 327
 328 # Used by the gstutils test
 329 gmp_dep = cc.find_library('gmp', required : false)
 330 cdata.set('HAVE_GMP', gmp_dep.found())
 331 gsl_dep = cc.find_library('gsl', required : false)
 332 gslcblas_dep = cc.find_library('gslcblas', required : false)
 333 cdata.set('HAVE_GSL', gsl_dep.found() and gslcblas_dep.found())
 334 test_deps = [gmp_dep, gsl_dep, gslcblas_dep]
 335
 336 # Used by gstinfo.c
 337 dl_dep = cc.find_library('dl', required : false)
 338 cdata.set('HAVE_DLADDR', cc.has_function('dladdr', dependencies : dl_dep))
 339
 340
 341 configinc = include_directories('.')
 342 libsinc = include_directories('libs')
 343 privinc = include_directories('gst')
 344
 345 # Find dependencies
 346 glib_dep = dependency('glib-2.0', version : '>=2.32.0',
 347   fallback: ['glib', 'libglib_dep'])
 348 gobject_dep = dependency('gobject-2.0',
 349   fallback: ['glib', 'libgobject_dep'])
 350 gmodule_dep = dependency('gmodule-2.0',
 351   fallback: ['glib', 'libgmodule_dep'])
 352 if host_machine.system() == 'windows'
 353     gio_dep = dependency('gio-2.0',
 354         fallback: ['glib', 'libgio_dep'])
 355 else
 356     gio_dep = [dependency('gio-2.0',
 357                   fallback: ['glib', 'libgio_dep']),
 358                dependency('gio-unix-2.0',
 359                   fallback: ['glib', 'libgio_dep'])]
 360 endif
 361
 362 mathlib = cc.find_library('m', required : false)
 363 # Needed for timer_create/settime/delete
 364 # Also provides clock_gettime in glibc < 2.17
 365 rt_lib = cc.find_library('rt', required : false)
 366
 367 gir = find_program('g-ir-scanner', required : false)
 368 gnome = import('gnome')
 369
 370 # Fixme, not very elegant.
 371 build_gir = gir.found() and not meson.is_cross_build() and not get_option('disable_introspection')
 372
 373 gir_init_section = [ '--add-init-section=extern void gst_init(gint*,gchar**);' + \
 374     'g_setenv("GST_REGISTRY_DISABLE", "yes", TRUE);' + \
 375     'g_setenv("GST_REGISTRY_1.0", "/no/way/this/exists.reg", TRUE);' + \
 376     'g_setenv("GST_PLUGIN_PATH_1_0", "", TRUE);' + \
 377     'g_setenv("GST_PLUGIN_SYSTEM_PATH_1_0", "", TRUE);' + \
 378     'gst_init(NULL,NULL);' ]
 379 vs_module_defs_dir = meson.current_source_dir() + '/win32/common/'
 380
 381 # Used by the *_mkenum.py helper scripts
 382 glib_mkenums = find_program('glib-mkenums')
 383
 384 gst_c_args = ['-DHAVE_CONFIG_H']
 385 if libtype == 'static'
 386   gst_c_args += ['-DGST_STATIC_COMPILATION']
 387 endif
 388
 389 # Used in gst/parse/meson.build and below
 390 python3 = import('python3').find_python()
 391
 392 bashcomp_dep = dependency('bash-completion', version : '>= 2.0', required : false)
 393
 394 bashcomp_found = bashcomp_dep.found()
 395 bash_completions_dir = ''
 396 bash_helpers_dir = ''
 397
 398 if bashcomp_found
 399   # get_pkgconfig_variable() won't let us set the prefix
 400   pkgconfig = find_program('pkg-config')
 401
 402   runcmd = run_command(pkgconfig,
 403       '--define-variable=prefix=.',
 404       '--variable=completionsdir',
 405       'bash-completion')
 406
 407   if (runcmd.returncode() == 0)
 408     bash_completions_dir = runcmd.stdout().strip()
 409   else
 410     message('Found bash-completion but the .pc file did not set \'completionsdir\'.')
 411     bashcomp_found = false
 412   endif
 413
 414   runcmd = run_command(pkgconfig,
 415       '--define-variable=prefix=.',
 416       '--variable=helpersdir',
 417       'bash-completion')
 418
 419   if (runcmd.returncode() == 0)
 420     bash_helpers_dir = runcmd.stdout().strip()
 421   else
 422     message('Found bash-completion, but the .pc file did not set \'helpersdir\'.')
 423     bashcomp_found = false
 424   endif
 425 endif
 426
 427 subdir('gst')
 428 subdir('libs')
 429 subdir('plugins')
 430 subdir('tools')
 431 subdir('pkgconfig')
 432 subdir('tests')
 433 subdir('po')
 434 subdir('data')
 435
 436 configure_file(output : 'config.h', configuration : cdata)
 437
 438 if build_machine.system() == 'windows'
 439   message('Disabling gtk-doc while building on Windows')
 440 elif get_option('disable_gtkdoc')
 441   message('gtk-doc is disabled via options')
 442 else
 443   if find_program('gtkdoc-scan', required : false).found()
 444     subdir('docs')
 445   else
 446     message('Not building documentation as gtk-doc was not found')
 447   endif
 448 endif
 449
 450 run_command(python3, '-c', 'import shutil; shutil.copy("hooks/pre-commit.hook", ".git/hooks/pre-commit")')
 451
 452 install_data('gst-element-check-1.0.m4', install_dir : join_paths(get_option('datadir'), 'aclocal'))