meson.build

   1 project('gstreamer', 'c',
   2   version : '1.17.0.1',
   3   meson_version : '>= 0.48',
   4   default_options : [ 'warning_level=1',
   5                       'buildtype=debugoptimized' ])
   6
   7 gst_version = meson.project_version()
   8 version_arr = gst_version.split('.')
   9 gst_version_major = version_arr[0].to_int()
  10 gst_version_minor = version_arr[1].to_int()
  11 gst_version_micro = version_arr[2].to_int()
  12 if version_arr.length() == 4
  13   gst_version_nano = version_arr[3].to_int()
  14 else
  15   gst_version_nano = 0
  16 endif
  17 gst_version_is_dev = gst_version_minor % 2 == 1 and gst_version_micro < 90
  18
  19 host_system = host_machine.system()
  20
  21 apiversion = '1.0'
  22 soversion = 0
  23 # maintaining compatibility with the previous libtool versioning
  24 # current = minor * 100 + micro
  25 curversion = gst_version_minor * 100 + gst_version_micro
  26 libversion = '@0@.@1@.0'.format(soversion, curversion)
  27 osxversion = curversion + 1
  28
  29 prefix = get_option('prefix')
  30
  31 libexecdir = get_option('libexecdir')
  32 helpers_install_dir = join_paths(libexecdir, 'gstreamer-1.0')
  33
  34 cc = meson.get_compiler('c')
  35
  36 cdata = configuration_data()
  37
  38 # Ignore several spurious warnings for things gstreamer does very commonly
  39 # If a warning is completely useless and spammy, use '/wdXXXX' to suppress it
  40 # If a warning is harmless but hard to fix, use '/woXXXX' so it's shown once
  41 # NOTE: Only add warnings here if you are sure they're spurious
  42 if cc.get_id() == 'msvc'
  43   add_project_arguments(
  44       '/wd4018', # implicit signed/unsigned conversion
  45       '/wd4146', # unary minus on unsigned (beware INT_MIN)
  46       '/wd4244', # lossy type conversion (e.g. double -> int)
  47       '/wd4305', # truncating type conversion (e.g. double -> float)
  48       cc.get_supported_arguments(['/utf-8']), # set the input encoding to utf-8
  49       language : 'c')
  50 elif cc.has_link_argument('-Wl,-Bsymbolic-functions')
  51   # FIXME: Add an option for this if people ask for it
  52   add_project_link_arguments('-Wl,-Bsymbolic-functions', language : 'c')
  53 endif
  54
  55 # Symbol visibility
  56 have_visibility_hidden = false
  57 if cc.get_id() == 'msvc'
  58   export_define = '__declspec(dllexport) extern'
  59 elif cc.has_argument('-fvisibility=hidden')
  60   add_project_arguments('-fvisibility=hidden', language: 'c')
  61   export_define = 'extern __attribute__ ((visibility ("default")))'
  62   have_visibility_hidden = true
  63 else
  64   export_define = 'extern'
  65 endif
  66
  67 # Passing this through the command line would be too messy
  68 cdata.set('GST_API_EXPORT', export_define)
  69
  70 # Disable strict aliasing
  71 if cc.has_argument('-fno-strict-aliasing')
  72   add_project_arguments('-fno-strict-aliasing', language: 'c')
  73 endif
  74
  75 # Define G_DISABLE_DEPRECATED for development versions
  76 if gst_version_is_dev
  77   message('Disabling deprecated GLib API')
  78   add_project_arguments('-DG_DISABLE_DEPRECATED', language: 'c')
  79 endif
  80
  81 cast_checks = get_option('gobject-cast-checks')
  82 if cast_checks.disabled() or (cast_checks.auto() and not gst_version_is_dev)
  83   message('Disabling GLib cast checks')
  84   add_project_arguments('-DG_DISABLE_CAST_CHECKS', language: 'c')
  85 endif
  86
  87 glib_asserts = get_option('glib-asserts')
  88 if glib_asserts.disabled() or (glib_asserts.auto() and not gst_version_is_dev)
  89   message('Disabling GLib asserts')
  90   add_project_arguments('-DG_DISABLE_ASSERT', language: 'c')
  91 endif
  92
  93 glib_checks = get_option('glib-checks')
  94 if glib_checks.disabled() or (glib_checks.auto() and not gst_version_is_dev)
  95   message('Disabling GLib checks')
  96   add_project_arguments('-DG_DISABLE_CHECKS', language: 'c')
  97 endif
  98
  99 cdata.set_quoted('GST_API_VERSION', apiversion)
 100 cdata.set_quoted('GST_DATADIR', join_paths(prefix, get_option('datadir')))
 101 cdata.set_quoted('LOCALEDIR', join_paths(prefix, get_option('localedir')))
 102 cdata.set_quoted('LIBDIR', join_paths(prefix, get_option('libdir')))
 103 cdata.set_quoted('GST_API_VERSION', '1.0')
 104 cdata.set_quoted('GETTEXT_PACKAGE', 'gstreamer-1.0')
 105 cdata.set_quoted('GST_LICENSE', 'LGPL')
 106 cdata.set_quoted('PACKAGE', 'gstreamer')
 107 cdata.set_quoted('PACKAGE_NAME', 'GStreamer')
 108 cdata.set_quoted('PACKAGE_STRING', 'GStreamer @0@'.format(gst_version))
 109 cdata.set_quoted('PACKAGE_TARNAME', 'gstreamer')
 110 cdata.set_quoted('PACKAGE_BUGREPORT', 'http://bugzilla.gnome.org/enter_bug.cgi?product=GStreamer')
 111 cdata.set_quoted('PACKAGE_URL', '')
 112 cdata.set_quoted('PACKAGE_VERSION', gst_version)
 113 cdata.set_quoted('PLUGINDIR', join_paths(get_option('prefix'), get_option('libdir'), 'gstreamer-1.0'))
 114 cdata.set_quoted('VERSION', gst_version)
 115 cdata.set_quoted('GST_PLUGIN_SCANNER_INSTALLED', join_paths(prefix, helpers_install_dir, 'gst-plugin-scanner'))
 116 cdata.set_quoted('GST_PTP_HELPER_INSTALLED', join_paths(prefix, helpers_install_dir, 'gst-ptp-helper'))
 117 cdata.set_quoted('GST_PLUGIN_SUBDIR', get_option('libdir'),
 118   description: 'plugin directory path component, used to find plugins on relocatable builds on windows')
 119 cdata.set_quoted('GST_PLUGIN_SCANNER_SUBDIR', libexecdir,
 120   description: 'libexecdir path component, used to find plugin-scanner on relocatable builds on windows')
 121 cdata.set('GST_DISABLE_OPTION_PARSING', not get_option('option-parsing'))
 122
 123 mem_align_opt = get_option('memory-alignment')
 124 if mem_align_opt == 'malloc'
 125   cdata.set('MEMORY_ALIGNMENT_MALLOC', 1)
 126 elif mem_align_opt == 'pagesize'
 127   cdata.set('MEMORY_ALIGNMENT_PAGESIZE', 1)
 128 else
 129   cdata.set('MEMORY_ALIGNMENT', mem_align_opt.to_int())
 130 endif
 131
 132 if ['darwin', 'ios'].contains(host_system)
 133   cdata.set_quoted('GST_EXTRA_MODULE_SUFFIX', '.dylib')
 134 endif
 135
 136 if gst_version_nano > 0
 137     # Have GST_ERROR message printed when running from git
 138     cdata.set('GST_LEVEL_DEFAULT', 'GST_LEVEL_ERROR')
 139 else
 140     cdata.set('GST_LEVEL_DEFAULT', 'GST_LEVEL_NONE')
 141 endif
 142
 143 # GStreamer package name and origin url
 144 gst_package_name = get_option('package-name')
 145 if gst_package_name == ''
 146   if gst_version_nano == 0
 147     gst_package_name = 'GStreamer source release'
 148   elif gst_version_nano == 1
 149     gst_package_name = 'GStreamer git'
 150   else
 151     gst_package_name = 'GStreamer prerelease'
 152   endif
 153 endif
 154 cdata.set_quoted('GST_PACKAGE_NAME', gst_package_name)
 155 cdata.set_quoted('GST_PACKAGE_ORIGIN', get_option('package-origin'))
 156
 157 # These are only needed/used by the ABI tests
 158 host_defines = [
 159   [ 'x86', 'HAVE_CPU_I386' ],
 160   [ 'x86_64', 'HAVE_CPU_X86_64' ],
 161   [ 'arm', 'HAVE_CPU_ARM' ],
 162   [ 'aarch64', 'HAVE_CPU_AARCH64' ],
 163   [ 'mips', 'HAVE_CPU_MIPS' ],
 164   [ 'powerpc', 'HAVE_CPU_PPC' ],
 165   [ 'powerpc64', 'HAVE_CPU_PPC64' ],
 166   [ 'alpha', 'HAVE_CPU_ALPHA' ],
 167   [ 'sparc', 'HAVE_CPU_SPARC' ],
 168   [ 'ia64', 'HAVE_CPU_IA64' ],
 169   [ 'hppa', 'HAVE_CPU_HPPA' ],
 170   [ 'm68k', 'HAVE_CPU_M68K' ],
 171   [ 's390', 'HAVE_CPU_S390' ],
 172 ]
 173 foreach h : host_defines
 174   if h.get(0) == host_machine.cpu()
 175     cdata.set(h.get(1), 1)
 176   endif
 177 endforeach
 178 # FIXME: should really be called HOST_CPU or such
 179 cdata.set_quoted('TARGET_CPU', host_machine.cpu())
 180
 181 check_headers = [
 182   'dlfcn.h',
 183   'inttypes.h',
 184   'memory.h',
 185   'poll.h',
 186   'stdint.h',
 187   'stdio_ext.h',
 188   'strings.h',
 189   'string.h',
 190   'sys/param.h',
 191   'sys/poll.h',
 192   'sys/prctl.h',
 193   'sys/socket.h',
 194   'sys/stat.h',
 195   'sys/times.h',
 196   'sys/time.h',
 197   'sys/types.h',
 198   'sys/utsname.h',
 199   'sys/wait.h',
 200   'ucontext.h',
 201   'unistd.h',
 202   'valgrind/valgrind.h',
 203   'sys/resource.h',
 204   'sys/uio.h',
 205 ]
 206
 207 if host_system == 'windows'
 208   check_headers += ['winsock2.h']
 209 endif
 210
 211 foreach h : check_headers
 212   if cc.has_header(h)
 213     define = 'HAVE_' + h.underscorify().to_upper()
 214     cdata.set(define, 1)
 215   endif
 216 endforeach
 217
 218 if cc.has_member('struct tm', 'tm_gmtoff', prefix : '#include <time.h>')
 219   cdata.set('HAVE_TM_GMTOFF', 1)
 220 endif
 221
 222 check_functions = [
 223   'gmtime_r',
 224   'sigaction',
 225   'getrusage',
 226   'fseeko',
 227   'ftello',
 228   'poll',
 229   'ppoll',
 230   'pselect',
 231   'getpagesize',
 232   'clock_gettime',
 233   'strnlen',
 234   # These are needed by libcheck
 235   'getline',
 236   'mkstemp',
 237   'alarm',
 238   'gettimeofday',
 239 ]
 240
 241 foreach f : check_functions
 242   if cc.has_function(f)
 243     define = 'HAVE_' + f.underscorify().to_upper()
 244     cdata.set(define, 1)
 245   endif
 246 endforeach
 247
 248 if cc.has_function('localtime_r', prefix : '#include<time.h>')
 249   cdata.set('HAVE_LOCALTIME_R', 1)
 250   # Needed by libcheck
 251   cdata.set('HAVE_DECL_LOCALTIME_R', 1)
 252 endif
 253
 254 if cc.links('''#include <pthread.h>
 255                int main() {
 256                  pthread_setname_np("example"); return 0;
 257                }''', name : 'pthread_setname_np(const char*)')
 258   cdata.set('HAVE_PTHREAD_SETNAME_NP_WITHOUT_TID', 1)
 259 endif
 260
 261 # Check for posix timers and monotonic clock
 262 time_prefix = '#include <time.h>\n'
 263 if cdata.has('HAVE_UNISTD_H')
 264   time_prefix += '#include <unistd.h>'
 265 endif
 266
 267 posix_timers_src = time_prefix + '''
 268 #if !defined(_POSIX_TIMERS) || _POSIX_TIMERS < 0 || !defined(CLOCK_REALTIME)
 269 #error Either _POSIX_TIMERS or CLOCK_REALTIME not defined
 270 #endif
 271 '''
 272 if cc.compiles(posix_timers_src, name : 'posix timers from time.h')
 273   cdata.set('HAVE_POSIX_TIMERS', 1)
 274 endif
 275
 276 monotonic_clock_src = time_prefix + '''
 277 #if !defined(_POSIX_MONOTONIC_CLOCK) || _POSIX_MONOTONIC_CLOCK < 0 || !defined(CLOCK_MONOTONIC)
 278 #error Either _POSIX_MONOTONIC_CLOCK or CLOCK_MONOTONIC not defined
 279 #endif
 280 '''
 281 if cc.compiles(monotonic_clock_src, name : 'monotonic clock from time.h')
 282   cdata.set('HAVE_MONOTONIC_CLOCK', 1)
 283 endif
 284
 285 # Check for __uint128_t (gcc) by checking for 128-bit division
 286 uint128_t_src = '''int main() {
 287 static __uint128_t v1 = 100;
 288 static __uint128_t v2 = 10;
 289 static __uint128_t u;
 290 u = v1 / v2;
 291 }'''
 292 if cc.compiles(uint128_t_src, name : '__uint128_t available')
 293   cdata.set('HAVE_UINT128_T', 1)
 294 endif
 295
 296 # All supported platforms have long long now
 297 cdata.set('HAVE_LONG_LONG', 1)
 298
 299 # We only want to use the __declspec(dllexport/import) dance in GST_EXPORT when
 300 # building with MSVC
 301 if cc.get_id() == 'msvc'
 302   cdata.set('GSTCONFIG_BUILT_WITH_MSVC', 1)
 303 else
 304   cdata.set('GSTCONFIG_BUILT_WITH_MSVC', 0)
 305 endif
 306
 307 # -------------------------------------------------------------------------------------
 308 # config.h things needed by libcheck
 309 # -------------------------------------------------------------------------------------
 310 if cc.has_function('getpid')
 311   cdata.set('HAVE_GETPID', 1)
 312 elif host_system == 'windows' and cc.has_function('_getpid')
 313   cdata.set('HAVE_PROCESS_H', 1) # Used by gstreamer too
 314   cdata.set('HAVE__GETPID', 1)
 315 endif
 316 if cc.has_function('strdup')
 317   cdata.set('HAVE_DECL_STRDUP', 1)
 318 elif host_system == 'windows' and cc.has_function('_strdup')
 319   cdata.set('HAVE__STRDUP', 1) # Windows (MSVC)
 320 endif
 321 if host_system != 'windows'
 322   cdata.set('HAVE_FORK', 1)
 323 else
 324   # libcheck requires HAVE_FORK to be 0 when fork() is not available
 325   cdata.set('HAVE_FORK', 0)
 326 endif
 327 if cc.has_function('strsignal')
 328   cdata.set('HAVE_DECL_STRSIGNAL', 1)
 329 endif
 330 # Check for availability of types
 331 if not cc.has_type('clockid_t', prefix : '#include <time.h>')
 332   cdata.set('clockid_t', 'int')
 333 endif
 334 if not cc.has_type('timer_t', prefix : '#include <time.h>')
 335   cdata.set('timer_t', 'int')
 336 endif
 337 if not cc.has_members('struct timespec', 'tv_sec', 'tv_nsec',
 338                       prefix : '#include <time.h>')
 339   cdata.set('STRUCT_TIMESPEC_DEFINITION_MISSING', 1)
 340 endif
 341 if not cc.has_members('struct itimerspec', 'it_interval', 'it_value',
 342                       prefix : '#include <time.h>')
 343   cdata.set('STRUCT_ITIMERSPEC_DEFINITION_MISSING', 1)
 344 endif
 345
 346 # Platform deps; only ws2_32 and execinfo for now
 347 platform_deps = []
 348 if host_system == 'windows'
 349   platform_deps = [cc.find_library('ws2_32')]
 350 endif
 351
 352 backtrace_deps = []
 353 unwind_dep = dependency('libunwind', required : get_option('libunwind'))
 354 dw_dep = dependency('libdw', required: get_option('libdw'))
 355 dbghelp_dep = dependency('DbgHelp', required : get_option('dbghelp'))
 356 backtrace_deps = [unwind_dep, dw_dep, dbghelp_dep]
 357 backtrace_source_info = false
 358 backtrace_minimal = false
 359 # MSVC debug stack trace support
 360 if host_system == 'windows' and dbghelp_dep.found()
 361   cdata.set('HAVE_DBGHELP', 1)
 362   backtrace_source_info = true
 363 # DWARF stack trace support with libunwind and elf-utils
 364 elif unwind_dep.found()
 365   cdata.set('HAVE_UNWIND', 1)
 366   if dw_dep.found()
 367     cdata.set('HAVE_DW', 1)
 368     backtrace_source_info = true
 369   endif
 370   backtrace_minimal = true
 371 # Basic backtrace() stack trace support
 372 elif cc.has_function('backtrace')
 373   cdata.set('HAVE_BACKTRACE', 1)
 374   backtrace_minimal = true
 375 endif
 376 # Print messages about what was enabled
 377 if not backtrace_source_info
 378   if not backtrace_minimal
 379     message('NO support for stack traces.')
 380   else
 381     message('Minimal support for stack traces, no source info.')
 382   endif
 383 endif
 384
 385 if cc.has_header('execinfo.h')
 386   if cc.has_function('backtrace', prefix : '#include <execinfo.h>')
 387     cdata.set('HAVE_BACKTRACE', 1)
 388   else
 389     execinfo_dep = cc.find_library('execinfo', required : false)
 390     if execinfo_dep.found() and cc.has_function('backtrace', prefix : '#include <execinfo.h>', dependencies : execinfo_dep)
 391       cdata.set('HAVE_BACKTRACE', 1)
 392       platform_deps += execinfo_dep
 393     endif
 394   endif
 395 endif
 396
 397 gst_debug = get_option('gst_debug')
 398 if not gst_debug
 399   add_project_arguments(['-Wno-unused'], language: 'c')
 400 endif
 401
 402 warning_flags = [
 403   '-Wmissing-declarations',
 404   '-Wmissing-prototypes',
 405   '-Wredundant-decls',
 406   '-Wundef',
 407   '-Wwrite-strings',
 408   '-Wformat',
 409   '-Wformat-nonliteral',
 410   '-Wformat-security',
 411   '-Wold-style-definition',
 412   '-Winit-self',
 413   '-Wmissing-include-dirs',
 414   '-Waddress',
 415   '-Waggregate-return',
 416   '-Wno-multichar',
 417   '-Wdeclaration-after-statement',
 418   '-Wvla',
 419   '-Wpointer-arith',
 420 ]
 421
 422 foreach extra_arg : warning_flags
 423   if cc.has_argument (extra_arg)
 424     add_project_arguments([extra_arg], language: 'c')
 425   endif
 426 endforeach
 427
 428 # Used by the gstutils test
 429 gmp_dep = cc.find_library('gmp', required : false)
 430 cdata.set('HAVE_GMP', gmp_dep.found())
 431 gsl_dep = cc.find_library('gsl', required : false)
 432 gslcblas_dep = cc.find_library('gslcblas', required : false)
 433 cdata.set('HAVE_GSL', gsl_dep.found() and gslcblas_dep.found())
 434 test_deps = [gmp_dep, gsl_dep, gslcblas_dep]
 435
 436 # Used by gstinfo.c
 437 dl_dep = cc.find_library('dl', required : false)
 438 cdata.set('HAVE_DLADDR', cc.has_function('dladdr', dependencies : dl_dep))
 439 cdata.set('GST_ENABLE_EXTRA_CHECKS', not get_option('extra-checks').disabled())
 440 cdata.set('USE_POISONING', get_option('poisoning'))
 441
 442 configinc = include_directories('.')
 443 libsinc = include_directories('libs')
 444 privinc = include_directories('gst')
 445
 446 # Find dependencies
 447 glib_dep = dependency('glib-2.0', version : '>=2.44.0',
 448   fallback: ['glib', 'libglib_dep'])
 449 gobject_dep = dependency('gobject-2.0',
 450   fallback: ['glib', 'libgobject_dep'])
 451 gmodule_dep = dependency('gmodule-2.0',
 452   fallback: ['glib', 'libgmodule_dep'])
 453 if host_system == 'windows'
 454     gio_dep = dependency('gio-2.0',
 455         fallback: ['glib', 'libgio_dep'])
 456 else
 457     gio_dep = [dependency('gio-2.0',
 458                   fallback: ['glib', 'libgio_dep']),
 459                dependency('gio-unix-2.0',
 460                   fallback: ['glib', 'libgio_dep'])]
 461 endif
 462
 463 mathlib = cc.find_library('m', required : false)
 464 # Needed for timer_create/settime/delete
 465 # Also provides clock_gettime in glibc < 2.17
 466 rt_lib = cc.find_library('rt', required : false)
 467
 468 gir = find_program('g-ir-scanner', required : get_option('introspection'))
 469 gnome = import('gnome')
 470
 471 build_gir = gir.found() and (not meson.is_cross_build() or get_option('introspection').enabled())
 472
 473 gir_init_section = [ '--add-init-section=extern void gst_init(gint*,gchar**);' + \
 474     'g_setenv("GST_REGISTRY_DISABLE", "yes", TRUE);' + \
 475     'g_setenv("GST_REGISTRY_1.0", "/no/way/this/exists.reg", TRUE);' + \
 476     'g_setenv("GST_PLUGIN_PATH_1_0", "", TRUE);' + \
 477     'g_setenv("GST_PLUGIN_SYSTEM_PATH_1_0", "", TRUE);' + \
 478     'gst_init(NULL,NULL);', '--quiet']
 479
 480 gst_c_args = ['-DHAVE_CONFIG_H']
 481
 482 # FIXME: This is only needed on windows and probably breaks when
 483 # default_library = 'both'. We should add this flag to static_c_args instead
 484 # when Meson supports it: https://github.com/mesonbuild/meson/issues/3304
 485 if get_option('default_library') == 'static'
 486   gst_c_args += ['-DGST_STATIC_COMPILATION']
 487 endif
 488
 489 # Used in gst/parse/meson.build and below
 490 python3 = import('python').find_installation()
 491
 492 bashcomp_option = get_option('bash-completion')
 493 bashcomp_dep = dependency('bash-completion', version : '>= 2.0', required : bashcomp_option)
 494 bash_completions_dir = ''
 495 bash_helpers_dir = ''
 496
 497 bashcomp_found = false
 498 if bashcomp_dep.found()
 499   bashcomp_found = true
 500   bash_completions_dir = bashcomp_dep.get_pkgconfig_variable('completionsdir', define_variable: ['prefix', '.'])
 501   if bash_completions_dir == ''
 502     msg = 'Found bash-completion but the .pc file did not set \'completionsdir\'.'
 503     if bashcomp_option.enabled()
 504       error(msg)
 505     else
 506       message(msg)
 507     endif
 508     bashcomp_found = false
 509   endif
 510
 511   bash_helpers_dir = bashcomp_dep.get_pkgconfig_variable('helpersdir', define_variable: ['prefix', '.'])
 512   if bash_helpers_dir == ''
 513     msg = 'Found bash-completion, but the .pc file did not set \'helpersdir\'.'
 514     if bashcomp_option.enabled()
 515       error(msg)
 516     else
 517       message(msg)
 518     endif
 519     bashcomp_found = false
 520   endif
 521 endif
 522
 523 plugins_install_dir = join_paths(get_option('libdir'), 'gstreamer-1.0')
 524
 525 pkgconfig = import('pkgconfig')
 526 plugins_pkgconfig_install_dir = join_paths(plugins_install_dir, 'pkgconfig')
 527 if get_option('default_library') == 'shared'
 528   # If we don't build static plugins there is no need to generate pc files
 529   plugins_pkgconfig_install_dir = disabler()
 530 endif
 531
 532 subdir('gst')
 533 subdir('libs')
 534 subdir('plugins')
 535 if not get_option('tools').disabled()
 536   subdir('tools')
 537 endif
 538 subdir('pkgconfig')
 539 subdir('tests')
 540 subdir('data')
 541 subdir('docs')
 542
 543 # xgettext is optional (on Windows for instance)
 544 if find_program('xgettext', required : get_option('nls')).found()
 545   cdata.set('ENABLE_NLS', 1)
 546   subdir('po')
 547 endif
 548
 549 configure_file(output : 'config.h', configuration : cdata)
 550 run_command(python3, '-c', 'import shutil; shutil.copy("hooks/pre-commit.hook", ".git/hooks/pre-commit")')
 551 install_data('gst-element-check-1.0.m4', install_dir : join_paths(get_option('datadir'), 'aclocal'))