meson.build

   1 project('gst-plugins-ugly', 'c',
   2   version : '1.17.90',
   3   meson_version : '>= 0.48',
   4   default_options : [ 'warning_level=1',
   5                       'buildtype=debugoptimized' ])
   6
   7 gst_version = meson.project_version()
   8 version_arr = gst_version.split('.')
   9 gst_version_major = version_arr[0].to_int()
  10 gst_version_minor = version_arr[1].to_int()
  11 gst_version_micro = version_arr[2].to_int()
  12  if version_arr.length() == 4
  13   gst_version_nano = version_arr[3].to_int()
  14 else
  15   gst_version_nano = 0
  16 endif
  17 gst_version_is_dev = gst_version_minor % 2 == 1 and gst_version_micro < 90
  18
  19 have_cxx = add_languages('cpp', native: false, required: false)
  20
  21 glib_req = '>= 2.44.0'
  22 gst_req = '>= @0@.@1@.0'.format(gst_version_major, gst_version_minor)
  23
  24 api_version = '1.0'
  25
  26 plugins_install_dir = join_paths(get_option('libdir'), 'gstreamer-1.0')
  27 plugins = []
  28
  29 cc = meson.get_compiler('c')
  30 if have_cxx
  31   cxx = meson.get_compiler('cpp')
  32 endif
  33
  34 if cc.get_id() == 'msvc'
  35   # Ignore several spurious warnings for things gstreamer does very commonly
  36   # If a warning is completely useless and spammy, use '/wdXXXX' to suppress it
  37   # If a warning is harmless but hard to fix, use '/woXXXX' so it's shown once
  38   # NOTE: Only add warnings here if you are sure they're spurious
  39   add_project_arguments(
  40       '/wd4018', # implicit signed/unsigned conversion
  41       '/wd4146', # unary minus on unsigned (beware INT_MIN)
  42       '/wd4244', # lossy type conversion (e.g. double -> int)
  43       '/wd4305', # truncating type conversion (e.g. double -> float)
  44       cc.get_supported_arguments(['/utf-8']), # set the input encoding to utf-8
  45       language : 'c')
  46   # Disable SAFESEH with MSVC for plugins and libs that use external deps that
  47   # are built with MinGW
  48   noseh_link_args = ['/SAFESEH:NO']
  49 else
  50   noseh_link_args = []
  51 endif
  52
  53 if cc.has_link_argument('-Wl,-Bsymbolic-functions')
  54   add_project_link_arguments('-Wl,-Bsymbolic-functions', language : 'c')
  55 endif
  56 if have_cxx and cxx.has_link_argument('-Wl,-Bsymbolic-functions')
  57   add_project_link_arguments('-Wl,-Bsymbolic-functions', language : 'cpp')
  58 endif
  59
  60 cdata = configuration_data()
  61 check_headers = [
  62   ['HAVE_DLFCN_H', 'dlfcn.h'],
  63   ['HAVE_INTTYPES_H', 'inttypes.h'],
  64   ['HAVE_MALLOC_H', 'malloc.h'],
  65   ['HAVE_MEMORY_H', 'memory.h'],
  66   ['HAVE_STDINT_H', 'stdint.h'],
  67   ['HAVE_STDLIB_H', 'stdlib.h'],
  68   ['HAVE_STRINGS_H', 'strings.h'],
  69   ['HAVE_STRING_H', 'string.h'],
  70   ['HAVE_SYS_STAT_H', 'sys/stat.h'],
  71   ['HAVE_SYS_TYPES_H', 'sys/types.h'],
  72   ['HAVE_UNISTD_H', 'unistd.h'],
  73   ['HAVE_WINSOCK2_H', 'winsock2.h'],
  74 ]
  75
  76 foreach h : check_headers
  77   if cc.has_header(h.get(1))
  78     cdata.set(h.get(0), 1)
  79   endif
  80 endforeach
  81
  82 check_functions = [
  83   ['HAVE_DCGETTEXT', 'dcgettext'], # FIXME: this looks unused
  84 ]
  85
  86 foreach f : check_functions
  87   if cc.has_function(f.get(1))
  88     cdata.set(f.get(0), 1)
  89   endif
  90 endforeach
  91
  92 cdata.set('SIZEOF_CHAR', cc.sizeof('char'))
  93 cdata.set('SIZEOF_INT', cc.sizeof('int'))
  94 cdata.set('SIZEOF_LONG', cc.sizeof('long'))
  95 cdata.set('SIZEOF_SHORT', cc.sizeof('short'))
  96 cdata.set('SIZEOF_VOIDP', cc.sizeof('void*'))
  97
  98 cdata.set_quoted('VERSION', gst_version)
  99 cdata.set_quoted('PACKAGE', 'gst-plugins-ugly')
 100 cdata.set_quoted('GST_LICENSE', 'LGPL')
 101 cdata.set_quoted('GETTEXT_PACKAGE', 'gst-plugins-ugly-1.0')
 102 cdata.set_quoted('LOCALEDIR', join_paths(get_option('prefix'), get_option('localedir')))
 103
 104 # GStreamer package name and origin url
 105 gst_package_name = get_option('package-name')
 106 if gst_package_name == ''
 107   if gst_version_nano == 0
 108     gst_package_name = 'GStreamer Ugly Plug-ins source release'
 109   elif gst_version_nano == 1
 110     gst_package_name = 'GStreamer Ugly Plug-ins git'
 111   else
 112     gst_package_name = 'GStreamer Ugly Plug-ins prerelease'
 113   endif
 114 endif
 115 cdata.set_quoted('GST_PACKAGE_NAME', gst_package_name)
 116 cdata.set_quoted('GST_PACKAGE_ORIGIN', get_option('package-origin'))
 117
 118 # Mandatory GST deps
 119 gst_dep = dependency('gstreamer-1.0', version : gst_req,
 120     fallback : ['gstreamer', 'gst_dep'])
 121 gstapp_dep = dependency('gstreamer-app-1.0', version : gst_req,
 122     fallback : ['gst-plugins-base', 'app_dep'])
 123 gstvideo_dep = dependency('gstreamer-video-1.0', version : gst_req,
 124     fallback : ['gst-plugins-base', 'video_dep'])
 125 gstpbutils_dep = dependency('gstreamer-pbutils-1.0', version : gst_req,
 126     fallback : ['gst-plugins-base', 'pbutils_dep'])
 127 gsttag_dep = dependency('gstreamer-tag-1.0', version : gst_req,
 128     fallback : ['gst-plugins-base', 'tag_dep'])
 129 gstfft_dep = dependency('gstreamer-fft-1.0', version : gst_req,
 130     fallback : ['gst-plugins-base', 'fft_dep'])
 131 gstaudio_dep = dependency('gstreamer-audio-1.0', version : gst_req,
 132     fallback : ['gst-plugins-base', 'audio_dep'])
 133 gstbase_dep = dependency('gstreamer-base-1.0', version : gst_req,
 134   fallback : ['gstreamer', 'gst_base_dep'])
 135 gstriff_dep = dependency('gstreamer-riff-1.0', version : gst_req,
 136     fallback : ['gst-plugins-base', 'riff_dep'])
 137 gstrtp_dep = dependency('gstreamer-rtp-1.0', version : gst_req,
 138     fallback : ['gst-plugins-base', 'rtp_dep'])
 139 gstnet_dep = dependency('gstreamer-net-1.0', version : gst_req,
 140   fallback : ['gstreamer', 'gst_net_dep'])
 141 gstsdp_dep = dependency('gstreamer-sdp-1.0', version : gst_req,
 142     fallback : ['gst-plugins-base', 'sdp_dep'])
 143 gstrtsp_dep = dependency('gstreamer-rtsp-1.0', version : gst_req,
 144     fallback : ['gst-plugins-base', 'rtsp_dep'])
 145 gstcheck_dep = dependency('gstreamer-check-1.0', version : gst_req,
 146     required : get_option('tests'),
 147     fallback : ['gstreamer', 'gst_check_dep'])
 148 gstcontroller_dep = dependency('gstreamer-controller-1.0', version : gst_req,
 149   fallback : ['gstreamer', 'gst_controller_dep'])
 150
 151 orc_dep = dependency('orc-0.4', version : '>= 0.4.16', required : get_option('orc'),
 152     fallback : ['orc', 'orc_dep'])
 153 if orc_dep.found()
 154   cdata.set('HAVE_ORC', 1) # used by a52dec for cpu detection
 155 else
 156   cdata.set('DISABLE_ORC', 1)
 157 endif
 158
 159 gmodule_dep = dependency('gmodule-2.0', fallback : ['glib', 'libgmodule_dep'])
 160
 161 ugly_args = ['-DHAVE_CONFIG_H']
 162 configinc = include_directories('.')
 163 libsinc = include_directories('gst-libs')
 164
 165 # Disable compiler warnings for unused variables and args if gst debug system is disabled
 166 if gst_dep.type_name() == 'internal'
 167   gst_debug_disabled = not subproject('gstreamer').get_variable('gst_debug')
 168 else
 169   # We can't check that in the case of subprojects as we won't
 170   # be able to build against an internal dependency (which is not built yet)
 171   gst_debug_disabled = cc.has_header_symbol('gst/gstconfig.h', 'GST_DISABLE_GST_DEBUG', dependencies: gst_dep)
 172 endif
 173
 174 if gst_debug_disabled
 175   message('GStreamer debug system is disabled')
 176   if cc.has_argument('-Wno-unused')
 177     add_project_arguments('-Wno-unused', language: 'c')
 178   endif
 179   if have_cxx and cxx.has_argument ('-Wno-unused')
 180     add_project_arguments('-Wno-unused', language: 'cpp')
 181   endif
 182 else
 183   message('GStreamer debug system is enabled')
 184 endif
 185
 186 warning_flags = [
 187   '-Wmissing-declarations',
 188   '-Wredundant-decls',
 189   '-Wwrite-strings',
 190   '-Wformat',
 191   '-Wformat-nonliteral',
 192   '-Wformat-security',
 193   '-Winit-self',
 194   '-Wmissing-include-dirs',
 195   '-Waddress',
 196   '-Wno-multichar',
 197   '-Wvla',
 198   '-Wpointer-arith',
 199   '-Waggregate-return',
 200   '-fno-strict-aliasing',
 201   # Symbol visibility
 202   '-fvisibility=hidden',
 203 ]
 204
 205 warning_c_flags = [
 206   '-Wmissing-prototypes',
 207   '-Wold-style-definition',
 208   '-Wdeclaration-after-statement',
 209   '-Wnested-externs'
 210 ]
 211
 212 foreach extra_arg : warning_flags
 213   if cc.has_argument (extra_arg)
 214     add_project_arguments([extra_arg], language: 'c')
 215   endif
 216   if have_cxx and cxx.has_argument (extra_arg)
 217     add_project_arguments([extra_arg], language: 'cpp')
 218   endif
 219 endforeach
 220
 221 foreach extra_arg : warning_c_flags
 222   if cc.has_argument (extra_arg)
 223     add_project_arguments([extra_arg], language: 'c')
 224   endif
 225 endforeach
 226
 227 # Define G_DISABLE_DEPRECATED for development versions
 228 if gst_version_is_dev
 229   message('Disabling deprecated GLib API')
 230   add_project_arguments('-DG_DISABLE_DEPRECATED', language: 'c')
 231 endif
 232
 233 cast_checks = get_option('gobject-cast-checks')
 234 if cast_checks.disabled() or (cast_checks.auto() and not gst_version_is_dev)
 235   message('Disabling GLib cast checks')
 236   add_project_arguments('-DG_DISABLE_CAST_CHECKS', language: 'c')
 237 endif
 238
 239 glib_asserts = get_option('glib-asserts')
 240 if glib_asserts.disabled() or (glib_asserts.auto() and not gst_version_is_dev)
 241   message('Disabling GLib asserts')
 242   add_project_arguments('-DG_DISABLE_ASSERT', language: 'c')
 243 endif
 244
 245 glib_checks = get_option('glib-checks')
 246 if glib_checks.disabled() or (glib_checks.auto() and not gst_version_is_dev)
 247   message('Disabling GLib checks')
 248   add_project_arguments('-DG_DISABLE_CHECKS', language: 'c')
 249 endif
 250
 251 presetdir = join_paths(get_option('datadir'), 'gstreamer-' + api_version, 'presets')
 252
 253 pkgconfig = import('pkgconfig')
 254 plugins_pkgconfig_install_dir = join_paths(plugins_install_dir, 'pkgconfig')
 255 if get_option('default_library') == 'shared'
 256   # If we don't build static plugins there is no need to generate pc files
 257   plugins_pkgconfig_install_dir = disabler()
 258 endif
 259
 260 python3 = import('python').find_installation()
 261 subdir('gst')
 262 subdir('ext')
 263 subdir('tests')
 264
 265 # xgettext is optional (on Windows for instance)
 266 if find_program('xgettext', required : get_option('nls')).found()
 267   cdata.set('ENABLE_NLS', 1)
 268   subdir('po')
 269 endif
 270 subdir('docs')
 271
 272 # Set release date
 273 if gst_version_nano == 0
 274   extract_release_date = find_program('scripts/extract-release-date-from-doap-file.py')
 275   run_result = run_command(extract_release_date, gst_version, files('gst-plugins-ugly.doap'))
 276   if run_result.returncode() == 0
 277     release_date = run_result.stdout().strip()
 278     cdata.set_quoted('GST_PACKAGE_RELEASE_DATETIME', release_date)
 279     message('Package release date: ' + release_date)
 280   else
 281     # Error out if our release can't be found in the .doap file
 282     error(run_result.stderr())
 283   endif
 284 endif
 285
 286 configure_file(output : 'config.h', configuration : cdata)
 287
 288 run_command(python3, '-c', 'import shutil; shutil.copy("hooks/pre-commit.hook", ".git/hooks/pre-commit")')
 289
 290 if meson.version().version_compare('>= 0.54')
 291   plugin_names = []
 292   foreach plugin: plugins
 293     # FIXME: Use str.subtring() when we can depend on Meson 0.56
 294     split = plugin.name().split('gst')
 295     if split.length() == 2
 296       plugin_names += [split[1]]
 297     else
 298       warning('Need substring API in meson >= 0.56 to properly parse plugin name: ' + plugin.name())
 299       plugin_names += [plugin.name()]
 300     endif
 301   endforeach
 302   summary({'Plugins':plugin_names}, list_sep: ', ')
 303 endif