meson.build

   1 project('gstreamer-full', 'c',
   2   version : '1.22.2',
   3   meson_version : '>= 0.62.0',
   4   default_options : ['buildtype=debugoptimized',
   5                      # Needed due to https://github.com/mesonbuild/meson/issues/1889,
   6                      # but this can cause problems in the future. Remove it
   7                      # when it's no longer necessary.
   8                      'cpp_std=c++14'])
   9
  10 apiversion = '1.0'
  11 gst_version = '>= @0@'.format(meson.project_version())
  12
  13 build_system = build_machine.system()
  14 cc = meson.get_compiler('c')
  15
  16 fs = import('fs')
  17 gnome = import('gnome')
  18 pkgconfig = import('pkgconfig')
  19 python3 = import('python').find_installation()
  20 # Ensure that we're not being run from inside the development environment
  21 # because that will confuse meson, and it might find the already-built
  22 # gstreamer. It's fine if people run `ninja` as long as it doesn't run
  23 # reconfigure because ninja doesn't care about the env.
  24 ensure_not_devenv = '''
  25 import os
  26 assert('GST_ENV' not in os.environ)
  27 '''
  28 cmdres = run_command(python3, '-c', ensure_not_devenv, check: false)
  29 if cmdres.returncode() != 0
  30   error('Do not run `ninja reconfigure` or `meson` for gst-build inside the development environment, you will run into problems')
  31 endif
  32
  33 # Install gst-indent pre-commit hook
  34 run_command(python3, '-c', 'import shutil; shutil.copy("scripts/git-hooks/multi-pre-commit.hook", ".git/hooks/pre-commit")', check: false)
  35
  36 # On macOS, you have to run "Install Certificates.command" otherwise Python
  37 # doesn't have access to the latest SSL CA Certificates, and Meson will fail to
  38 # download wrap files from websites that use, for example, Let's Encrypt.
  39 # We already recommend this in the README, but add a warning here as well.
  40 # Can't make this an error because the user might be using XCode's Python
  41 # 3 which doesn't have this script.
  42 if build_system == 'darwin'
  43   python3_cacert_file = python3.get_path('data') / 'etc/openssl/cert.pem'
  44   install_cert_cmd = '/Applications/Python @0@/Install Certificates.command'.format(python3.language_version())
  45   if not fs.is_symlink(python3_cacert_file) and fs.is_file(install_cert_cmd)
  46     warning('Please run "@0@" so that Python has access to the latest SSL certificates. Meson might fail to download some wraps without it.'.format(install_cert_cmd))
  47   endif
  48 endif
  49
  50 documented_projects = ''
  51 # Make it possible to use msys2 built zlib which fails
  52 # when not using the mingw toolchain as it uses unistd.h
  53 if not meson.is_subproject() and cc.get_id() == 'msvc'
  54   uname = find_program('uname', required: false)
  55   if uname.found()
  56     ret = run_command(uname, '-o', check: false)
  57     if ret.returncode() == 0 and ret.stdout().to_lower() == 'msys'
  58       ret = run_command(uname, '-r', check: false)
  59       # The kernel version returned by uname is actually the msys version
  60       if ret.returncode() == 0 and ret.stdout().startswith('2')
  61         # If a system zlib is found, disable UNIX features in zlib.h and zconf.h
  62         if cc.find_library('z').found()
  63           add_global_arguments('-DZ_SOLO', language: 'c')
  64         endif
  65       endif
  66     endif
  67   endif
  68 endif
  69
  70 # Ensure that MSVC interprets all source code as UTF-8. Only do this when we're
  71 # not a subproject, because subprojects are not allowed to call
  72 # add_global_arguments().
  73 if not meson.is_subproject() and cc.get_id() == 'msvc'
  74   add_global_arguments(
  75       cc.get_supported_arguments(['/utf-8']), # set the input encoding to utf-8
  76       language: ['c', 'cpp'])
  77 endif
  78
  79 building_full = get_option('default_library') == 'static'
  80 tools_option = []
  81 if building_full and not get_option('tools').disabled()
  82   # Do not build subprojects tools when we build them against gst-full
  83   tools_option = ['tools=disabled']
  84 endif
  85
  86 # Ordered list of subprojects (dict has no ordering guarantees)
  87 subprojects = [
  88   ['gstreamer', {'build-hotdoc': true, 'subproject_options': tools_option}],
  89   ['gst-plugins-base', {'option': get_option('base'), 'build-hotdoc': true}],
  90   ['gst-plugins-good', {'option': get_option('good'), 'build-hotdoc': true}],
  91   ['libnice', { 'option': get_option('libnice'), 'match_gst_version': false}],
  92   ['gst-plugins-bad', { 'option': get_option('bad'), 'build-hotdoc': true}],
  93   ['gst-plugins-ugly', { 'option': get_option('ugly'), 'build-hotdoc': true}],
  94   ['gst-libav', { 'option': get_option('libav'), 'build-hotdoc': true}],
  95   ['gst-rtsp-server', { 'option': get_option('rtsp_server'), 'build-hotdoc': true}],
  96   ['gst-devtools', { 'option': get_option('devtools'), 'build-hotdoc': true, 'subproject_options': tools_option}],
  97   ['gst-integration-testsuites', { 'option': get_option('devtools') }],
  98   ['gst-editing-services', { 'option': get_option('ges'), 'build-hotdoc': true, 'subproject_options': tools_option}],
  99   ['gstreamer-vaapi', { 'option': get_option('vaapi'), 'build-hotdoc': true}],
 100   ['gst-omx', { 'option': get_option('omx'), 'build-hotdoc': true}],
 101   ['gstreamer-sharp', { 'option': get_option('sharp') }],
 102   ['pygobject', { 'option': get_option('python'), 'match_gst_version': false, 'sysdep': 'pygobject-3.0', 'sysdep_version': '>= 3.8' }],
 103   ['gst-python', { 'option': get_option('python')}],
 104   ['gst-examples', { 'option': get_option('gst-examples'), 'match_gst_versions': false}],
 105   ['gst-plugins-rs', { 'option': get_option('rs'), 'build-hotdoc': true, 'match_gst_version': false}],
 106 ]
 107
 108 if build_system == 'windows'
 109   subproject('win-flex-bison-binaries')
 110   subproject('win-nasm')
 111 elif build_system == 'darwin'
 112   subproject('macos-bison-binary')
 113 endif
 114
 115 orc_option = get_option('orc')
 116 # There is a check below to keep this in sync with subprojects/gst-plugins-base/meson.build
 117 orc_req = '>= 0.4.24'
 118 orc_source_option = get_option('orc-source')
 119 orc_subproject = disabler()
 120 if orc_option.allowed()
 121   if orc_source_option == 'subproject'
 122     orc_subproject = subproject('orc', required: orc_option)
 123   else
 124     dependency('orc-0.4', version: orc_req, required: orc_option,
 125                allow_fallback: orc_source_option == 'auto')
 126   endif
 127 endif
 128
 129 foreach custom_subproj: get_option('custom_subprojects').split(',')
 130     if custom_subproj != ''
 131         message ('Adding custom subproject ' + custom_subproj)
 132         subprojects += [[custom_subproj, {'match_gst_version': false}]]
 133     endif
 134 endforeach
 135
 136
 137 subprojects_names = []
 138 plugins_doc_caches = []
 139 orc_update_targets = []
 140 all_plugins = []
 141 all_tools = {}
 142 # Using a list and not a dict to keep the ordering to build the chain of `gir`
 143 # dependencies
 144 all_libraries = []
 145 foreach sp : subprojects
 146   project_name = sp[0]
 147   build_infos = sp[1]
 148   is_required = build_infos.get('option', true)
 149   sysdep = build_infos.get('sysdep', '')
 150   sysdep_version = build_infos.get('sysdep_version', '')
 151   match_gst_version = build_infos.get('match_gst_version', true)
 152   default_options =  build_infos.get('subproject_options', [])
 153
 154   if match_gst_version
 155     subproj = subproject(project_name, version: gst_version, required: is_required, default_options: default_options)
 156   elif sysdep != ''
 157     sysdep_dep = dependency(sysdep, version: sysdep_version, required: is_required, default_options: default_options)
 158   else
 159     subproj = subproject(project_name, required: is_required, default_options: default_options)
 160   endif
 161
 162   if project_name == 'gst-plugins-base'
 163     gst_base_orc_req = subproj.get_variable('orc_req', '')
 164     if gst_base_orc_req != orc_req
 165       error('orc_req is "@0@" but it should be "@1@" from subprojects/gst-plugins-base/meson.build'
 166             .format(orc_req, gst_base_orc_req))
 167     endif
 168   endif
 169
 170   if subproj.found()
 171     plugins = subproj.get_variable('gst_plugins', [])
 172     legacy_plugins = subproj.get_variable('plugins', [])
 173     all_plugins += plugins
 174     if plugins.length() == 0 and legacy_plugins.length() > 0
 175       warning(f'DEPRECATED use of the `plugins` variable in @project_name@.')
 176       warning('The variable should now be called `gst_plugins` and use:')
 177       warning('`declare_dependency( link_with: <plugin_target>, variable: {\'full_path\': <plugin_target>.full_path()})` instead')
 178       foreach plugin: legacy_plugins
 179         all_plugins += [declare_dependency(link_with: plugin, variables: {'full_path': plugin.full_path()})]
 180       endforeach
 181     endif
 182
 183     all_libraries += subproj.get_variable('gst_libraries', [])
 184     if not get_option('tools').disabled()
 185       all_tools += subproj.get_variable('gst_tools', {})
 186     endif
 187
 188     orc_update_targets += subproj.get_variable('orc_update_targets', [])
 189
 190     subprojects_names += [project_name]
 191
 192     if not meson.is_cross_build() and build_infos.get('build-hotdoc', false)
 193       plugins_doc_caches += [subproj.get_variable('gst_plugins_doc_dep', [])]
 194       if documented_projects != ''
 195         documented_projects += ','
 196       endif
 197       documented_projects  += project_name
 198     endif
 199   endif
 200 endforeach
 201
 202 # Check if we need to also build glib-networking for TLS modules
 203 giomodules = []
 204 glib_dep = dependency('glib-2.0')
 205 if glib_dep.type_name() == 'internal'
 206   subp = subproject('glib-networking', required : get_option('tls'),
 207              default_options: ['gnutls=auto', 'openssl=auto'])
 208   if subp.found()
 209     giomodules += subp.get_variable('giomodules', [])
 210   endif
 211 endif
 212
 213 gst_plugins_doc_dep = custom_target('plugins-doc-cache',
 214   command: [python3, '-c', 'print("Built all doc caches")'],
 215   input: plugins_doc_caches,
 216   output: 'plugins_doc_caches',
 217   capture: true,
 218 )
 219
 220 if meson.is_cross_build() or build_machine.system() == 'windows'
 221     if get_option('doc').enabled()
 222         error('Documentation enabled but building the doc while cross building or building on windows is not supported yet.')
 223     endif
 224
 225     documented_projects = ''
 226     message('Documentation not built as building the documentation while cross building or building on windows is not supported yet.')
 227 else
 228   hotdoc_p = find_program('hotdoc', required : get_option('doc'))
 229   if not hotdoc_p.found()
 230     documented_projects = ''
 231     message('Not building documentation as hotdoc was not found')
 232   endif
 233 endif
 234
 235 write_file_contents = '''
 236 import os
 237 import sys
 238
 239 assert len(sys.argv) >= 3
 240 fname = sys.argv[1]
 241 contents = sys.argv[2]
 242
 243 with open(fname, 'w') as f:
 244     f.write(contents)
 245 '''
 246
 247 configure_file(
 248   output : 'GstDocumentedSubprojects',
 249   command : [python3,
 250              '-c', write_file_contents,
 251              '@OUTPUT@',
 252              documented_projects]
 253 )
 254
 255 if documented_projects != ''
 256   gst_doc = subproject('gst-docs', required: get_option('doc').enabled())
 257   if gst_doc.found()
 258     gst_doc_target = gst_doc.get_variable('gstreamer_doc')
 259     alias_target('gst-doc', gst_doc_target)
 260   endif
 261   message('Gst docs subprojects: ' + documented_projects)
 262 endif
 263
 264 all_plugins_paths = []
 265 all_plugins_dirs = []
 266 plugins_names = []
 267 foreach plugin: all_plugins
 268   plugin_path = plugin.get_variable('full_path')
 269   all_plugins_paths += plugin_path
 270   all_plugins_dirs += fs.parent(plugin_path)
 271   plugins_names += fs.name(plugin_path)
 272 endforeach
 273
 274 # Work around meson bug: https://github.com/mesonbuild/meson/pull/6770
 275 pathsep = host_machine.system() == 'windows' ? ';' : ':'
 276 all_plugins_paths = pathsep.join(all_plugins_paths)
 277
 278 devenv = environment()
 279 if not building_full
 280   devenv.prepend('GST_PLUGIN_PATH', all_plugins_dirs)
 281 else
 282   # Make sure the current build directory is first in PATH so we prefer tools
 283   # built here that links on gst-full instead instead of those built in
 284   # subprojects.
 285   devenv.prepend('PATH', meson.current_build_dir())
 286 endif
 287 devenv.set('CURRENT_GST', meson.current_source_dir())
 288 devenv.set('GST_VERSION', meson.project_version())
 289 devenv.set('GST_ENV', 'gst-' + meson.project_version())
 290 devenv.set('GST_REGISTRY', meson.current_build_dir() / 'registry.dat')
 291 devenv.set('GST_PLUGIN_SYSTEM_PATH', '')
 292 meson.add_devenv(devenv)
 293
 294 generate_plugins_paths = find_program('scripts/generate_plugins_path.py')
 295 configure_file(
 296   output : 'GstPluginsPath.json',
 297   command : [generate_plugins_paths,
 298              '@OUTPUT@',
 299              all_plugins_paths]
 300 )
 301
 302 if building_full
 303   cdata = configuration_data()
 304   cdata.set_quoted('GST_API_VERSION', apiversion)
 305   cdata.set_quoted('GETTEXT_PACKAGE', 'gstreamer-full-1.0')
 306   cdata.set_quoted('PACKAGE_VERSION', gst_version)
 307   cdata.set_quoted('GST_PACKAGE_ORIGIN', get_option('package-origin'))
 308   configure_file(output : 'config.h', configuration : cdata)
 309   configinc = include_directories('.')
 310   gst_c_args = ['-DHAVE_CONFIG_H']
 311
 312   # Generate a .c file which declare and register all built plugins
 313   all_plugin_names = ';'.join(plugins_names)
 314
 315   static_plugins = get_option('gst-full-plugins')
 316   if static_plugins == '*'
 317     static_plugins = all_plugin_names
 318   endif
 319   generate_init_static_plugins = find_program('scripts/generate_init_static_plugins.py')
 320   init_static_plugins_c = configure_file(
 321     output: 'gstinitstaticplugins.c',
 322     command : [generate_init_static_plugins,
 323                '-o ' + '@OUTPUT@',
 324                '-p ' + static_plugins,
 325                '-e ' + get_option('gst-full-elements'),
 326                '-t ' + get_option('gst-full-typefind-functions'),
 327                '-d ' + get_option('gst-full-device-providers'),
 328                '-T ' + get_option('gst-full-dynamic-types'),
 329                '--giomodules', ';'.join(giomodules),
 330                ]
 331   )
 332
 333   gstfull_link_args = cc.get_supported_link_arguments(['-Wl,-Bsymbolic-functions'])
 334
 335   # Get a list of libraries that needs to be exposed in the ABI.
 336   exposed_libs = []
 337   exposed_deps = []
 338   exposed_girs = []
 339   incdir_deps = []
 340   wanted_libs = ['gstreamer-1.0'] + get_option('gst-full-libraries')
 341   all_libs = '*' in wanted_libs
 342
 343   foreach pkgname_library : all_libraries
 344     pkg_name = pkgname_library[0]
 345     lib_def = pkgname_library[1]
 346
 347     if pkg_name in wanted_libs or all_libs
 348       if lib_def.has_key('lib')
 349         exposed_deps += dependency(pkg_name)
 350         incdir_deps += dependency(pkg_name).partial_dependency(includes: true, sources: true)
 351         exposed_libs += [lib_def['lib']]
 352       endif
 353
 354       if lib_def.has_key('gir')
 355         exposed_girs += lib_def['gir']
 356       endif
 357     endif
 358   endforeach
 359
 360   # glib and gobject are part of our public API. If we are using glib from the
 361   # system then our pkg-config file must require it. If we built it as
 362   # subproject then we need to link_whole it.
 363   glib_deps = []
 364   glib_dep = dependency('glib-2.0')
 365   gobject_dep = dependency('gobject-2.0')
 366   if gobject_dep.type_name() == 'internal'
 367     glib_subproject = subproject('glib')
 368     exposed_libs += glib_subproject.get_variable('libglib')
 369     exposed_libs += glib_subproject.get_variable('libgobject')
 370     incdir_deps += [
 371       glib_dep.partial_dependency(includes: true),
 372       gobject_dep.partial_dependency(includes: true),
 373     ]
 374   else
 375     glib_deps = [glib_dep, gobject_dep]
 376   endif
 377
 378   link_deps = []
 379   if get_option('gst-full-version-script') != ''
 380     symbol_map = meson.current_source_dir() / get_option('gst-full-version-script')
 381     link_arg = '-Wl,--version-script=' + symbol_map
 382     if cc.has_link_argument(link_arg)
 383       gstfull_link_args += link_arg
 384       link_deps += symbol_map
 385     elif cc.get_id() == 'msvc'
 386       warning('FIXME: Provide a def file to publish the public symbols')
 387     else
 388       warning('FIXME: Linker does not support the supplied version script (' + symbol_map + '), please disable the "gst-full-version-script" option')
 389     endif
 390   endif
 391
 392   giomodules_deps = []
 393   foreach module : giomodules
 394     giomodules_deps += dependency(module)
 395   endforeach
 396
 397   # Build both shared and static library
 398   gstfull = both_libraries('gstreamer-full-1.0',
 399     init_static_plugins_c,
 400     link_args: gstfull_link_args,
 401     link_whole : exposed_libs,
 402     dependencies : [incdir_deps, glib_deps, all_plugins, giomodules_deps],
 403     link_depends : link_deps,
 404     install : true,
 405   )
 406
 407   gst_full_dep = declare_dependency(link_with: gstfull.get_shared_lib(),
 408     dependencies : incdir_deps + glib_deps,
 409     include_directories: include_directories('.')
 410   )
 411
 412   gst_full_libs_private = cc.get_supported_link_arguments(['-Wl,--undefined=gst_init_static_plugins'])
 413   if gst_full_libs_private == []
 414     warning('The compiler does not support `-Wl,--undefined` linker flag. The method `gst_init_static_plugins` might be dropped during the link stage of an application using libgstreamer-full-1.0.a, preventing plugins registration.')
 415   endif
 416
 417   if not get_option('introspection').disabled()
 418     built_girs = {}
 419     foreach gir: exposed_girs
 420       includes = []
 421       foreach include: gir.get('includes', [])
 422         includes += [built_girs.get(include, include)]
 423       endforeach
 424
 425       gir += {
 426         'includes': includes,
 427         'extra_args': gir.get('extra_args', []) + ['--add-include-path=' + meson.current_build_dir()],
 428         'install': true,
 429       }
 430       built_girs += {gir.get('namespace') + '-' + gir.get('nsversion'): gnome.generate_gir(gstfull, kwargs: gir)[0]}
 431     endforeach
 432   endif
 433
 434   pkgconfig.generate(gstfull,
 435     requires: glib_deps,
 436     libraries_private: gst_full_libs_private,
 437     subdirs : 'gstreamer-1.0')
 438   meson.override_dependency('gstreamer-full-1.0', gst_full_dep)
 439
 440   if not get_option('tools').disabled()
 441     foreach tool, data: all_tools
 442       exe_name = '@0@-@1@'.format(tool, apiversion)
 443       extra_args = data.get('extra_c_args', [])
 444       sources = data.get('files')
 445       install_tag = data.get('install_tag', 'bin')
 446       deps = []
 447       foreach d : data.get('deps', [])
 448         if d not in exposed_deps
 449           deps += d
 450         endif
 451       endforeach
 452
 453       executable(exe_name,
 454         sources,
 455         install: true,
 456         install_tag: install_tag,
 457         include_directories : [configinc],
 458         dependencies : [gst_full_dep] + deps,
 459         c_args: extra_args + gst_c_args + ['-DG_LOG_DOMAIN="@0@"'.format(exe_name)],
 460       )
 461
 462       if data.has_key('man_page')
 463         install_man(data.get('man_page'))
 464       endif
 465
 466     endforeach
 467   endif
 468 endif
 469
 470 message('Building subprojects: ' + ', '.join(subprojects_names))
 471
 472 setenv = find_program('gst-env.py')
 473
 474 devenv_cmd = [setenv, '--builddir=@0@'.format(meson.global_build_root()),
 475               '--srcdir=@0@'.format(meson.global_source_root())]
 476
 477 subdir('tests')
 478 subdir('ci/fuzzing')
 479
 480 if meson.can_run_host_binaries() and build_machine.system() == 'linux' and host_machine.system() == 'windows'
 481   # FIXME: Ideally we could get the wrapper directly from meson
 482   devenv_cmd += ['--wine', host_machine.cpu_family() == 'x86_64' ? 'wine64' : 'wine32']
 483   sysroot = meson.get_cross_property('sys_root')
 484   if sysroot != ''
 485     # Logic from meson
 486     devenv_cmd += ['--winepath', 'Z:' + join_paths(sysroot, 'bin')]
 487   endif
 488 endif
 489
 490 run_target('devenv', command : devenv_cmd)
 491
 492 if orc_subproject.found() and orc_update_targets.length() > 0
 493   alias_target('update-orc-dist', orc_update_targets)
 494 endif
 495
 496 subdir('scripts')
 497
 498 dotnet_format = find_program('dotnet-format', required: false)
 499 if dotnet_format.found()
 500     run_target('csharp_format_check',
 501         command: [join_paths(meson.current_source_dir(), 'scripts', 'format-csharp'),
 502             '--check'
 503         ],
 504     )
 505     run_target('csharp_format_apply',
 506         command: [join_paths(meson.current_source_dir(), 'scripts', 'format-csharp'),
 507         ],
 508     )
 509 endif
 510
 511 summary({
 512   'gstreamer-full library': building_full,
 513 }, section: 'Build options', bool_yn: true, list_sep: '  ')
 514
 515 gst_tools = []
 516 foreach tool, data: all_tools
 517   gst_tools += tool
 518 endforeach
 519
 520 summary({
 521     'Tools': gst_tools,
 522 }, section: 'Build options', list_sep: ', ')