meson.build

   1 project('gstreamer-full', 'c',
   2   version : '1.21.0.1',
   3   meson_version : '>= 0.60.0',
   4   default_options : ['buildtype=debugoptimized',
   5                      # Needed due to https://github.com/mesonbuild/meson/issues/1889,
   6                      # but this can cause problems in the future. Remove it
   7                      # when it's no longer necessary.
   8                      'cpp_std=c++14'])
   9
  10 apiversion = '1.0'
  11 gst_version = '>= @0@'.format(meson.project_version())
  12
  13 build_system = build_machine.system()
  14 cc = meson.get_compiler('c')
  15
  16 fs = import('fs')
  17 gnome = import('gnome')
  18 pkgconfig = import('pkgconfig')
  19 python3 = import('python').find_installation()
  20 # Ensure that we're not being run from inside the development environment
  21 # because that will confuse meson, and it might find the already-built
  22 # gstreamer. It's fine if people run `ninja` as long as it doesn't run
  23 # reconfigure because ninja doesn't care about the env.
  24 ensure_not_devenv = '''
  25 import os
  26 assert('GST_ENV' not in os.environ)
  27 '''
  28 cmdres = run_command(python3, '-c', ensure_not_devenv, check: false)
  29 if cmdres.returncode() != 0
  30   error('Do not run `ninja reconfigure` or `meson` for gst-build inside the development environment, you will run into problems')
  31 endif
  32
  33 # Install gst-indent pre-commit hook
  34 run_command(python3, '-c', 'import shutil; shutil.copy("scripts/git-hooks/multi-pre-commit.hook", ".git/hooks/pre-commit")', check: false)
  35
  36 # Ensure that the user does not have Strawberry Perl in PATH, since it ships
  37 # with a pkg-config.bat and broken pkgconfig files for libffi and zlib. Will
  38 # cause a build error, such as in
  39 # https://gitlab.freedesktop.org/gstreamer/gst-build/-/issues/41
  40 ensure_no_strawberry_perl = '''
  41 import os
  42 assert(r'Strawberry\perl\bin' not in os.environ['PATH'])
  43 '''
  44 if build_system == 'windows' and meson.version().version_compare('<0.60.0')
  45   cmdres = run_command(python3, '-c', ensure_no_strawberry_perl, check: false)
  46   if cmdres.returncode() != 0
  47     error('You have Strawberry Perl in PATH which is known to cause build issues with Meson < 0.60.0. Please remove it from PATH, uninstall it, or upgrade Meson.')
  48   endif
  49 endif
  50
  51 # On macOS, you have to run "Install Certificates.command" otherwise Python
  52 # doesn't have access to the latest SSL CA Certificates, and Meson will fail to
  53 # download wrap files from websites that use, for example, Let's Encrypt.
  54 # We already recommend this in the README, but add a warning here as well.
  55 # Can't make this an error because the user might be using XCode's Python
  56 # 3 which doesn't have this script.
  57 if build_system == 'darwin'
  58   python3_cacert_file = python3.get_path('data') / 'etc/openssl/cert.pem'
  59   install_cert_cmd = '/Applications/Python @0@/Install Certificates.command'.format(python3.language_version())
  60   if not fs.is_symlink(python3_cacert_file) and fs.is_file(install_cert_cmd)
  61     warning('Please run "@0@" so that Python has access to the latest SSL certificates. Meson might fail to download some wraps without it.'.format(install_cert_cmd))
  62   endif
  63 endif
  64
  65 documented_projects = ''
  66 # Make it possible to use msys2 built zlib which fails
  67 # when not using the mingw toolchain as it uses unistd.h
  68 if not meson.is_subproject() and cc.get_id() == 'msvc'
  69   uname = find_program('uname', required: false)
  70   if uname.found()
  71     ret = run_command(uname, '-o', check: false)
  72     if ret.returncode() == 0 and ret.stdout().to_lower() == 'msys'
  73       ret = run_command(uname, '-r', check: false)
  74       # The kernel version returned by uname is actually the msys version
  75       if ret.returncode() == 0 and ret.stdout().startswith('2')
  76         # If a system zlib is found, disable UNIX features in zlib.h and zconf.h
  77         if cc.find_library('z').found()
  78           add_global_arguments('-DZ_SOLO', language: 'c')
  79         endif
  80       endif
  81     endif
  82   endif
  83 endif
  84
  85 # Ensure that MSVC interprets all source code as UTF-8. Only do this when we're
  86 # not a subproject, because subprojects are not allowed to call
  87 # add_global_arguments().
  88 if not meson.is_subproject() and cc.get_id() == 'msvc'
  89   add_global_arguments(
  90       cc.get_supported_arguments(['/utf-8']), # set the input encoding to utf-8
  91       language: ['c', 'cpp'])
  92 endif
  93
  94 building_full = get_option('default_library') == 'static'
  95 tools_option = 'tools=auto'
  96 if building_full and not get_option('tools').disabled()
  97   # Do not build subprojects tools when we build them against gst-full
  98   tools_option = 'tools=disabled'
  99 endif
 100
 101 # Ordered list of subprojects (dict has no ordering guarantees)
 102 subprojects = [
 103   ['gstreamer', {'build-hotdoc': true, 'subproject_options': [tools_option]}],
 104   ['gst-plugins-base', {'option': get_option('base'), 'build-hotdoc': true}],
 105   ['gst-plugins-good', {'option': get_option('good'), 'build-hotdoc': true}],
 106   ['libnice', { 'option': get_option('libnice'), 'match_gst_version': false}],
 107   ['gst-plugins-bad', { 'option': get_option('bad'), 'build-hotdoc': true}],
 108   ['gst-plugins-ugly', { 'option': get_option('ugly'), 'build-hotdoc': true}],
 109   ['gst-libav', { 'option': get_option('libav'), 'build-hotdoc': true}],
 110   ['gst-rtsp-server', { 'option': get_option('rtsp_server'), 'build-hotdoc': true}],
 111   ['gst-devtools', { 'option': get_option('devtools'), 'build-hotdoc': true, 'subproject_options': [tools_option]}],
 112   ['gst-integration-testsuites', { 'option': get_option('devtools') }],
 113   ['gst-editing-services', { 'option': get_option('ges'), 'build-hotdoc': true, 'subproject_options': [tools_option]}],
 114   ['gstreamer-vaapi', { 'option': get_option('vaapi'), 'build-hotdoc': true}],
 115   ['gst-omx', { 'option': get_option('omx'), 'build-hotdoc': true}],
 116   ['gstreamer-sharp', { 'option': get_option('sharp') }],
 117   ['pygobject', { 'option': get_option('python'), 'match_gst_version': false, 'sysdep': 'pygobject-3.0', 'sysdep_version': '>= 3.8' }],
 118   ['gst-python', { 'option': get_option('python')}],
 119   ['gst-examples', { 'option': get_option('gst-examples'), 'match_gst_versions': false}],
 120   ['gst-plugins-rs', { 'option': get_option('rs'), 'match_gst_version': false}],
 121 ]
 122
 123 symlink = '''
 124 import os
 125
 126 os.symlink(os.path.join('@1@', 'subprojects', '@0@'),
 127   os.path.join('@1@', '@0@'))
 128 '''
 129
 130 if build_system == 'windows'
 131   subproject('win-flex-bison-binaries')
 132   subproject('win-nasm')
 133 elif build_system == 'darwin'
 134   subproject('macos-bison-binary')
 135 endif
 136
 137 orc_subproject = subproject('orc', required: get_option('orc'))
 138
 139 foreach custom_subproj: get_option('custom_subprojects').split(',')
 140     if custom_subproj != ''
 141         message ('Adding custom subproject ' + custom_subproj)
 142         subprojects += [[custom_subproj, {'match_gst_version': false}]]
 143     endif
 144 endforeach
 145
 146
 147 subprojects_names = []
 148 plugins_doc_caches = []
 149 orc_update_targets = []
 150 all_plugins = []
 151 all_tools = {}
 152 # Using a list and not a dict to keep the ordering to build the chain of `gir`
 153 # dependencies
 154 all_libraries = []
 155 foreach sp : subprojects
 156   project_name = sp[0]
 157   build_infos = sp[1]
 158   is_required = build_infos.get('option', true)
 159   sysdep = build_infos.get('sysdep', '')
 160   sysdep_version = build_infos.get('sysdep_version', '')
 161   match_gst_version = build_infos.get('match_gst_version', true)
 162   default_options =  build_infos.get('subproject_options', [])
 163
 164   if match_gst_version
 165     subproj = subproject(project_name, version: gst_version, required: is_required, default_options: default_options)
 166   elif sysdep != ''
 167       sysdep_dep = dependency(sysdep, version: sysdep_version, required: false, default_options: default_options)
 168       if not sysdep_dep.found()
 169         subproj = subproject(project_name, required: is_required, default_options: default_options)
 170       endif
 171   else
 172     subproj = subproject(project_name, required: is_required, default_options: default_options)
 173   endif
 174
 175   if subproj.found()
 176     plugins = subproj.get_variable('gst_plugins', [])
 177     all_plugins += plugins
 178     if subproj.get_variable('gst_plugins', []).length() != subproj.get_variable('plugins', plugins).length()
 179       warning(f'DEPRECATED use of the `plugins` variable in @project_name@.')
 180       warning('The variable should now be called `gst_plugins` and use:')
 181       warning('`declare_dependency( link_with: <plugin_target>, variable: {\'full_path\': <plugin_target>.full_path()})` instead')
 182       foreach plugin: subproj.get_variable('plugins', [])
 183         all_plugins += [declare_dependency(link_with: plugin, variables: {'full_path': plugin.full_path()})]
 184       endforeach
 185     endif
 186
 187     all_libraries += subproj.get_variable('libraries', [])
 188     if not get_option('tools').disabled()
 189       all_tools += subproj.get_variable('gst_tools', {})
 190     endif
 191
 192     orc_update_targets += subproj.get_variable('orc_update_targets', [])
 193
 194     subprojects_names += [project_name]
 195
 196     if not meson.is_cross_build() and build_infos.get('build-hotdoc', false)
 197       plugins_doc_caches += [subproj.get_variable('plugins_doc_dep', [])]
 198       if documented_projects != ''
 199         documented_projects += ','
 200       endif
 201       documented_projects  += project_name
 202     endif
 203   endif
 204 endforeach
 205
 206 # Check if we need to also build glib-networking for TLS modules
 207 glib_dep = dependency('glib-2.0')
 208 if glib_dep.type_name() == 'internal'
 209   subproject('glib-networking', required : get_option('tls'),
 210              default_options: ['gnutls=auto', 'openssl=auto'])
 211 endif
 212
 213 plugins_doc_dep = custom_target('plugins-doc-cache',
 214   command: [python3, '-c', 'print("Built all doc caches")'],
 215   input: plugins_doc_caches,
 216   output: 'plugins_doc_caches',
 217   capture: true,
 218 )
 219
 220 if meson.is_cross_build() or build_machine.system() == 'windows'
 221     if get_option('doc').enabled()
 222         error('Documentation enabled but building the doc while cross building or building on windows is not supported yet.')
 223     endif
 224
 225     documented_projects = ''
 226     message('Documentation not built as building the documentation while cross building or building on windows is not supported yet.')
 227 else
 228   hotdoc_p = find_program('hotdoc', required : get_option('doc'))
 229   if not hotdoc_p.found()
 230     documented_projects = ''
 231     message('Not building documentation as hotdoc was not found')
 232   endif
 233 endif
 234
 235 write_file_contents = '''
 236 import os
 237 import sys
 238
 239 assert len(sys.argv) >= 3
 240 fname = sys.argv[1]
 241 contents = sys.argv[2]
 242
 243 with open(fname, 'w') as f:
 244     f.write(contents)
 245 '''
 246
 247 configure_file(
 248   output : 'GstDocumentedSubprojects',
 249   command : [python3,
 250              '-c', write_file_contents,
 251              '@OUTPUT@',
 252              documented_projects]
 253 )
 254
 255 if documented_projects != ''
 256   subproject('gst-docs', required: get_option('doc').enabled())
 257   message('Gst docs subprojects: ' + documented_projects)
 258 endif
 259
 260 all_plugins_paths = []
 261 all_plugins_dirs = []
 262 plugins_names = []
 263 foreach plugin: all_plugins
 264   plugin_path = plugin.get_variable('full_path')
 265   all_plugins_paths += plugin_path
 266   all_plugins_dirs += fs.parent(plugin_path)
 267   plugins_names += plugin_path
 268 endforeach
 269
 270 # Work around meson bug: https://github.com/mesonbuild/meson/pull/6770
 271 pathsep = host_machine.system() == 'windows' ? ';' : ':'
 272 all_plugins_paths = pathsep.join(all_plugins_paths)
 273
 274 devenv = environment()
 275 if not building_full
 276   devenv.prepend('GST_PLUGIN_PATH', all_plugins_dirs)
 277 else
 278   # Make sure the current build directory is first in PATH so we prefer tools
 279   # built here that links on gst-full instead instead of those built in
 280   # subprojects.
 281   devenv.prepend('PATH', meson.current_build_dir())
 282 endif
 283 devenv.set('CURRENT_GST', meson.current_source_dir())
 284 devenv.set('GST_VERSION', meson.project_version())
 285 devenv.set('GST_ENV', 'gst-' + meson.project_version())
 286 devenv.set('GST_REGISTRY', meson.current_build_dir() / 'registry.dat')
 287 devenv.set('GST_PLUGIN_SYSTEM_PATH', '')
 288 meson.add_devenv(devenv)
 289
 290 generate_plugins_paths = find_program('scripts/generate_plugins_path.py')
 291 configure_file(
 292   output : 'GstPluginsPath.json',
 293   command : [generate_plugins_paths,
 294              '@OUTPUT@',
 295              all_plugins_paths]
 296 )
 297
 298 if building_full
 299   cdata = configuration_data()
 300   cdata.set_quoted('GST_API_VERSION', apiversion)
 301   cdata.set_quoted('GETTEXT_PACKAGE', 'gstreamer-full-1.0')
 302   cdata.set_quoted('PACKAGE_VERSION', gst_version)
 303   cdata.set_quoted('GST_PACKAGE_ORIGIN', get_option('package-origin'))
 304   configure_file(output : 'config.h', configuration : cdata)
 305   configinc = include_directories('.')
 306   gst_c_args = ['-DHAVE_CONFIG_H']
 307
 308   # Generate a .c file which declare and register all built plugins
 309   all_plugin_names = ';'.join(plugins_names)
 310
 311   static_plugins = get_option('gst-full-plugins')
 312   if static_plugins == '*'
 313     static_plugins = all_plugin_names
 314   endif
 315   generate_init_static_plugins = find_program('scripts/generate_init_static_plugins.py')
 316   init_static_plugins_c = configure_file(
 317     output: 'gstinitstaticplugins.c',
 318     command : [generate_init_static_plugins,
 319                '-o ' + '@OUTPUT@',
 320                '-p ' + static_plugins,
 321                '-e ' + get_option('gst-full-elements'),
 322                '-t ' + get_option('gst-full-typefind-functions'),
 323                '-d ' + get_option('gst-full-device-providers'),
 324                '-T ' + get_option('gst-full-dynamic-types')
 325                ]
 326   )
 327
 328   gstfull_link_args = cc.get_supported_link_arguments(['-Wl,-Bsymbolic-functions'])
 329
 330   # Get a list of libraries that needs to be exposed in the ABI.
 331   exposed_libs = []
 332   exposed_deps = []
 333   exposed_girs = []
 334   incdir_deps = []
 335   wanted_libs = ['gstreamer-1.0'] + get_option('gst-full-libraries')
 336   all_libs = '*' in wanted_libs
 337
 338   foreach pkgname_library : all_libraries
 339     pkg_name = pkgname_library[0]
 340     lib_def = pkgname_library[1]
 341
 342     if pkg_name in wanted_libs or all_libs
 343       if lib_def.has_key('lib')
 344         exposed_deps += dependency(pkg_name)
 345         incdir_deps += dependency(pkg_name).partial_dependency(includes: true, sources: true)
 346         exposed_libs += [lib_def['lib']]
 347       endif
 348
 349       if lib_def.has_key('gir')
 350         exposed_girs += lib_def['gir']
 351       endif
 352     endif
 353   endforeach
 354
 355   # glib and gobject are part of our public API. If we are using glib from the
 356   # system then our pkg-config file must require it. If we built it as
 357   # subproject then we need to link_whole it.
 358   glib_deps = []
 359   glib_dep = dependency('glib-2.0')
 360   gobject_dep = dependency('gobject-2.0')
 361   if gobject_dep.type_name() == 'internal'
 362     glib_subproject = subproject('glib')
 363     exposed_libs += glib_subproject.get_variable('libglib')
 364     exposed_libs += glib_subproject.get_variable('libgobject')
 365     incdir_deps += [
 366       glib_dep.partial_dependency(includes: true),
 367       gobject_dep.partial_dependency(includes: true),
 368     ]
 369   else
 370     glib_deps = [glib_dep, gobject_dep]
 371   endif
 372
 373   link_deps = []
 374   if get_option('gst-full-version-script') != ''
 375     symbol_map = meson.current_source_dir() / get_option('gst-full-version-script')
 376     link_arg = '-Wl,--version-script=' + symbol_map
 377     if cc.has_link_argument(link_arg)
 378       gstfull_link_args += link_arg
 379       link_deps += symbol_map
 380     elif cc.get_id() == 'msvc'
 381       warning('FIXME: Provide a def file to publish the public symbols')
 382     else
 383       warning('FIXME: Linker does not support the supplied version script (' + symbol_map + '), please disable the "gst-full-version-script" option')
 384     endif
 385   endif
 386
 387   # Build both shared and static library
 388   gstfull = both_libraries('gstreamer-full-1.0',
 389     init_static_plugins_c,
 390     link_args: gstfull_link_args,
 391     link_whole : exposed_libs,
 392     dependencies : [incdir_deps, glib_deps, all_plugins],
 393     link_depends : link_deps,
 394     install : true,
 395   )
 396
 397   gst_full_dep = declare_dependency(link_with: gstfull.get_shared_lib(),
 398     dependencies : incdir_deps + glib_deps,
 399     include_directories: include_directories('.')
 400   )
 401
 402   gst_full_libs_private = cc.get_supported_link_arguments(['-Wl,--undefined=gst_init_static_plugins'])
 403   if gst_full_libs_private == []
 404     warning('The compiler does not support `-Wl,--undefined` linker flag. The method `gst_init_static_plugins` might be dropped during the link stage of an application using libgstreamer-full-1.0.a, preventing plugins registration.')
 405   endif
 406
 407   if not get_option('introspection').disabled()
 408     built_girs = {}
 409     foreach gir: exposed_girs
 410       includes = []
 411       foreach include: gir.get('includes', [])
 412         includes += [built_girs.get(include, include)]
 413       endforeach
 414
 415       gir += {
 416         'includes': includes,
 417         'extra_args': gir.get('extra_args', []) + ['--add-include-path=' + meson.current_build_dir()],
 418         'install': true,
 419       }
 420       built_girs += {gir.get('namespace') + '-' + gir.get('nsversion'): gnome.generate_gir(gstfull, kwargs: gir)[0]}
 421     endforeach
 422   endif
 423
 424   pkgconfig.generate(gstfull,
 425     requires: glib_deps,
 426     libraries_private: gst_full_libs_private,
 427     subdirs : 'gstreamer-1.0')
 428   meson.override_dependency('gstreamer-full-1.0', gst_full_dep)
 429
 430   if not get_option('tools').disabled()
 431     foreach tool, data: all_tools
 432       exe_name = '@0@-@1@'.format(tool, apiversion)
 433       extra_args = data.get('extra_c_args', [])
 434       sources = data.get('files')
 435       deps = []
 436       foreach d : data.get('deps', [])
 437         if d not in exposed_deps
 438           deps += d
 439         endif
 440       endforeach
 441
 442       executable(exe_name,
 443         sources,
 444         install: true,
 445         include_directories : [configinc],
 446         dependencies : [gst_full_dep] + deps,
 447         c_args: extra_args + gst_c_args + ['-DG_LOG_DOMAIN="@0@"'.format(exe_name)],
 448       )
 449
 450       if data.has_key('man_page')
 451         install_man(data.get('man_page'))
 452       endif
 453
 454     endforeach
 455   endif
 456 endif
 457
 458 message('Building subprojects: ' + ', '.join(subprojects_names))
 459
 460 setenv = find_program('gst-env.py')
 461
 462 devenv_cmd = [setenv, '--builddir=@0@'.format(meson.global_build_root()),
 463               '--srcdir=@0@'.format(meson.global_source_root())]
 464
 465 subdir('tests')
 466 subdir('ci/fuzzing')
 467
 468 if meson.can_run_host_binaries() and build_machine.system() == 'linux' and host_machine.system() == 'windows'
 469   # FIXME: Ideally we could get the wrapper directly from meson
 470   devenv_cmd += ['--wine', host_machine.cpu_family() == 'x86_64' ? 'wine64' : 'wine32']
 471   sysroot = meson.get_cross_property('sys_root')
 472   if sysroot != ''
 473     # Logic from meson
 474     devenv_cmd += ['--winepath', 'Z:' + join_paths(sysroot, 'bin')]
 475   endif
 476 endif
 477
 478 run_target('devenv', command : devenv_cmd)
 479
 480 if orc_subproject.found() and orc_update_targets.length() > 0
 481   alias_target('update-orc-dist', orc_update_targets)
 482 endif
 483
 484 dotnet_format = find_program('dotnet-format', required: false)
 485 if dotnet_format.found()
 486     run_target('csharp_format_check',
 487         command: [join_paths(meson.current_source_dir(), 'scripts', 'format-csharp'),
 488             '--check'
 489         ],
 490     )
 491     run_target('csharp_format_apply',
 492         command: [join_paths(meson.current_source_dir(), 'scripts', 'format-csharp'),
 493         ],
 494     )
 495 endif
 496
 497 summary({
 498   'gstreamer-full library': building_full,
 499 }, section: 'Build options', bool_yn: true, list_sep: '  ')
 500
 501 gst_tools = []
 502 foreach tool, data: all_tools
 503   gst_tools += tool
 504 endforeach
 505
 506 summary({
 507     'Tools': gst_tools,
 508 }, section: 'Build options', list_sep: ', ')