meson.build

   1 project('gst-libav', 'c', 'cpp',
   2   version : '1.13.0.1',
   3   meson_version : '>= 0.36.0',
   4   default_options : [ 'warning_level=1',
   5                       'buildtype=debugoptimized' ])
   6
   7 gst_version = meson.project_version()
   8 version_arr = gst_version.split('.')
   9 gst_version_major = version_arr[0]
  10 gst_version_minor = version_arr[1]
  11 gst_version_micro = version_arr[2]
  12 gst_version_nano = version_arr.get(3, 0)
  13
  14 libavfilter_dep = dependency('libavfilter', version: '>= 6.47.100')
  15 libavformat_dep = dependency('libavformat', version: '>= 57.41.100')
  16 libavcodec_dep = dependency('libavcodec', version: '>= 57.48.101')
  17 libavutil_dep = dependency('libavutil', version: '>= 55.28.100')
  18
  19 libav_deps = [libavfilter_dep, libavformat_dep, libavcodec_dep, libavutil_dep]
  20
  21 cc = meson.get_compiler('c')
  22
  23 check_ffmpeg_src = '''#include <libavcodec/avcodec.h>
  24 #if LIBAVCODEC_VERSION_MICRO >= 100
  25 /* FFmpeg uses 100+ as its micro version */
  26 #else
  27 #error libav provider should be FFmpeg
  28 #endif'''
  29
  30 if not cc.compiles(check_ffmpeg_src, dependencies : libav_deps, name : 'libav is provided by FFmpeg')
  31     error('Uncompatible libavcodec found')
  32 endif
  33
  34 cdata = configuration_data()
  35 cdata.set('LIBAV_SOURCE', '"system install"')
  36 cdata.set('PACKAGE_VERSION', '"@0@"'.format(gst_version))
  37 cdata.set('PACKAGE', '"gst-libav"')
  38
  39 # GStreamer package name and origin url
  40 gst_package_name = get_option('with-package-name')
  41 if gst_package_name == ''
  42   if gst_version_nano == 0
  43     gst_package_name = 'GStreamer FFMPEG Plug-ins source release'
  44   elif gst_version_nano == 1
  45     gst_package_name = 'GStreamer FFMPEG Plug-ins git'
  46   else
  47     gst_package_name = 'GStreamer FFMPEG Plug-ins prerelease'
  48   endif
  49 endif
  50 cdata.set_quoted('GST_PACKAGE_NAME', gst_package_name)
  51 cdata.set_quoted('GST_PACKAGE_ORIGIN', get_option('with-package-origin'))
  52
  53
  54 check_headers = [['unistd.h', 'HAVE_UNISTD_H']]
  55
  56 foreach h : check_headers
  57   if cc.has_header(h.get(0))
  58     cdata.set(h.get(1), 1)
  59   endif
  60 endforeach
  61
  62 gst_req = '>= @0@.@1@.0'.format(gst_version_major, gst_version_minor)
  63 gst_dep = dependency('gstreamer-1.0', version : gst_req,
  64   fallback : ['gstreamer', 'gst_dep'])
  65 gstbase_dep = dependency('gstreamer-base-1.0', version : gst_req,
  66   fallback : ['gstreamer', 'gst_base_dep'])
  67
  68 gstvideo_dep = dependency('gstreamer-video-1.0', version : gst_req,
  69     fallback : ['gst-plugins-base', 'video_dep'])
  70 gstaudio_dep = dependency('gstreamer-audio-1.0', version : gst_req,
  71     fallback : ['gst-plugins-base', 'audio_dep'])
  72 gstpbutils_dep = dependency('gstreamer-pbutils-1.0', version : gst_req,
  73     fallback : ['gst-plugins-base', 'pbutils_dep'])
  74 libm = cc.find_library('m', required : false)
  75
  76 configure_file(output : 'config.h', configuration : cdata)
  77
  78 gst_libav_args = ['-DHAVE_CONFIG_H']
  79 if cc.get_id() != 'msvc'
  80   gst_libav_args += ['-Wno-deprecated-declarations']
  81 else
  82   # Ignore several spurious warnings for things gstreamer does very commonly
  83   # If a warning is completely useless and spammy, use '/wdXXXX' to suppress it
  84   # If a warning is harmless but hard to fix, use '/woXXXX' so it's shown once
  85   # NOTE: Only add warnings here if you are sure they're spurious
  86   add_project_arguments(
  87       '/wd4018', # implicit signed/unsigned conversion
  88       '/wd4146', # unary minus on unsigned (beware INT_MIN)
  89       '/wd4244', # lossy type conversion (e.g. double -> int)
  90       '/wd4305', # truncating type conversion (e.g. double -> float)
  91       language : 'c')
  92 endif
  93
  94 # Symbol visibility
  95 if cc.has_argument('-fvisibility=hidden')
  96   add_project_arguments('-fvisibility=hidden', language: 'c')
  97 endif
  98
  99 # Disable strict aliasing
 100 if cc.has_argument('-fno-strict-aliasing')
 101   add_project_arguments('-fno-strict-aliasing', language: 'c')
 102 endif
 103
 104 if gst_dep.type_name() == 'internal'
 105     gst_proj = subproject('gstreamer')
 106
 107     if gst_proj.get_variable('disable_gst_debug')
 108         message('GStreamer debug system is disabled')
 109         add_project_arguments('-Wno-unused', language: 'c')
 110     else
 111         message('GStreamer debug system is enabled')
 112     endif
 113 else
 114     # We can't check that in the case of subprojects as we won't
 115     # be able to build against an internal dependency (which is not built yet)
 116     if not cc.compiles('''
 117 #include <gst/gstconfig.h>
 118 #ifdef GST_DISABLE_GST_DEBUG
 119 #error "debugging disabled, make compiler fail"
 120 #endif''' , dependencies: gst_dep)
 121         message('GStreamer debug system is disabled')
 122         add_project_arguments('-Wno-unused', language: 'c')
 123     else
 124         message('GStreamer debug system is enabled')
 125     endif
 126 endif
 127
 128 configinc = include_directories('.')
 129 plugins_install_dir = '@0@/gstreamer-1.0'.format(get_option('libdir'))
 130 subdir('ext/libav/')
 131
 132 python3 = import('python3').find_python()
 133 run_command(python3, '-c', 'import shutil; shutil.copy("hooks/pre-commit.hook", ".git/hooks/pre-commit")')