meson.build

   1 project('gstreamer', 'c',
   2   version : '1.15.0.1',
   3   meson_version : '>= 0.47',
   4   default_options : [ 'warning_level=1',
   5                       'buildtype=debugoptimized' ])
   6
   7 gst_version = meson.project_version()
   8 version_arr = gst_version.split('.')
   9 gst_version_major = version_arr[0].to_int()
  10 gst_version_minor = version_arr[1].to_int()
  11 gst_version_micro = version_arr[2].to_int()
  12 if version_arr.length() == 4
  13   gst_version_nano = version_arr[3].to_int()
  14 else
  15   gst_version_nano = 0
  16 endif
  17 gst_version_is_dev = gst_version_minor % 2 == 1 and gst_version_micro < 90
  18
  19 host_system = host_machine.system()
  20
  21 apiversion = '1.0'
  22 soversion = 0
  23 # maintaining compatibility with the previous libtool versioning
  24 # current = minor * 100 + micro
  25 curversion = gst_version_minor * 100 + gst_version_micro
  26 libversion = '@0@.@1@.0'.format(soversion, curversion)
  27 osxversion = curversion + 1
  28
  29 prefix = get_option('prefix')
  30
  31 libexecdir = get_option('libexecdir')
  32 helpers_install_dir = join_paths(libexecdir, 'gstreamer-1.0')
  33
  34 cc = meson.get_compiler('c')
  35
  36 # Ignore several spurious warnings for things gstreamer does very commonly
  37 # If a warning is completely useless and spammy, use '/wdXXXX' to suppress it
  38 # If a warning is harmless but hard to fix, use '/woXXXX' so it's shown once
  39 # NOTE: Only add warnings here if you are sure they're spurious
  40 if cc.get_id() == 'msvc'
  41   add_project_arguments(
  42       '/wd4018', # implicit signed/unsigned conversion
  43       '/wd4146', # unary minus on unsigned (beware INT_MIN)
  44       '/wd4244', # lossy type conversion (e.g. double -> int)
  45       '/wd4305', # truncating type conversion (e.g. double -> float)
  46       language : 'c')
  47 elif cc.has_link_argument('-Wl,-Bsymbolic-functions')
  48   # FIXME: Add an option for this if people ask for it
  49   add_project_link_arguments('-Wl,-Bsymbolic-functions', language : 'c')
  50 endif
  51
  52 # Symbol visibility
  53 have_visibility_hidden = cc.has_argument('-fvisibility=hidden')
  54 if have_visibility_hidden
  55   add_project_arguments('-fvisibility=hidden', language: 'c')
  56 endif
  57
  58 # Disable strict aliasing
  59 if cc.has_argument('-fno-strict-aliasing')
  60   add_project_arguments('-fno-strict-aliasing', language: 'c')
  61 endif
  62
  63 # Define G_DISABLE_DEPRECATED for development versions
  64 if gst_version_is_dev
  65   message('Disabling deprecated GLib API')
  66   add_project_arguments('-DG_DISABLE_DEPRECATED', language: 'c')
  67 endif
  68
  69 cast_checks = get_option('gobject-cast-checks')
  70 if cast_checks.disabled() or (cast_checks.auto() and not gst_version_is_dev)
  71   message('Disabling GLib cast checks')
  72   add_project_arguments('-DG_DISABLE_CAST_CHECKS', language: 'c')
  73 endif
  74
  75 glib_asserts = get_option('glib-asserts')
  76 if glib_asserts.disabled() or (glib_asserts.auto() and not gst_version_is_dev)
  77   message('Disabling GLib asserts')
  78   add_project_arguments('-DG_DISABLE_ASSERT', language: 'c')
  79 endif
  80
  81 cdata = configuration_data()
  82 cdata.set_quoted('GST_API_VERSION', apiversion)
  83 cdata.set_quoted('GST_DATADIR', join_paths(prefix, get_option('datadir')))
  84 cdata.set_quoted('LOCALEDIR', join_paths(prefix, get_option('localedir')))
  85 cdata.set_quoted('LIBDIR', join_paths(prefix, get_option('libdir')))
  86 cdata.set_quoted('GST_API_VERSION', '1.0')
  87 cdata.set_quoted('GETTEXT_PACKAGE', 'gstreamer-1.0')
  88 cdata.set_quoted('GST_LICENSE', 'LGPL')
  89 cdata.set_quoted('PACKAGE', 'gstreamer')
  90 cdata.set_quoted('PACKAGE_NAME', 'GStreamer')
  91 cdata.set_quoted('PACKAGE_STRING', 'GStreamer @0@'.format(gst_version))
  92 cdata.set_quoted('PACKAGE_TARNAME', 'gstreamer')
  93 cdata.set_quoted('PACKAGE_BUGREPORT', 'http://bugzilla.gnome.org/enter_bug.cgi?product=GStreamer')
  94 cdata.set_quoted('PACKAGE_URL', '')
  95 cdata.set_quoted('PACKAGE_VERSION', gst_version)
  96 cdata.set_quoted('PLUGINDIR', join_paths(get_option('prefix'), get_option('libdir'), 'gstreamer-1.0'))
  97 cdata.set_quoted('VERSION', gst_version)
  98 cdata.set_quoted('GST_PLUGIN_SCANNER_INSTALLED', join_paths(prefix, helpers_install_dir, 'gst-plugin-scanner'))
  99 cdata.set_quoted('GST_PTP_HELPER_INSTALLED', join_paths(prefix, helpers_install_dir, 'gst-ptp-helper'))
 100 cdata.set_quoted('GST_PLUGIN_SCANNER_SUBDIR', libexecdir,
 101   description: 'libexecdir path component, used to find plugin-scanner on relocatable builds on windows')
 102 cdata.set('GST_DISABLE_OPTION_PARSING', not get_option('option-parsing'))
 103
 104 mem_align_opt = get_option('memory-alignment')
 105 if mem_align_opt == 'malloc'
 106   cdata.set('MEMORY_ALIGNMENT_MALLOC', 1)
 107 elif mem_align_opt == 'pagesize'
 108   cdata.set('MEMORY_ALIGNMENT_PAGESIZE', 1)
 109 else
 110   cdata.set('MEMORY_ALIGNMENT', mem_align_opt.to_int())
 111 endif
 112
 113 if ['darwin', 'ios'].contains(host_system)
 114   cdata.set_quoted('GST_EXTRA_MODULE_SUFFIX', '.dylib')
 115 endif
 116
 117 if gst_version_nano > 0
 118     # Have GST_ERROR message printed when running from git
 119     cdata.set('GST_LEVEL_DEFAULT', 'GST_LEVEL_ERROR')
 120 else
 121     cdata.set('GST_LEVEL_DEFAULT', 'GST_LEVEL_NONE')
 122 endif
 123
 124 # GStreamer package name and origin url
 125 gst_package_name = get_option('package-name')
 126 if gst_package_name == ''
 127   if gst_version_nano == 0
 128     gst_package_name = 'GStreamer source release'
 129   elif gst_version_nano == 1
 130     gst_package_name = 'GStreamer git'
 131   else
 132     gst_package_name = 'GStreamer prerelease'
 133   endif
 134 endif
 135 cdata.set_quoted('GST_PACKAGE_NAME', gst_package_name)
 136 cdata.set_quoted('GST_PACKAGE_ORIGIN', get_option('package-origin'))
 137
 138 # These are only needed/used by the ABI tests
 139 host_defines = [
 140   [ 'x86', 'HAVE_CPU_I386' ],
 141   [ 'x86_64', 'HAVE_CPU_X86_64' ],
 142   [ 'arm', 'HAVE_CPU_ARM' ],
 143   [ 'aarch64', 'HAVE_CPU_AARCH64' ],
 144   [ 'mips', 'HAVE_CPU_MIPS' ],
 145   [ 'powerpc', 'HAVE_CPU_PPC' ],
 146   [ 'powerpc64', 'HAVE_CPU_PPC64' ],
 147   [ 'alpha', 'HAVE_CPU_ALPHA' ],
 148   [ 'sparc', 'HAVE_CPU_SPARC' ],
 149   [ 'ia64', 'HAVE_CPU_IA64' ],
 150   [ 'hppa', 'HAVE_CPU_HPPA' ],
 151   [ 'm68k', 'HAVE_CPU_M68K' ],
 152   [ 's390', 'HAVE_CPU_S390' ],
 153 ]
 154 foreach h : host_defines
 155   if h.get(0) == host_machine.cpu()
 156     cdata.set(h.get(1), 1)
 157   endif
 158 endforeach
 159 # FIXME: should really be called HOST_CPU or such
 160 cdata.set_quoted('TARGET_CPU', host_machine.cpu())
 161
 162 check_headers = [
 163   'dlfcn.h',
 164   'inttypes.h',
 165   'memory.h',
 166   'poll.h',
 167   'stdint.h',
 168   'stdio_ext.h',
 169   'strings.h',
 170   'string.h',
 171   'sys/param.h',
 172   'sys/poll.h',
 173   'sys/prctl.h',
 174   'sys/socket.h',
 175   'sys/stat.h',
 176   'sys/times.h',
 177   'sys/time.h',
 178   'sys/types.h',
 179   'sys/utsname.h',
 180   'sys/wait.h',
 181   'ucontext.h',
 182   'unistd.h',
 183   'valgrind/valgrind.h',
 184   'sys/resource.h',
 185 ]
 186
 187 if host_system == 'windows'
 188   check_headers += ['winsock2.h']
 189 endif
 190
 191 foreach h : check_headers
 192   if cc.has_header(h)
 193     define = 'HAVE_' + h.underscorify().to_upper()
 194     cdata.set(define, 1)
 195   endif
 196 endforeach
 197
 198 if cc.has_member('struct tm', 'tm_gmtoff', prefix : '#include <time.h>')
 199   cdata.set('HAVE_TM_GMTOFF', 1)
 200 endif
 201
 202 check_functions = [
 203   'gmtime_r',
 204   'sigaction',
 205   'getrusage',
 206   'fseeko',
 207   'ftello',
 208   'poll',
 209   'ppoll',
 210   'pselect',
 211   'getpagesize',
 212   'clock_gettime',
 213   # These are needed by libcheck
 214   'getline',
 215   'mkstemp',
 216   'alarm',
 217   'gettimeofday',
 218 ]
 219
 220 foreach f : check_functions
 221   if cc.has_function(f)
 222     define = 'HAVE_' + f.underscorify().to_upper()
 223     cdata.set(define, 1)
 224   endif
 225 endforeach
 226
 227 if cc.has_function('localtime_r', prefix : '#include<time.h>')
 228   cdata.set('HAVE_LOCALTIME_R', 1)
 229   # Needed by libcheck
 230   cdata.set('HAVE_DECL_LOCALTIME_R', 1)
 231 endif
 232
 233 if cc.links('''#include <pthread.h>
 234                int main() {
 235                  pthread_setname_np("example"); return 0;
 236                }''', name : 'pthread_setname_np(const char*)')
 237   cdata.set('HAVE_PTHREAD_SETNAME_NP_WITHOUT_TID', 1)
 238 endif
 239
 240 # Check for posix timers and the monotonic clock
 241 time_prefix = '#include <time.h>\n'
 242 if cdata.has('HAVE_UNISTD_H')
 243   time_prefix += '#include <unistd.h>'
 244 endif
 245
 246 posix_timers_src = time_prefix + '''
 247 #if !defined(_POSIX_TIMERS) || _POSIX_TIMERS < 0 || !defined(CLOCK_REALTIME)
 248 #error Either _POSIX_TIMERS or CLOCK_REALTIME not defined
 249 #endif
 250 '''
 251 if cc.compiles(posix_timers_src, name : 'posix timers from time.h')
 252   cdata.set('HAVE_POSIX_TIMERS', 1)
 253 endif
 254
 255 monotonic_clock_src = time_prefix + '''
 256 #if !defined(_POSIX_MONOTONIC_CLOCK) || _POSIX_MONOTONIC_CLOCK < 0 || !defined(CLOCK_MONOTONIC)
 257 #error Either _POSIX_MONOTONIC_CLOCK or CLOCK_MONOTONIC not defined
 258 #endif
 259 '''
 260 if cc.compiles(monotonic_clock_src, name : 'monotonic clock from time.h')
 261   cdata.set('HAVE_MONOTONIC_CLOCK', 1)
 262 endif
 263
 264 # Check for __uint128_t (gcc) by checking for 128-bit division
 265 uint128_t_src = '''int main() {
 266 static __uint128_t v1 = 100;
 267 static __uint128_t v2 = 10;
 268 static __uint128_t u;
 269 u = v1 / v2;
 270 }'''
 271 if cc.compiles(uint128_t_src, name : '__uint128_t available')
 272   cdata.set('HAVE_UINT128_T', 1)
 273 endif
 274
 275 # All supported platforms have long long now
 276 cdata.set('HAVE_LONG_LONG', 1)
 277
 278 # We only want to use the __declspec(dllexport/import) dance in GST_EXPORT when
 279 # building with MSVC
 280 if cc.get_id() == 'msvc'
 281   cdata.set('GSTCONFIG_BUILT_WITH_MSVC', 1)
 282 else
 283   cdata.set('GSTCONFIG_BUILT_WITH_MSVC', 0)
 284 endif
 285
 286 # -------------------------------------------------------------------------------------
 287 # config.h things needed by libcheck
 288 # -------------------------------------------------------------------------------------
 289 if cc.has_function('getpid')
 290   cdata.set('HAVE_GETPID', 1)
 291 elif host_system == 'windows' and cc.has_function('_getpid')
 292   cdata.set('HAVE_PROCESS_H', 1) # Used by gstreamer too
 293   cdata.set('HAVE__GETPID', 1)
 294 endif
 295 if cc.has_function('strdup')
 296   cdata.set('HAVE_DECL_STRDUP', 1)
 297 elif host_system == 'windows' and cc.has_function('_strdup')
 298   cdata.set('HAVE__STRDUP', 1) # Windows (MSVC)
 299 endif
 300 if host_system != 'windows'
 301   cdata.set('HAVE_FORK', 1)
 302 else
 303   # libcheck requires HAVE_FORK to be 0 when fork() is not available
 304   cdata.set('HAVE_FORK', 0)
 305 endif
 306 if cc.has_function('strsignal')
 307   cdata.set('HAVE_DECL_STRSIGNAL', 1)
 308 endif
 309 # Check for availability of types
 310 if not cc.has_type('clockid_t', prefix : '#include <time.h>')
 311   cdata.set('clockid_t', 'int')
 312 endif
 313 if not cc.has_type('timer_t', prefix : '#include <time.h>')
 314   cdata.set('timer_t', 'int')
 315 endif
 316 if not cc.has_members('struct timespec', 'tv_sec', 'tv_nsec',
 317                       prefix : '#include <time.h>')
 318   cdata.set('STRUCT_TIMESPEC_DEFINITION_MISSING', 1)
 319 endif
 320 if not cc.has_members('struct itimerspec', 'it_interval', 'it_value',
 321                       prefix : '#include <time.h>')
 322   cdata.set('STRUCT_ITIMERSPEC_DEFINITION_MISSING', 1)
 323 endif
 324
 325 # Platform deps; only ws2_32 and execinfo for now
 326 platform_deps = []
 327 if host_system == 'windows'
 328   platform_deps = [cc.find_library('ws2_32')]
 329 endif
 330
 331 backtrace_deps = []
 332 unwind_dep = dependency('libunwind', required : get_option('libunwind'))
 333 dw_dep = dependency('libdw', required: get_option('libunwind'))
 334 backtrace_deps = [unwind_dep, dw_dep]
 335 if unwind_dep.found()
 336   cdata.set('HAVE_UNWIND', 1)
 337   if dw_dep.found()
 338     cdata.set('HAVE_DW', 1)
 339   else
 340     message('Support for backtraces is partial only.')
 341   endif
 342 else
 343   if cc.has_function('backtrace')
 344     cdata.set('HAVE_BACKTRACE', 1)
 345   else
 346       message('NO backtraces support.')
 347   endif
 348 endif
 349
 350 if cc.has_header('execinfo.h')
 351   if cc.has_function('backtrace', prefix : '#include <execinfo.h>')
 352     cdata.set('HAVE_BACKTRACE', 1)
 353   else
 354     execinfo_dep = cc.find_library('execinfo', required : false)
 355     if execinfo_dep.found() and cc.has_function('backtrace', prefix : '#include <execinfo.h>', dependencies : execinfo_dep)
 356       cdata.set('HAVE_BACKTRACE', 1)
 357       platform_deps += execinfo_dep
 358     endif
 359   endif
 360 endif
 361
 362 gst_debug = get_option('gst_debug')
 363 if not gst_debug
 364   add_project_arguments(['-Wno-unused'], language: 'c')
 365 endif
 366
 367 warning_flags = [
 368   '-Wmissing-declarations',
 369   '-Wmissing-prototypes',
 370   '-Wredundant-decls',
 371   '-Wundef',
 372   '-Wwrite-strings',
 373   '-Wformat',
 374   '-Wformat-nonliteral',
 375   '-Wformat-security',
 376   '-Wold-style-definition',
 377   '-Winit-self',
 378   '-Wmissing-include-dirs',
 379   '-Waddress',
 380   '-Waggregate-return',
 381   '-Wno-multichar',
 382   '-Wnested-externs',
 383   '-Wdeclaration-after-statement',
 384   '-Wvla',
 385   '-Wpointer-arith',
 386 ]
 387
 388 foreach extra_arg : warning_flags
 389   if cc.has_argument (extra_arg)
 390     add_project_arguments([extra_arg], language: 'c')
 391   endif
 392 endforeach
 393
 394 # Used by the gstutils test
 395 gmp_dep = cc.find_library('gmp', required : false)
 396 cdata.set('HAVE_GMP', gmp_dep.found())
 397 gsl_dep = cc.find_library('gsl', required : false)
 398 gslcblas_dep = cc.find_library('gslcblas', required : false)
 399 cdata.set('HAVE_GSL', gsl_dep.found() and gslcblas_dep.found())
 400 test_deps = [gmp_dep, gsl_dep, gslcblas_dep]
 401
 402 # Used by gstinfo.c
 403 dl_dep = cc.find_library('dl', required : false)
 404 cdata.set('HAVE_DLADDR', cc.has_function('dladdr', dependencies : dl_dep))
 405 cdata.set('GST_ENABLE_EXTRA_CHECKS', get_option('extra-checks'))
 406 cdata.set('USE_POISONING', get_option('poisoning'))
 407
 408 configinc = include_directories('.')
 409 libsinc = include_directories('libs')
 410 privinc = include_directories('gst')
 411
 412 # Find dependencies
 413 glib_dep = dependency('glib-2.0', version : '>=2.32.0',
 414   fallback: ['glib', 'libglib_dep'])
 415 gobject_dep = dependency('gobject-2.0',
 416   fallback: ['glib', 'libgobject_dep'])
 417 gmodule_dep = dependency('gmodule-2.0',
 418   fallback: ['glib', 'libgmodule_dep'])
 419 if host_system == 'windows'
 420     gio_dep = dependency('gio-2.0',
 421         fallback: ['glib', 'libgio_dep'])
 422 else
 423     gio_dep = [dependency('gio-2.0',
 424                   fallback: ['glib', 'libgio_dep']),
 425                dependency('gio-unix-2.0',
 426                   fallback: ['glib', 'libgio_dep'])]
 427 endif
 428
 429 mathlib = cc.find_library('m', required : false)
 430 # Needed for timer_create/settime/delete
 431 # Also provides clock_gettime in glibc < 2.17
 432 rt_lib = cc.find_library('rt', required : false)
 433
 434 gir = find_program('g-ir-scanner', required : get_option('introspection'))
 435 gnome = import('gnome')
 436
 437 build_gir = gir.found() and not meson.is_cross_build()
 438
 439 gir_init_section = [ '--add-init-section=extern void gst_init(gint*,gchar**);' + \
 440     'g_setenv("GST_REGISTRY_DISABLE", "yes", TRUE);' + \
 441     'g_setenv("GST_REGISTRY_1.0", "/no/way/this/exists.reg", TRUE);' + \
 442     'g_setenv("GST_PLUGIN_PATH_1_0", "", TRUE);' + \
 443     'g_setenv("GST_PLUGIN_SYSTEM_PATH_1_0", "", TRUE);' + \
 444     'gst_init(NULL,NULL);' ]
 445
 446 gst_c_args = ['-DHAVE_CONFIG_H']
 447
 448 # FIXME: This is only needed on windows and probably breaks when
 449 # default_library = 'both'. We should add this flag to static_c_args instead
 450 # when Meson supports it: https://github.com/mesonbuild/meson/issues/3304
 451 if get_option('default_library') == 'static'
 452   gst_c_args += ['-DGST_STATIC_COMPILATION']
 453 endif
 454
 455 # Used in gst/parse/meson.build and below
 456 python3 = import('python3').find_python()
 457
 458 bashcomp_option = get_option('bash-completion')
 459 bashcomp_dep = dependency('bash-completion', version : '>= 2.0', required : bashcomp_option)
 460 bash_completions_dir = ''
 461 bash_helpers_dir = ''
 462
 463 bashcomp_found = false
 464 if bashcomp_dep.found()
 465   bashcomp_found = true
 466   bash_completions_dir = bashcomp_dep.get_pkgconfig_variable('completionsdir', define_variable: ['prefix', '.'])
 467   if bash_completions_dir == ''
 468     msg = 'Found bash-completion but the .pc file did not set \'completionsdir\'.'
 469     if bashcomp_option.enabled()
 470       error(msg)
 471     else
 472       message(msg)
 473     endif
 474     bashcomp_found = false
 475   endif
 476
 477   bash_helpers_dir = bashcomp_dep.get_pkgconfig_variable('helpersdir', define_variable: ['prefix', '.'])
 478   if bash_helpers_dir == ''
 479     msg = 'Found bash-completion, but the .pc file did not set \'helpersdir\'.'
 480     if bashcomp_option.enabled()
 481       error(msg)
 482     else
 483       message(msg)
 484     endif
 485     bashcomp_found = false
 486   endif
 487 endif
 488
 489 subdir('gst')
 490 subdir('libs')
 491 subdir('plugins')
 492 if not get_option('tools').disabled()
 493   subdir('tools')
 494 endif
 495 subdir('pkgconfig')
 496 subdir('tests')
 497 subdir('data')
 498
 499 # xgettext is optional (on Windows for instance)
 500 if find_program('xgettext', required : get_option('nls')).found()
 501   cdata.set('ENABLE_NLS', 1)
 502   subdir('po')
 503 endif
 504
 505 configure_file(output : 'config.h', configuration : cdata)
 506
 507 if build_machine.system() == 'windows'
 508   message('Disabling gtk-doc while building on Windows')
 509 else
 510   if find_program('gtkdoc-scan', required : get_option('gtk_doc')).found()
 511     subdir('docs')
 512   else
 513     message('Not building documentation as gtk-doc was not found')
 514   endif
 515 endif
 516
 517 run_command(python3, '-c', 'import shutil; shutil.copy("hooks/pre-commit.hook", ".git/hooks/pre-commit")')
 518
 519 install_data('gst-element-check-1.0.m4', install_dir : join_paths(get_option('datadir'), 'aclocal'))