meson.build

   1 project('gst-plugins-ugly', 'c',
   2   version : '1.15.0.1',
   3   meson_version : '>= 0.46.0',
   4   default_options : [ 'warning_level=1',
   5                       'buildtype=debugoptimized' ])
   6
   7 gst_version = meson.project_version()
   8 version_arr = gst_version.split('.')
   9 gst_version_major = version_arr[0].to_int()
  10 gst_version_minor = version_arr[1].to_int()
  11 gst_version_micro = version_arr[2].to_int()
  12  if version_arr.length() == 4
  13   gst_version_nano = version_arr[3].to_int()
  14 else
  15   gst_version_nano = 0
  16 endif
  17
  18 have_cxx = add_languages('cpp', required : false)
  19
  20 glib_req = '>= 2.40.0'
  21 gst_req = '>= @0@.@1@.0'.format(gst_version_major, gst_version_minor)
  22
  23 api_version = '1.0'
  24
  25 plugins_install_dir = '@0@/gstreamer-1.0'.format(get_option('libdir'))
  26
  27 cc = meson.get_compiler('c')
  28
  29 if cc.get_id() == 'msvc'
  30   # Ignore several spurious warnings for things gstreamer does very commonly
  31   # If a warning is completely useless and spammy, use '/wdXXXX' to suppress it
  32   # If a warning is harmless but hard to fix, use '/woXXXX' so it's shown once
  33   # NOTE: Only add warnings here if you are sure they're spurious
  34   add_project_arguments(
  35       '/wd4018', # implicit signed/unsigned conversion
  36       '/wd4146', # unary minus on unsigned (beware INT_MIN)
  37       '/wd4244', # lossy type conversion (e.g. double -> int)
  38       '/wd4305', # truncating type conversion (e.g. double -> float)
  39       language : 'c')
  40   # Disable SAFESEH with MSVC for plugins and libs that use external deps that
  41   # are built with MinGW
  42   noseh_link_args = ['/SAFESEH:NO']
  43 else
  44   noseh_link_args = []
  45 endif
  46
  47 if cc.has_link_argument('-Wl,-Bsymbolic-functions')
  48   add_project_link_arguments('-Wl,-Bsymbolic-functions', language : 'c')
  49 endif
  50
  51 # Symbol visibility
  52 if cc.has_argument('-fvisibility=hidden')
  53   add_project_arguments('-fvisibility=hidden', language: 'c')
  54 endif
  55
  56 # Disable strict aliasing
  57 if cc.has_argument('-fno-strict-aliasing')
  58   add_project_arguments('-fno-strict-aliasing', language: 'c')
  59 endif
  60
  61 cdata = configuration_data()
  62 check_headers = [
  63   ['HAVE_DLFCN_H', 'dlfcn.h'],
  64   ['HAVE_INTTYPES_H', 'inttypes.h'],
  65   ['HAVE_MALLOC_H', 'malloc.h'],
  66   ['HAVE_MEMORY_H', 'memory.h'],
  67   ['HAVE_STDINT_H', 'stdint.h'],
  68   ['HAVE_STDLIB_H', 'stdlib.h'],
  69   ['HAVE_STRINGS_H', 'strings.h'],
  70   ['HAVE_STRING_H', 'string.h'],
  71   ['HAVE_SYS_STAT_H', 'sys/stat.h'],
  72   ['HAVE_SYS_TYPES_H', 'sys/types.h'],
  73   ['HAVE_UNISTD_H', 'unistd.h'],
  74   ['HAVE_WINSOCK2_H', 'winsock2.h'],
  75 ]
  76
  77 foreach h : check_headers
  78   if cc.has_header(h.get(1))
  79     cdata.set(h.get(0), 1)
  80   endif
  81 endforeach
  82
  83 check_functions = [
  84 # check token HAVE_CPU_ALPHA
  85 # check token HAVE_CPU_ARM
  86 # check token HAVE_CPU_CRIS
  87 # check token HAVE_CPU_CRISV32
  88 # check token HAVE_CPU_HPPA
  89 # check token HAVE_CPU_I386
  90 # check token HAVE_CPU_IA64
  91 # check token HAVE_CPU_M68K
  92 # check token HAVE_CPU_MIPS
  93 # check token HAVE_CPU_PPC
  94 # check token HAVE_CPU_PPC64
  95 # check token HAVE_CPU_S390
  96 # check token HAVE_CPU_SPARC
  97 # check token HAVE_CPU_X86_64
  98   ['HAVE_DCGETTEXT', 'dcgettext'],
  99 # check token HAVE_EXPERIMENTAL
 100 # check token HAVE_EXTERNAL
 101 # check token HAVE_GETTEXT
 102 # check token HAVE_VALGRIND
 103 ]
 104
 105 foreach f : check_functions
 106   if cc.has_function(f.get(1))
 107     cdata.set(f.get(0), 1)
 108   endif
 109 endforeach
 110
 111 cdata.set('SIZEOF_CHAR', cc.sizeof('char'))
 112 cdata.set('SIZEOF_INT', cc.sizeof('int'))
 113 cdata.set('SIZEOF_LONG', cc.sizeof('long'))
 114 cdata.set('SIZEOF_SHORT', cc.sizeof('short'))
 115 cdata.set('SIZEOF_VOIDP', cc.sizeof('void*'))
 116
 117 cdata.set('VERSION', '"@0@"'.format(gst_version))
 118 cdata.set('PACKAGE', '"gst-plugins-ugly"')
 119 cdata.set('GETTEXT_PACKAGE', '"gst-plugins-ugly-1.0"')
 120 cdata.set('GST_LICENSE', '"LGPL"')
 121
 122 # GStreamer package name and origin url
 123 gst_package_name = get_option('with-package-name')
 124 if gst_package_name == ''
 125   if gst_version_nano == 0
 126     gst_package_name = 'GStreamer Ugly Plug-ins source release'
 127   elif gst_version_nano == 1
 128     gst_package_name = 'GStreamer Ugly Plug-ins git'
 129   else
 130     gst_package_name = 'GStreamer Ugly Plug-ins prerelease'
 131   endif
 132 endif
 133 cdata.set_quoted('GST_PACKAGE_NAME', gst_package_name)
 134 cdata.set_quoted('GST_PACKAGE_ORIGIN', get_option('with-package-origin'))
 135
 136 # Mandatory GST deps
 137 gst_dep = dependency('gstreamer-1.0', version : gst_req,
 138     fallback : ['gstreamer', 'gst_dep'])
 139 gstapp_dep = dependency('gstreamer-app-1.0', version : gst_req,
 140     fallback : ['gst-plugins-base', 'app_dep'])
 141 gstvideo_dep = dependency('gstreamer-video-1.0', version : gst_req,
 142     fallback : ['gst-plugins-base', 'video_dep'])
 143 gstpbutils_dep = dependency('gstreamer-pbutils-1.0', version : gst_req,
 144     fallback : ['gst-plugins-base', 'pbutils_dep'])
 145 gsttag_dep = dependency('gstreamer-tag-1.0', version : gst_req,
 146     fallback : ['gst-plugins-base', 'tag_dep'])
 147 gstfft_dep = dependency('gstreamer-fft-1.0', version : gst_req,
 148     fallback : ['gst-plugins-base', 'fft_dep'])
 149 gstaudio_dep = dependency('gstreamer-audio-1.0', version : gst_req,
 150     fallback : ['gst-plugins-base', 'audio_dep'])
 151 gstbase_dep = dependency('gstreamer-base-1.0', version : gst_req,
 152   fallback : ['gstreamer', 'gst_base_dep'])
 153 gstriff_dep = dependency('gstreamer-riff-1.0', version : gst_req,
 154     fallback : ['gst-plugins-base', 'riff_dep'])
 155 gstrtp_dep = dependency('gstreamer-rtp-1.0', version : gst_req,
 156     fallback : ['gst-plugins-base', 'rtp_dep'])
 157 gstnet_dep = dependency('gstreamer-net-1.0', version : gst_req,
 158   fallback : ['gstreamer', 'gst_net_dep'])
 159 gstsdp_dep = dependency('gstreamer-sdp-1.0', version : gst_req,
 160     fallback : ['gst-plugins-base', 'sdp_dep'])
 161 gstrtsp_dep = dependency('gstreamer-rtsp-1.0', version : gst_req,
 162     fallback : ['gst-plugins-base', 'rtsp_dep'])
 163 if host_machine.system() != 'windows'
 164   gstcheck_dep = dependency('gstreamer-check-1.0', version : gst_req,
 165     fallback : ['gstreamer', 'gst_check_dep'])
 166 endif
 167 gstcontroller_dep = dependency('gstreamer-controller-1.0', version : gst_req,
 168   fallback : ['gstreamer', 'gst_controller_dep'])
 169
 170 orc_dep = dependency('orc-0.4', version : '>= 0.4.16', required : false)
 171 if orc_dep.found()
 172   cdata.set('HAVE_ORC', 1) # used by a52dec for cpu detection
 173 else
 174   cdata.set('DISABLE_ORC', 1)
 175 endif
 176
 177 configure_file(output : 'config.h', configuration : cdata)
 178
 179 ugly_args = ['-DHAVE_CONFIG_H']
 180 configinc = include_directories('.')
 181 libsinc = include_directories('gst-libs')
 182
 183 if gst_dep.type_name() == 'internal'
 184   gst_debug_disabled = subproject('gstreamer').get_variable('disable_gst_debug')
 185 else
 186   # We can't check that in the case of subprojects as we won't
 187   # be able to build against an internal dependency (which is not built yet)
 188   gst_debug_disabled = cc.has_header_symbol('gst/gstconfig.h', 'GST_DISABLE_GST_DEBUG', dependencies: gst_dep)
 189 endif
 190
 191 if gst_debug_disabled and cc.has_argument('-Wno-unused')
 192   add_project_arguments('-Wno-unused', language: 'c')
 193 endif
 194
 195 warning_flags = [
 196   '-Wmissing-declarations',
 197   '-Wredundant-decls',
 198   '-Wwrite-strings',
 199   '-Wformat',
 200   '-Wformat-nonliteral',
 201   '-Wformat-security',
 202   '-Winit-self',
 203   '-Wmissing-include-dirs',
 204   '-Waddress',
 205   '-Wno-multichar',
 206   '-Wvla',
 207   '-Wpointer-arith',
 208   '-Waggregate-return',
 209 ]
 210
 211 warning_c_flags = [
 212   '-Wmissing-prototypes',
 213   '-Wold-style-definition',
 214   '-Wdeclaration-after-statement',
 215   '-Wnested-externs'
 216 ]
 217
 218 if have_cxx
 219   cxx = meson.get_compiler('cpp')
 220 endif
 221
 222 foreach extra_arg : warning_flags
 223   if cc.has_argument (extra_arg)
 224     add_project_arguments([extra_arg], language: 'c')
 225   endif
 226   if have_cxx and cxx.has_argument (extra_arg)
 227     add_project_arguments([extra_arg], language: 'cpp')
 228   endif
 229 endforeach
 230
 231 foreach extra_arg : warning_c_flags
 232   if cc.has_argument (extra_arg)
 233     add_project_arguments([extra_arg], language: 'c')
 234   endif
 235 endforeach
 236
 237 presetdir = join_paths(get_option('datadir'), 'gstreamer-' + api_version, 'presets')
 238 subdir('gst')
 239 subdir('ext')
 240 subdir('tests')
 241
 242 # xgettext is optional (on Windows for instance)
 243 if find_program('xgettext', required : false).found()
 244   subdir('po')
 245 endif
 246
 247 python3 = import('python3').find_python()
 248 run_command(python3, '-c', 'import shutil; shutil.copy("hooks/pre-commit.hook", ".git/hooks/pre-commit")')