meson.build

   1 project('gst-editing-services', 'c',
   2   version : '1.11.0.1',
   3   meson_version : '>= 0.35.0',
   4   default_options : [ 'warning_level=1',
   5                       'buildtype=debugoptimized' ])
   6
   7 gst_version = meson.project_version()
   8 version_arr = gst_version.split('.')
   9 gst_version_major = version_arr[0]
  10 gst_version_minor = version_arr[1]
  11 gst_version_micro = version_arr[2]
  12 if version_arr.length() == 4
  13   gst_version_nano = version_arr[3]
  14 else
  15   gst_version_nano = 0
  16 endif
  17
  18 apiversion = '1.0'
  19 soversion = 0
  20 # maintaining compatibility with the previous libtool versioning
  21 # current = minor * 100 + micro
  22 libversion = '@0@.@1@.0'.format(soversion, gst_version_minor.to_int() * 100 + gst_version_micro.to_int())
  23
  24 glib_req = '>= 2.40.0'
  25 gst_req = '>= @0@.@1@.0'.format(gst_version_major, gst_version_minor)
  26
  27 cc = meson.get_compiler('c')
  28 # Ignore several spurious warnings for things gstreamer does very commonly
  29 # If a warning is completely useless and spammy, use '/wdXXXX' to suppress it
  30 # If a warning is harmless but hard to fix, use '/woXXXX' so it's shown once
  31 # NOTE: Only add warnings here if you are sure they're spurious
  32 if cc.get_id() == 'msvc'
  33   add_global_arguments('/wd4018', '/wd4244', '/wd4996', language : 'c')
  34 endif
  35
  36 cdata = configuration_data()
  37 cdata.set('VERSION', '"@0@"'.format(gst_version))
  38 cdata.set('PACKAGE', '"gst-editing-services"')
  39 cdata.set('PACKAGE_VERSION', '"@0@"'.format(gst_version))
  40 cdata.set('PACKAGE_BUGREPORT', '"http://bugzilla.gnome.org/enter_bug.cgi?product=GStreamer"')
  41 cdata.set('PACKAGE_NAME', '"GStreamer Editing Services"')
  42 cdata.set('GST_PACKAGE_NAME', '"GStreamer Editing Services"')
  43 cdata.set('GST_PACKAGE_ORIGIN', '"Unknown package origin"')
  44 cdata.set('GST_LICENSE', '"LGPL"')
  45 cdata.set('LIBDIR', '"@0@"'.format(get_option('libdir')))
  46
  47 # Mandatory GST deps
  48 gst_dep = dependency('gstreamer-' + apiversion, version : gst_req,
  49     fallback : ['gstreamer', 'gst_dep'])
  50 gstpbutils_dep = dependency('gstreamer-pbutils-' + apiversion, version : gst_req,
  51     fallback : ['gst-plugins-base', 'pbutils_dep'])
  52 gstvideo_dep = dependency('gstreamer-video-' + apiversion, version : gst_req,
  53     fallback : ['gst-plugins-base', 'video_dep'])
  54 gstbase_dep = dependency('gstreamer-base-1.0', version : gst_req,
  55     fallback : ['gstreamer', 'gst_base_dep'])
  56 if host_machine.system() != 'windows'
  57   gstcheck_dep = dependency('gstreamer-check-1.0', version : gst_req,
  58     fallback : ['gstreamer', 'gst_check_dep'], required: false)
  59 endif
  60 gstcontroller_dep = dependency('gstreamer-controller-1.0', version : gst_req,
  61   fallback : ['gstreamer', 'gst_controller_dep'])
  62 gstvalidate_dep = dependency('gst-validate-1.0', version : gst_req, required : false,
  63   fallback : ['gst-devtools', 'validate_dep'])
  64
  65 gio_dep = dependency('gio-2.0', version : glib_req)
  66 libxml_dep = dependency('libxml-2.0')
  67
  68 # TODO Properly port to Gtk 3
  69 # gtk_dep = dependency('gtk+-3.0', required : false)
  70
  71 libges_deps = [gst_dep, gstbase_dep, gstvideo_dep, gstpbutils_dep,
  72                gstcontroller_dep, gio_dep, libxml_dep]
  73
  74 if gstvalidate_dep.found()
  75     libges_deps = libges_deps + [gstvalidate_dep]
  76     cdata.set('HAVE_GST_VALIDATE', 1)
  77 endif
  78
  79 configure_file(input : 'config.h.meson',
  80   output : 'config.h',
  81   configuration : cdata)
  82
  83
  84 gir = find_program('g-ir-scanner', required : false)
  85 gnome = import('gnome')
  86 gtkdoc = find_program('gtkdoc-scan', required : false)
  87
  88 # Fixme, not very elegant.
  89 build_gir = gir.found() and not meson.is_cross_build() and not get_option('disable_introspection')
  90 gir_init_section = [ '--add-init-section=' + \
  91     'extern void gst_init(gint*,gchar**);' + \
  92     'extern void ges_init(void);' + \
  93     'g_setenv("GST_REGISTRY_1.0", "/no/way/this/exists.reg", TRUE);' + \
  94     'g_setenv("GST_PLUGIN_PATH_1_0", "", TRUE);' + \
  95     'g_setenv("GST_PLUGIN_SYSTEM_PATH_1_0", "", TRUE);' + \
  96     'gst_init(NULL,NULL);' + \
  97     'ges_init();' ]
  98
  99 ges_c_args = ['-DHAVE_CONFIG_H']
 100 plugins_install_dir = '@0@/gstreamer-1.0'.format(get_option('libdir'))
 101
 102 configinc = include_directories('.')
 103 subdir('ges')
 104 subdir('plugins')
 105 subdir('tools')
 106 subdir('pkgconfig')
 107 subdir('tests')
 108 subdir('examples')
 109
 110 if build_machine.system() != 'windows'
 111   if gtkdoc.found()
 112     subdir('docs')
 113   else
 114     message('Not building documentation as gtk-doc was not found')
 115   endif
 116 else
 117   message('Disabling gtk-doc while building on Windows')
 118 endif
 119
 120 python3 = find_program('python3')
 121 run_command(python3, '-c', 'import shutil; shutil.copy("hooks/pre-commit.hook", ".git/hooks/pre-commit")')