meson.build

   1 project('All GStreamer modules', 'c',
   2   version : '1.19.1.1',
   3   meson_version : '>= 0.54.0',
   4   default_options : ['buildtype=debugoptimized'])
   5
   6 gst_version = '>= @0@'.format(meson.project_version())
   7 gst_branch = 'master'
   8
   9 build_system = build_machine.system()
  10 cc = meson.get_compiler('c')
  11
  12 pkgconfig = import('pkgconfig')
  13 python3 = import('python').find_installation()
  14 # Ensure that we're not being run from inside the gst-uninstalled env
  15 # because that will confuse meson, and it might find the already-built
  16 # gstreamer. It's fine if people run `ninja` as long as it doesn't run
  17 # reconfigure because ninja doesn't care about the env.
  18 ensure_not_uninstalled = '''
  19 import os
  20 assert('GST_ENV' not in os.environ)
  21 '''
  22 cmdres = run_command(python3, '-c', ensure_not_uninstalled)
  23 if cmdres.returncode() != 0
  24   error('Do not run `ninja` or `meson` for gst-build inside the uninstalled environment, you will run into problems')
  25 endif
  26
  27 # Ensure that the user does not have Strawberry Perl in PATH, since it ships
  28 # with a pkg-config.bat and broken pkgconfig files for libffi and zlib. Will
  29 # cause a build error, such as in
  30 # https://gitlab.freedesktop.org/gstreamer/gst-build/-/issues/41
  31 ensure_no_strawberry_perl = '''
  32 import os
  33 assert(r'Strawberry\perl\bin' not in os.environ['PATH'])
  34 '''
  35 if build_system == 'windows'
  36   cmdres = run_command(python3, '-c', ensure_no_strawberry_perl)
  37   if cmdres.returncode() != 0
  38     error('You have Strawberry Perl in PATH which is known to cause build issues with gst-build. Please remove it from PATH or uninstall it.')
  39   endif
  40 endif
  41
  42 documented_projects = ''
  43 # Make it possible to use msys2 built zlib which fails
  44 # when not using the mingw toolchain as it uses unistd.h
  45 if not meson.is_subproject() and cc.get_id() == 'msvc'
  46   uname = find_program('uname', required: false)
  47   if uname.found()
  48     ret = run_command(uname, '-o')
  49     if ret.returncode() == 0 and ret.stdout().to_lower() == 'msys'
  50       ret = run_command(uname, '-r')
  51       # The kernel version returned by uname is actually the msys version
  52       if ret.returncode() == 0 and ret.stdout().startswith('2')
  53         # If a system zlib is found, disable UNIX features in zlib.h and zconf.h
  54         if cc.find_library('z').found()
  55           add_global_arguments('-DZ_SOLO', language: 'c')
  56         endif
  57       endif
  58     endif
  59   endif
  60 endif
  61
  62 # Ensure that MSVC interprets all source code as UTF-8. Only do this when we're
  63 # not a subproject, because subprojects are not allowed to call
  64 # add_global_arguments().
  65 if not meson.is_subproject() and cc.get_id() == 'msvc'
  66   add_global_arguments(
  67       cc.get_supported_arguments(['/utf-8']), # set the input encoding to utf-8
  68       language: ['c', 'cpp'])
  69 endif
  70
  71 # Ordered list of subprojects (dict has no ordering guarantees)
  72 subprojects = [
  73   ['gstreamer', {'build-hotdoc': true}],
  74   ['gst-plugins-base', {'option': get_option('base'), 'build-hotdoc': true}],
  75   ['gst-plugins-good', {'option': get_option('good'), 'build-hotdoc': true}],
  76   ['libnice', { 'option': get_option('libnice'), 'match_gst_version': false}],
  77   ['gst-plugins-bad', { 'option': get_option('bad'), 'build-hotdoc': true}],
  78   ['gst-plugins-ugly', { 'option': get_option('ugly'), 'build-hotdoc': true}],
  79   ['gst-libav', { 'option': get_option('libav'), 'build-hotdoc': true}],
  80   ['gst-rtsp-server', { 'option': get_option('rtsp_server'), 'build-hotdoc': true}],
  81   ['gst-devtools', { 'option': get_option('devtools'), 'build-hotdoc': true }],
  82   ['gst-integration-testsuites', { 'option': get_option('devtools') }],
  83   ['gst-editing-services', { 'option': get_option('ges'), 'build-hotdoc': true}],
  84   ['gstreamer-vaapi', { 'option': get_option('vaapi'), 'build-hotdoc': true}],
  85   ['gst-omx', { 'option': get_option('omx'), 'build-hotdoc': true}],
  86   ['gstreamer-sharp', { 'option': get_option('sharp') }],
  87   ['pygobject', { 'option': get_option('python'), 'match_gst_version': false }],
  88   ['gst-python', { 'option': get_option('python')}],
  89   ['gst-examples', { 'option': get_option('gst-examples'), 'match_gst_versions': false}],
  90   ['gst-plugins-rs', { 'option': get_option('rs'), 'match_gst_version': false}],
  91 ]
  92
  93 symlink = '''
  94 import os
  95
  96 os.symlink(os.path.join('@1@', 'subprojects', '@0@'),
  97   os.path.join('@1@', '@0@'))
  98 '''
  99
 100 if build_system == 'windows'
 101   subproject('win-flex-bison-binaries')
 102   subproject('win-nasm')
 103 elif build_system == 'darwin'
 104   subproject('macos-bison-binary')
 105 endif
 106
 107 orc_subproject = subproject('orc', required: get_option('orc'))
 108
 109 subprojects_names = []
 110 plugins_doc_caches = []
 111 orc_update_targets = []
 112 all_plugins = []
 113 foreach sp : subprojects
 114   project_name = sp[0]
 115   build_infos = sp[1]
 116   is_required = build_infos.get('option', true)
 117   match_gst_version = build_infos.get('match_gst_version', true)
 118
 119   if match_gst_version
 120     subproj = subproject(project_name, version: gst_version, required: is_required)
 121   else
 122     subproj = subproject(project_name, required: is_required)
 123   endif
 124
 125   if subproj.found()
 126     plugins = subproj.get_variable('plugins', [])
 127     all_plugins += plugins
 128
 129     orc_update_targets += subproj.get_variable('orc_update_targets', [])
 130
 131     subprojects_names += [project_name]
 132     cmdres = run_command(python3, '-c', symlink.format(project_name, meson.current_source_dir()))
 133     if cmdres.returncode() == 0
 134       message('Created symlink to ' + project_name)
 135     endif
 136
 137     if not meson.is_cross_build() and build_infos.get('build-hotdoc', false)
 138       if plugins.length() > 0
 139         plugins_doc_caches += [subproj.get_variable('plugins_doc_dep')]
 140       endif
 141       if documented_projects != ''
 142         documented_projects += ','
 143       endif
 144       documented_projects  += project_name
 145     endif
 146   endif
 147 endforeach
 148
 149 # Check if we need to also build glib-networking for TLS modules
 150 glib_dep = dependency('glib-2.0')
 151 if glib_dep.type_name() == 'internal'
 152   subproject('glib-networking', required : get_option('tls'),
 153              default_options: ['gnutls=auto', 'openssl=auto'])
 154 endif
 155
 156 plugins_doc_dep = custom_target('plugins-doc-cache',
 157   command: [python3, '-c', 'print("Built all doc caches")'],
 158   input: plugins_doc_caches,
 159   output: 'plugins_doc_caches',
 160   capture: true,
 161 )
 162
 163 if meson.is_cross_build() or build_machine.system() == 'windows'
 164     if get_option('doc').enabled()
 165         error('Documentation enabled but building the doc while cross building or building on windows is not supported yet.')
 166     endif
 167
 168     documented_projects = ''
 169     message('Documentation not built as building the documentation while cross building or building on windows is not supported yet.')
 170 else
 171   hotdoc_p = find_program('hotdoc', required : get_option('doc'))
 172   if not hotdoc_p.found()
 173     documented_projects = ''
 174     message('Not building documentation as hotdoc was not found')
 175   endif
 176 endif
 177
 178 write_file_contents = '''
 179 import os
 180 import sys
 181
 182 assert len(sys.argv) >= 3
 183 fname = sys.argv[1]
 184 contents = sys.argv[2]
 185
 186 with open(fname, 'w') as f:
 187     f.write(contents)
 188 '''
 189
 190 configure_file(
 191   output : 'GstDocumentedSubprojects',
 192   command : [python3,
 193              '-c', write_file_contents,
 194              '@OUTPUT@',
 195              documented_projects]
 196 )
 197
 198 if documented_projects != ''
 199   subproject('gst-docs', required: get_option('doc').enabled())
 200   message('Gst docs subprojects: ' + documented_projects)
 201 endif
 202
 203 all_plugins_paths = []
 204 foreach plugin: all_plugins
 205   all_plugins_paths += plugin.full_path()
 206 endforeach
 207 # Work around meson bug: https://github.com/mesonbuild/meson/pull/6770
 208 pathsep = host_machine.system() == 'windows' ? ';' : ':'
 209 all_plugins_paths = pathsep.join(all_plugins_paths)
 210
 211 generate_plugins_paths = find_program('scripts/generate_plugins_path.py')
 212 configure_file(
 213   output : 'GstPluginsPath.json',
 214   command : [generate_plugins_paths,
 215              '@OUTPUT@',
 216              all_plugins_paths]
 217 )
 218
 219 # FIXME: Create a 'libraries' list in each subproject like we do for 'plugins'
 220 libraries_map = {
 221   # name: [subproject_name, variable_name]
 222   'gstreamer': ['gstreamer', 'libgst'],
 223   'base': ['gstreamer', 'gst_base'],
 224   'check': ['gstreamer', 'gst_check'],
 225   'controller': ['gstreamer', 'gst_controller'],
 226   'net': ['gstreamer', 'gst_net'],
 227
 228   'allocators': ['gst-plugins-base', 'gstallocators'],
 229   'app': ['gst-plugins-base', 'gstapp'],
 230   'audio': ['gst-plugins-base', 'gstaudio'],
 231   'fft': ['gst-plugins-base', 'gstfft'],
 232   'pbutils': ['gst-plugins-base', 'pbutils'],
 233   'riff': ['gst-plugins-base', 'gstriff'],
 234   'rtp': ['gst-plugins-base', 'gst_rtp'],
 235   'rtsp': ['gst-plugins-base', 'gst_rtsp'],
 236   'sdp': ['gst-plugins-base', 'gstsdp'],
 237   'tag': ['gst-plugins-base', 'gsttag'],
 238   'video': ['gst-plugins-base', 'gstvideo'],
 239   'gl': ['gst-plugins-base', 'gstgl'],
 240
 241   'bad-audio': ['gst-plugins-bad', 'gstbadaudio'],
 242   'bad-transcoder': ['gst-plugins-bad', 'gst_transcoder'],
 243   'codecparsers': ['gst-plugins-bad', 'gstcodecparsers'],
 244   'insertbin': ['gst-plugins-bad', 'gstinsertbin'],
 245   'mpegts': ['gst-plugins-bad', 'gstmpegts'],
 246   'player': ['gst-plugins-bad', 'gstplayer'],
 247   'sctp': ['gst-plugins-bad', 'libgstsctp'],
 248   'webrtc': ['gst-plugins-bad', 'gstwebrtc'],
 249   'vulkan': ['gst-plugins-bad', 'gstvulkan'],
 250
 251   'rtsp-server': ['gst-rtsp-server', 'gst_rtsp_server'],
 252 }
 253
 254 if get_option('default_library') == 'static'
 255   if not get_option('introspection').disabled()
 256     error('GObject Introspection is not supported in static builds. Please use -Dintrospection=disabled')
 257   endif
 258   # Generate a .c file which declare and register all built plugins
 259   plugins_names = []
 260   foreach plugin: all_plugins
 261     plugins_names += plugin.full_path()
 262   endforeach
 263   all_plugin_names = ';'.join(plugins_names)
 264
 265   static_plugins = get_option('gst-full-plugins')
 266   if static_plugins == '*'
 267     static_plugins = all_plugin_names
 268   endif
 269   generate_init_static_plugins = find_program('scripts/generate_init_static_plugins.py')
 270   init_static_plugins_c = configure_file(
 271     output: 'gstinitstaticplugins.c',
 272     command : [generate_init_static_plugins,
 273                '-o ' + '@OUTPUT@',
 274                '-p ' + static_plugins,
 275                '-e ' + get_option('gst-full-elements'),
 276                '-t ' + get_option('gst-full-typefind-functions'),
 277                '-d ' + get_option('gst-full-device-providers'),
 278                '-T ' + get_option('gst-full-dynamic-types')
 279                ]
 280   )
 281
 282   gstfull_link_args = cc.get_supported_link_arguments(['-Wl,-Bsymbolic-functions'])
 283
 284   # Get a list of libraries that needs to be exposed in the ABI.
 285   exposed_libs = []
 286   incdir_deps = []
 287   foreach name : get_option('gst-full-libraries') + ['gstreamer']
 288     info = libraries_map[name]
 289     exposed_libs += subproject(info[0]).get_variable(info[1])
 290     depname = name == 'gstreamer' ? 'gstreamer-1.0' : 'gstreamer-@0@-1.0'.format(name)
 291     incdir_deps += dependency(depname).partial_dependency(includes: true, sources: true)
 292   endforeach
 293
 294   # glib and gobject are part of our public API. If we are using glib from the
 295   # system then our pkg-config file must require it. If we built it as
 296   # subproject then we need to link_whole it.
 297   glib_deps = []
 298   glib_dep = dependency('glib-2.0')
 299   gobject_dep = dependency('gobject-2.0')
 300   if gobject_dep.type_name() == 'internal'
 301     glib_subproject = subproject('glib')
 302     exposed_libs += glib_subproject.get_variable('libglib')
 303     exposed_libs += glib_subproject.get_variable('libgobject')
 304     incdir_deps += [
 305       glib_dep.partial_dependency(includes: true),
 306       gobject_dep.partial_dependency(includes: true),
 307     ]
 308   else
 309     glib_deps = [glib_dep, gobject_dep]
 310   endif
 311
 312   link_deps = []
 313   if get_option('gst-full-version-script') != ''
 314     symbol_map = meson.current_source_dir() / get_option('gst-full-version-script')
 315     link_arg = '-Wl,--version-script=' + symbol_map
 316     if cc.has_link_argument(link_arg)
 317       gstfull_link_args += link_arg
 318       link_deps += symbol_map
 319     elif cc.get_id() == 'msvc'
 320       warning('FIXME: Provide a def file to publish the public symbols')
 321     else
 322       error('Failed to link with version script (' + symbol_map + '), check logs for details')
 323     endif
 324   endif
 325
 326   # Build both shared and static library
 327   gstfull = both_libraries('gstreamer-full-1.0',
 328     init_static_plugins_c,
 329     link_with : all_plugins,
 330     link_args: gstfull_link_args,
 331     link_whole : exposed_libs,
 332     dependencies : incdir_deps + glib_deps,
 333     link_depends : link_deps,
 334     install : true,
 335   )
 336
 337   gst_full_dep = declare_dependency(link_with: gstfull.get_shared_lib(),
 338     dependencies : incdir_deps + glib_deps,
 339     include_directories: include_directories('.')
 340   )
 341   gst_full_libs_private = cc.get_supported_link_arguments(['-Wl,--undefined=gst_init_static_plugins'])
 342   if gst_full_libs_private == []
 343     warning('The compiler does not support `-Wl,--undefined` linker flag. The method `gst_init_static_plugins` might be dropped during the link stage of an application using libgstreamer-full-1.0.a, preventing plugins registration.')
 344   endif
 345   pkgconfig.generate(gstfull,
 346     requires: glib_deps,
 347     libraries_private: gst_full_libs_private,
 348     subdirs : 'gstreamer-1.0')
 349   meson.override_dependency('gstreamer-full-1.0', gst_full_dep)
 350 endif
 351
 352 foreach custom_subproj: get_option('custom_subprojects').split(',')
 353     if custom_subproj != ''
 354         message ('Adding custom subproject ' + custom_subproj)
 355         subproject(custom_subproj)
 356         subprojects_names += [custom_subproj]
 357     endif
 358 endforeach
 359
 360 message('Building subprojects: ' + ', '.join(subprojects_names))
 361
 362 subdir('tests')
 363
 364 setenv = find_program('gst-env.py')
 365
 366 devenv_cmd = [setenv, '--builddir=@0@'.format(meson.build_root()),
 367               '--gstbuilddir=@0@'.format(meson.current_build_dir()),
 368               '--srcdir=@0@'.format(meson.source_root())]
 369
 370 if meson.has_exe_wrapper() and build_machine.system() == 'linux' and host_machine.system() == 'windows'
 371   # FIXME: Ideally we could get the wrapper directly from meson
 372   devenv_cmd += ['--wine', host_machine.cpu_family() == 'x86_64' ? 'wine64' : 'wine32']
 373   sysroot = meson.get_cross_property('sys_root')
 374   if sysroot != ''
 375     # Logic from meson
 376     devenv_cmd += ['--winepath', 'Z:' + join_paths(sysroot, 'bin')]
 377   endif
 378 endif
 379
 380 run_target('uninstalled', command : devenv_cmd)
 381 run_target('devenv', command : devenv_cmd)
 382
 383 update = find_program('git-update')
 384 run_target('git-update', command : [update])
 385 run_target('update', command : [update,
 386     '--builddir=@0@'.format(meson.current_build_dir())])
 387
 388 if orc_subproject.found() and orc_update_targets.length() > 0
 389   alias_target('update-orc-dist', orc_update_targets)
 390 endif