meson.build

   1 project('gstreamer', 'c',
   2   version : '1.19.0.1',
   3   meson_version : '>= 0.54',
   4   default_options : [ 'warning_level=1',
   5                       'buildtype=debugoptimized' ])
   6
   7 gst_version = meson.project_version()
   8 version_arr = gst_version.split('.')
   9 gst_version_major = version_arr[0].to_int()
  10 gst_version_minor = version_arr[1].to_int()
  11 gst_version_micro = version_arr[2].to_int()
  12 if version_arr.length() == 4
  13   gst_version_nano = version_arr[3].to_int()
  14 else
  15   gst_version_nano = 0
  16 endif
  17 gst_version_is_dev = gst_version_minor % 2 == 1 and gst_version_micro < 90
  18
  19 host_system = host_machine.system()
  20
  21 apiversion = '1.0'
  22 soversion = 0
  23 # maintaining compatibility with the previous libtool versioning
  24 # current = minor * 100 + micro
  25 curversion = gst_version_minor * 100 + gst_version_micro
  26 libversion = '@0@.@1@.0'.format(soversion, curversion)
  27 osxversion = curversion + 1
  28
  29 prefix = get_option('prefix')
  30
  31 datadir = join_paths(prefix, get_option('datadir'))
  32 libexecdir = get_option('libexecdir')
  33 helpers_install_dir = join_paths(libexecdir, 'gstreamer-1.0')
  34
  35 cc = meson.get_compiler('c')
  36
  37 cdata = configuration_data()
  38
  39 if cc.get_id() == 'msvc'
  40   msvc_args = [
  41       # Ignore several spurious warnings for things gstreamer does very commonly
  42       # If a warning is completely useless and spammy, use '/wdXXXX' to suppress it
  43       # If a warning is harmless but hard to fix, use '/woXXXX' so it's shown once
  44       # NOTE: Only add warnings here if you are sure they're spurious
  45       '/wd4018', # implicit signed/unsigned conversion
  46       '/wd4146', # unary minus on unsigned (beware INT_MIN)
  47       '/wd4244', # lossy type conversion (e.g. double -> int)
  48       '/wd4305', # truncating type conversion (e.g. double -> float)
  49       cc.get_supported_arguments(['/utf-8']), # set the input encoding to utf-8
  50
  51       # Enable some warnings on MSVC to match GCC/Clang behaviour
  52       '/w14062', # enumerator 'identifier' in switch of enum 'enumeration' is not handled
  53       '/w14101', # 'identifier' : unreferenced local variable
  54       '/w14189', # 'identifier' : local variable is initialized but not referenced
  55   ]
  56   add_project_arguments(msvc_args, language: 'c')
  57 elif cc.has_link_argument('-Wl,-Bsymbolic-functions')
  58   # FIXME: Add an option for this if people ask for it
  59   add_project_link_arguments('-Wl,-Bsymbolic-functions', language : 'c')
  60 endif
  61
  62 # Symbol visibility
  63 have_visibility_hidden = false
  64 if cc.get_id() == 'msvc'
  65   export_define = '__declspec(dllexport) extern'
  66 elif cc.has_argument('-fvisibility=hidden')
  67   add_project_arguments('-fvisibility=hidden', language: 'c')
  68   export_define = 'extern __attribute__ ((visibility ("default")))'
  69   have_visibility_hidden = true
  70 else
  71   export_define = 'extern'
  72 endif
  73
  74 # Passing this through the command line would be too messy
  75 cdata.set('GST_API_EXPORT', export_define)
  76
  77 # Disable strict aliasing
  78 if cc.has_argument('-fno-strict-aliasing')
  79   add_project_arguments('-fno-strict-aliasing', language: 'c')
  80 endif
  81
  82 # Define G_DISABLE_DEPRECATED for development versions
  83 if gst_version_is_dev
  84   message('Disabling deprecated GLib API')
  85   add_project_arguments('-DG_DISABLE_DEPRECATED', language: 'c')
  86 endif
  87
  88 cast_checks = get_option('gobject-cast-checks')
  89 if cast_checks.disabled() or (cast_checks.auto() and not gst_version_is_dev)
  90   message('Disabling GLib cast checks')
  91   add_project_arguments('-DG_DISABLE_CAST_CHECKS', language: 'c')
  92 endif
  93
  94 glib_asserts = get_option('glib-asserts')
  95 if glib_asserts.disabled() or (glib_asserts.auto() and not gst_version_is_dev)
  96   message('Disabling GLib asserts')
  97   add_project_arguments('-DG_DISABLE_ASSERT', language: 'c')
  98 endif
  99
 100 glib_checks = get_option('glib-checks')
 101 if glib_checks.disabled() or (glib_checks.auto() and not gst_version_is_dev)
 102   message('Disabling GLib checks')
 103   add_project_arguments('-DG_DISABLE_CHECKS', language: 'c')
 104 endif
 105
 106 cdata.set_quoted('GST_API_VERSION', apiversion)
 107 cdata.set_quoted('GST_DATADIR', datadir)
 108 cdata.set_quoted('LOCALEDIR', join_paths(prefix, get_option('localedir')))
 109 cdata.set_quoted('LIBDIR', join_paths(prefix, get_option('libdir')))
 110 cdata.set_quoted('GST_API_VERSION', '1.0')
 111 cdata.set_quoted('GETTEXT_PACKAGE', 'gstreamer-1.0')
 112 cdata.set_quoted('GST_LICENSE', 'LGPL')
 113 cdata.set_quoted('PACKAGE', 'gstreamer')
 114 cdata.set_quoted('PACKAGE_NAME', 'GStreamer')
 115 cdata.set_quoted('PACKAGE_STRING', 'GStreamer @0@'.format(gst_version))
 116 cdata.set_quoted('PACKAGE_TARNAME', 'gstreamer')
 117 cdata.set_quoted('PACKAGE_BUGREPORT', 'https://gitlab.freedesktop.org/gstreamer/gstreamer/issues/new')
 118 cdata.set_quoted('PACKAGE_URL', '')
 119 cdata.set_quoted('PACKAGE_VERSION', gst_version)
 120 cdata.set_quoted('PLUGINDIR', join_paths(get_option('prefix'), get_option('libdir'), 'gstreamer-1.0'))
 121 cdata.set_quoted('VERSION', gst_version)
 122 cdata.set_quoted('GST_PLUGIN_SCANNER_INSTALLED', join_paths(prefix, helpers_install_dir, 'gst-plugin-scanner'))
 123 cdata.set_quoted('GST_PTP_HELPER_INSTALLED', join_paths(prefix, helpers_install_dir, 'gst-ptp-helper'))
 124 cdata.set_quoted('GST_PLUGIN_SUBDIR', get_option('libdir'),
 125   description: 'plugin directory path component, used to find plugins on relocatable builds on windows')
 126 cdata.set_quoted('GST_PLUGIN_SCANNER_SUBDIR', libexecdir,
 127   description: 'libexecdir path component, used to find plugin-scanner on relocatable builds on windows')
 128 cdata.set('GST_DISABLE_OPTION_PARSING', not get_option('option-parsing'))
 129
 130 mem_align_opt = get_option('memory-alignment')
 131 if mem_align_opt == 'malloc'
 132   cdata.set('MEMORY_ALIGNMENT_MALLOC', 1)
 133 elif mem_align_opt == 'pagesize'
 134   cdata.set('MEMORY_ALIGNMENT_PAGESIZE', 1)
 135 else
 136   cdata.set('MEMORY_ALIGNMENT', mem_align_opt.to_int())
 137 endif
 138
 139 if ['darwin', 'ios'].contains(host_system)
 140   cdata.set_quoted('GST_EXTRA_MODULE_SUFFIX', '.dylib')
 141 endif
 142
 143 if gst_version_nano > 0
 144     # Have GST_ERROR message printed when running from git
 145     cdata.set('GST_LEVEL_DEFAULT', 'GST_LEVEL_ERROR')
 146 else
 147     cdata.set('GST_LEVEL_DEFAULT', 'GST_LEVEL_NONE')
 148 endif
 149
 150 # GStreamer package name and origin url
 151 gst_package_name = get_option('package-name')
 152 if gst_package_name == ''
 153   if gst_version_nano == 0
 154     gst_package_name = 'GStreamer source release'
 155   elif gst_version_nano == 1
 156     gst_package_name = 'GStreamer git'
 157   else
 158     gst_package_name = 'GStreamer prerelease'
 159   endif
 160 endif
 161 cdata.set_quoted('GST_PACKAGE_NAME', gst_package_name)
 162 cdata.set_quoted('GST_PACKAGE_ORIGIN', get_option('package-origin'))
 163
 164 # These are only needed/used by the ABI tests
 165 host_defines = [
 166   [ 'x86', 'HAVE_CPU_I386' ],
 167   [ 'x86_64', 'HAVE_CPU_X86_64' ],
 168   [ 'arm', 'HAVE_CPU_ARM' ],
 169   [ 'aarch64', 'HAVE_CPU_AARCH64' ],
 170   [ 'mips', 'HAVE_CPU_MIPS' ],
 171   [ 'powerpc', 'HAVE_CPU_PPC' ],
 172   [ 'powerpc64', 'HAVE_CPU_PPC64' ],
 173   [ 'alpha', 'HAVE_CPU_ALPHA' ],
 174   [ 'sparc', 'HAVE_CPU_SPARC' ],
 175   [ 'ia64', 'HAVE_CPU_IA64' ],
 176   [ 'hppa', 'HAVE_CPU_HPPA' ],
 177   [ 'm68k', 'HAVE_CPU_M68K' ],
 178   [ 's390', 'HAVE_CPU_S390' ],
 179 ]
 180 foreach h : host_defines
 181   if h.get(0) == host_machine.cpu_family()
 182     cdata.set(h.get(1), 1)
 183   endif
 184 endforeach
 185 # FIXME: should really be called HOST_CPU or such
 186 cdata.set_quoted('TARGET_CPU', host_machine.cpu())
 187
 188 check_headers = [
 189   'dlfcn.h',
 190   'inttypes.h',
 191   'memory.h',
 192   'poll.h',
 193   'stdint.h',
 194   'stdio_ext.h',
 195   'strings.h',
 196   'string.h',
 197   'sys/param.h',
 198   'sys/poll.h',
 199   'sys/prctl.h',
 200   'sys/socket.h',
 201   'sys/stat.h',
 202   'sys/times.h',
 203   'sys/time.h',
 204   'sys/types.h',
 205   'sys/utsname.h',
 206   'sys/wait.h',
 207   'ucontext.h',
 208   'unistd.h',
 209   'sys/resource.h',
 210   'sys/uio.h',
 211 ]
 212
 213 if host_system == 'windows'
 214   check_headers += ['winsock2.h']
 215 endif
 216
 217 foreach h : check_headers
 218   if cc.has_header(h)
 219     define = 'HAVE_' + h.underscorify().to_upper()
 220     cdata.set(define, 1)
 221   endif
 222 endforeach
 223
 224 if cc.has_member('struct tm', 'tm_gmtoff', prefix : '#include <time.h>')
 225   cdata.set('HAVE_TM_GMTOFF', 1)
 226 endif
 227
 228 check_functions = [
 229   'gmtime_r',
 230   'sigaction',
 231   'getrusage',
 232   'fseeko',
 233   'ftello',
 234   'poll',
 235   'ppoll',
 236   'pselect',
 237   'getpagesize',
 238   'clock_gettime',
 239   'clock_nanosleep',
 240   'strnlen',
 241   # These are needed by libcheck
 242   'getline',
 243   'mkstemp',
 244   'alarm',
 245   'gettimeofday',
 246 ]
 247
 248 foreach f : check_functions
 249   if cc.has_function(f)
 250     define = 'HAVE_' + f.underscorify().to_upper()
 251     cdata.set(define, 1)
 252   endif
 253 endforeach
 254
 255 if cc.has_function('localtime_r', prefix : '#include<time.h>')
 256   cdata.set('HAVE_LOCALTIME_R', 1)
 257   # Needed by libcheck
 258   cdata.set('HAVE_DECL_LOCALTIME_R', 1)
 259 endif
 260
 261 if cc.links('''#include <pthread.h>
 262                int main() {
 263                  pthread_setname_np("example"); return 0;
 264                }''', name : 'pthread_setname_np(const char*)')
 265   cdata.set('HAVE_PTHREAD_SETNAME_NP_WITHOUT_TID', 1)
 266 endif
 267 if cc.has_header_symbol('pthread.h', 'pthread_condattr_setclock')
 268   cdata.set('HAVE_PTHREAD_CONDATTR_SETCLOCK', 1)
 269 endif
 270 if cc.has_header_symbol('pthread.h', 'pthread_cond_timedwait_relative_np')
 271   cdata.set('HAVE_PTHREAD_COND_TIMEDWAIT_RELATIVE_NP', 1)
 272 endif
 273
 274 # Check for futex(2)
 275 if cc.links('''#include <linux/futex.h>
 276                #include <sys/syscall.h>
 277                #include <unistd.h>
 278                int main (int argc, char ** argv) {
 279                  syscall (__NR_futex, NULL, FUTEX_WAKE, FUTEX_WAIT);
 280                  return 0;
 281                }''', name : 'futex(2) system call')
 282   cdata.set('HAVE_FUTEX', 1)
 283 endif
 284
 285 # Check for posix timers and monotonic clock
 286 time_prefix = '#include <time.h>\n'
 287 if cdata.has('HAVE_UNISTD_H')
 288   time_prefix += '#include <unistd.h>'
 289 endif
 290
 291 posix_timers_src = time_prefix + '''
 292 #if !defined(_POSIX_TIMERS) || _POSIX_TIMERS < 0 || !defined(CLOCK_REALTIME)
 293 #error Either _POSIX_TIMERS or CLOCK_REALTIME not defined
 294 #endif
 295 '''
 296 if cc.compiles(posix_timers_src, name : 'posix timers from time.h')
 297   cdata.set('HAVE_POSIX_TIMERS', 1)
 298 endif
 299
 300 monotonic_clock_src = time_prefix + '''
 301 #if !defined(_POSIX_MONOTONIC_CLOCK) || _POSIX_MONOTONIC_CLOCK < 0 || !defined(CLOCK_MONOTONIC)
 302 #error Either _POSIX_MONOTONIC_CLOCK or CLOCK_MONOTONIC not defined
 303 #endif
 304 '''
 305 if cc.compiles(monotonic_clock_src, name : 'monotonic clock from time.h')
 306   cdata.set('HAVE_MONOTONIC_CLOCK', 1)
 307 endif
 308
 309 # Check for __uint128_t (gcc) by checking for 128-bit division
 310 uint128_t_src = '''int main() {
 311 static __uint128_t v1 = 100;
 312 static __uint128_t v2 = 10;
 313 static __uint128_t u;
 314 u = v1 / v2;
 315 }'''
 316 if cc.compiles(uint128_t_src, name : '__uint128_t available')
 317   cdata.set('HAVE_UINT128_T', 1)
 318 endif
 319
 320 # All supported platforms have long long now
 321 cdata.set('HAVE_LONG_LONG', 1)
 322
 323 # We only want to use the __declspec(dllexport/import) dance in GST_EXPORT when
 324 # building with MSVC
 325 if cc.get_id() == 'msvc'
 326   cdata.set('GSTCONFIG_BUILT_WITH_MSVC', 1)
 327 else
 328   cdata.set('GSTCONFIG_BUILT_WITH_MSVC', 0)
 329 endif
 330
 331 # -------------------------------------------------------------------------------------
 332 # config.h things needed by libcheck
 333 # -------------------------------------------------------------------------------------
 334 if cc.has_function('getpid')
 335   cdata.set('HAVE_GETPID', 1)
 336 elif host_system == 'windows' and cc.has_function('_getpid')
 337   cdata.set('HAVE_PROCESS_H', 1) # Used by gstreamer too
 338   cdata.set('HAVE__GETPID', 1)
 339 endif
 340 if cc.has_function('strdup')
 341   cdata.set('HAVE_DECL_STRDUP', 1)
 342 elif host_system == 'windows' and cc.has_function('_strdup')
 343   cdata.set('HAVE__STRDUP', 1) # Windows (MSVC)
 344 endif
 345 if host_system != 'windows'
 346   cdata.set('HAVE_FORK', 1)
 347 else
 348   # libcheck requires HAVE_FORK to be 0 when fork() is not available
 349   cdata.set('HAVE_FORK', 0)
 350 endif
 351 if cc.has_function('strsignal')
 352   cdata.set('HAVE_DECL_STRSIGNAL', 1)
 353 endif
 354 # Check for availability of types
 355 if not cc.has_type('clockid_t', prefix : '#include <time.h>')
 356   cdata.set('clockid_t', 'int')
 357 endif
 358 if not cc.has_type('timer_t', prefix : '#include <time.h>')
 359   cdata.set('timer_t', 'int')
 360 endif
 361 if not cc.has_members('struct timespec', 'tv_sec', 'tv_nsec',
 362                       prefix : '#include <time.h>')
 363   cdata.set('STRUCT_TIMESPEC_DEFINITION_MISSING', 1)
 364 endif
 365 if not cc.has_members('struct itimerspec', 'it_interval', 'it_value',
 366                       prefix : '#include <time.h>')
 367   cdata.set('STRUCT_ITIMERSPEC_DEFINITION_MISSING', 1)
 368 endif
 369
 370 # Platform deps; only ws2_32 and execinfo for now
 371 platform_deps = []
 372 if host_system == 'windows'
 373   platform_deps = [cc.find_library('ws2_32')]
 374 endif
 375
 376 building_for_uwp = false
 377 if host_system == 'windows'
 378   # Check whether we're building for UWP apps
 379   code = '''
 380   #include <windows.h>
 381   #if !(WINAPI_FAMILY_PARTITION(WINAPI_PARTITION_APP) && !WINAPI_FAMILY_PARTITION(WINAPI_PARTITION_DESKTOP))
 382   #error "Not building for UWP"
 383   #endif'''
 384   if cc.compiles(code, name : 'building for UWP')
 385     building_for_uwp = true
 386   endif
 387 endif
 388
 389 backtrace_deps = []
 390 unwind_dep = dependency('libunwind', required : get_option('libunwind'))
 391 dw_dep = dependency('libdw', required: get_option('libdw'))
 392 dbghelp_option = get_option('dbghelp')
 393 if dbghelp_option.enabled() and building_for_uwp
 394   error('DbgHelp is not supported for UWP')
 395 endif
 396 have_dbghelp = cc.has_header('dbghelp.h', required: dbghelp_option) and cc.has_header('tlhelp32.h', required: dbghelp_option)
 397 backtrace_deps = [unwind_dep, dw_dep]
 398 backtrace_source_info = false
 399 backtrace_minimal = false
 400 # MSVC debug stack trace support
 401 if host_system == 'windows' and have_dbghelp and not building_for_uwp
 402   cdata.set('HAVE_DBGHELP', 1)
 403   backtrace_source_info = true
 404 # DWARF stack trace support with libunwind and elf-utils
 405 elif unwind_dep.found()
 406   cdata.set('HAVE_UNWIND', 1)
 407   if dw_dep.found()
 408     cdata.set('HAVE_DW', 1)
 409     backtrace_source_info = true
 410   endif
 411   backtrace_minimal = true
 412 # Basic backtrace() stack trace support
 413 elif cc.has_function('backtrace')
 414   cdata.set('HAVE_BACKTRACE', 1)
 415   backtrace_minimal = true
 416 endif
 417 # Print messages about what was enabled
 418 if not backtrace_source_info
 419   if not backtrace_minimal
 420     message('NO support for stack traces.')
 421   else
 422     message('Minimal support for stack traces, no source info.')
 423   endif
 424 endif
 425
 426 if cc.has_header('execinfo.h')
 427   if cc.has_function('backtrace', prefix : '#include <execinfo.h>')
 428     cdata.set('HAVE_BACKTRACE', 1)
 429   else
 430     execinfo_dep = cc.find_library('execinfo', required : false)
 431     if execinfo_dep.found() and cc.has_function('backtrace', prefix : '#include <execinfo.h>', dependencies : execinfo_dep)
 432       cdata.set('HAVE_BACKTRACE', 1)
 433       platform_deps += execinfo_dep
 434     endif
 435   endif
 436 endif
 437
 438 gst_debug = get_option('gst_debug')
 439 if not gst_debug
 440   add_project_arguments(['-Wno-unused'], language: 'c')
 441 endif
 442
 443 warning_flags = [
 444   '-Wmissing-declarations',
 445   '-Wmissing-prototypes',
 446   '-Wredundant-decls',
 447   '-Wundef',
 448   '-Wwrite-strings',
 449   '-Wformat',
 450   '-Wformat-nonliteral',
 451   '-Wformat-security',
 452   '-Wold-style-definition',
 453   '-Winit-self',
 454   '-Wmissing-include-dirs',
 455   '-Waddress',
 456   '-Waggregate-return',
 457   '-Wno-multichar',
 458   '-Wdeclaration-after-statement',
 459   '-Wvla',
 460   '-Wpointer-arith',
 461 ]
 462
 463 foreach extra_arg : warning_flags
 464   if cc.has_argument (extra_arg)
 465     add_project_arguments([extra_arg], language: 'c')
 466   endif
 467 endforeach
 468
 469 # Used by the gstutils test
 470 gmp_dep = cc.find_library('gmp', required : false)
 471 cdata.set('HAVE_GMP', gmp_dep.found())
 472 gsl_dep = cc.find_library('gsl', required : false)
 473 gslcblas_dep = cc.find_library('gslcblas', required : false)
 474 cdata.set('HAVE_GSL', gsl_dep.found() and gslcblas_dep.found())
 475 test_deps = [gmp_dep, gsl_dep, gslcblas_dep]
 476
 477 # Used by gstinfo.c
 478 dl_dep = cc.find_library('dl', required : false)
 479 cdata.set('HAVE_DLADDR', cc.has_function('dladdr', dependencies : dl_dep))
 480 cdata.set('GST_ENABLE_EXTRA_CHECKS', not get_option('extra-checks').disabled())
 481 cdata.set('USE_POISONING', get_option('poisoning'))
 482
 483 configinc = include_directories('.')
 484 libsinc = include_directories('libs')
 485 privinc = include_directories('gst')
 486
 487 # Find dependencies
 488 glib_dep = dependency('glib-2.0', version : '>=2.56.0',
 489   fallback: ['glib', 'libglib_dep'])
 490 gobject_dep = dependency('gobject-2.0',
 491   fallback: ['glib', 'libgobject_dep'])
 492 gmodule_dep = dependency('gmodule-2.0',
 493   fallback: ['glib', 'libgmodule_dep'])
 494 if host_system == 'windows'
 495     gio_dep = dependency('gio-2.0',
 496         fallback: ['glib', 'libgio_dep'])
 497 else
 498     gio_dep = [dependency('gio-2.0',
 499                   fallback: ['glib', 'libgio_dep']),
 500                dependency('gio-unix-2.0',
 501                   fallback: ['glib', 'libgio_dep'])]
 502 endif
 503
 504 mathlib = cc.find_library('m', required : false)
 505 # Needed for timer_create/settime/delete
 506 # Also provides clock_gettime in glibc < 2.17
 507 rt_lib = cc.find_library('rt', required : false)
 508
 509 gir = find_program('g-ir-scanner', required : get_option('introspection'))
 510 gnome = import('gnome')
 511
 512 build_gir = gir.found() and (not meson.is_cross_build() or get_option('introspection').enabled())
 513
 514 gir_init_section = [ '--add-init-section=extern void gst_init(gint*,gchar**);' + \
 515     'g_setenv("GST_REGISTRY_DISABLE", "yes", TRUE);' + \
 516     'g_setenv("GST_REGISTRY_1.0", "/no/way/this/exists.reg", TRUE);' + \
 517     'g_setenv("GST_PLUGIN_PATH_1_0", "", TRUE);' + \
 518     'g_setenv("GST_PLUGIN_SYSTEM_PATH_1_0", "", TRUE);' + \
 519     'gst_init(NULL,NULL);', '--quiet']
 520
 521 gst_c_args = ['-DHAVE_CONFIG_H']
 522
 523 # FIXME: This is only needed on windows and probably breaks when
 524 # default_library = 'both'. We should add this flag to static_c_args instead
 525 # when Meson supports it: https://github.com/mesonbuild/meson/issues/3304
 526 if get_option('default_library') == 'static'
 527   gst_c_args += ['-DGST_STATIC_COMPILATION']
 528 endif
 529
 530 # Used in gst/parse/meson.build and below
 531 python3 = import('python').find_installation()
 532
 533 bashcomp_option = get_option('bash-completion')
 534 bashcomp_dep = dependency('bash-completion', version : '>= 2.0', required : bashcomp_option)
 535 bash_completions_dir = ''
 536 bash_helpers_dir = ''
 537
 538 bashcomp_found = false
 539 if bashcomp_dep.found()
 540   bashcomp_found = true
 541   bashcomp_dir_override = bashcomp_dep.version().version_compare('>= 2.10') ? ['datadir', datadir] : ['prefix', prefix]
 542   bash_completions_dir = bashcomp_dep.get_pkgconfig_variable('completionsdir', define_variable: bashcomp_dir_override)
 543   if bash_completions_dir == ''
 544     msg = 'Found bash-completion but the .pc file did not set \'completionsdir\'.'
 545     if bashcomp_option.enabled()
 546       error(msg)
 547     else
 548       message(msg)
 549     endif
 550     bashcomp_found = false
 551   endif
 552
 553   bash_helpers_dir = bashcomp_dep.get_pkgconfig_variable('helpersdir', define_variable: bashcomp_dir_override)
 554   if bash_helpers_dir == ''
 555     msg = 'Found bash-completion, but the .pc file did not set \'helpersdir\'.'
 556     if bashcomp_option.enabled()
 557       error(msg)
 558     else
 559       message(msg)
 560     endif
 561     bashcomp_found = false
 562   endif
 563 endif
 564
 565 plugins_install_dir = join_paths(get_option('libdir'), 'gstreamer-1.0')
 566
 567 pkgconfig = import('pkgconfig')
 568 plugins_pkgconfig_install_dir = join_paths(plugins_install_dir, 'pkgconfig')
 569 if get_option('default_library') == 'shared'
 570   # If we don't build static plugins there is no need to generate pc files
 571   plugins_pkgconfig_install_dir = disabler()
 572 endif
 573 pkgconfig_variables = ['exec_prefix=${prefix}',
 574     'toolsdir=${exec_prefix}/bin',
 575     'pluginsdir=${libdir}/gstreamer-1.0',
 576     'datarootdir=${prefix}/share',
 577     'datadir=${datarootdir}',
 578     'girdir=${datadir}/gir-1.0',
 579     'typelibdir=${libdir}/girepository-1.0',
 580     'libexecdir=${prefix}/libexec',
 581     'pluginscannerdir=${libexecdir}/gstreamer-1.0']
 582 pkgconfig_uninstalled_variables = ['exec_prefix=${prefix}',
 583         'gstreamerdir=${prefix}/subprojects/gstreamer',
 584     'bashhelpersdir=${gstreamerdir}/data/bash-completion/helpers',
 585     'helpersdir=${gstreamerdir}/libs/gst/helpers']
 586 pkgconfig_subdirs = ['gstreamer-1.0']
 587
 588 subdir('gst')
 589 subdir('libs')
 590 subdir('plugins')
 591 if not get_option('tools').disabled()
 592   subdir('tools')
 593 endif
 594 subdir('tests')
 595 subdir('data')
 596 subdir('docs')
 597
 598 # xgettext is optional (on Windows for instance)
 599 if find_program('xgettext', required : get_option('nls')).found()
 600   cdata.set('ENABLE_NLS', 1)
 601   subdir('po')
 602 endif
 603
 604 subdir('scripts')
 605
 606 # Set release date
 607 if gst_version_nano == 0
 608   extract_release_date = find_program('scripts/extract-release-date-from-doap-file.py')
 609   run_result = run_command(extract_release_date, gst_version, files('gstreamer.doap'))
 610   if run_result.returncode() == 0
 611     release_date = run_result.stdout().strip()
 612     cdata.set_quoted('GST_PACKAGE_RELEASE_DATETIME', release_date)
 613     message('Package release date: ' + release_date)
 614   else
 615     # Error out if our release can't be found in the .doap file
 616     error(run_result.stderr())
 617   endif
 618 endif
 619
 620 configure_file(output : 'config.h', configuration : cdata)
 621 run_command(python3, '-c', 'import shutil; shutil.copy("hooks/pre-commit.hook", ".git/hooks/pre-commit")')
 622 install_data('gst-element-check-1.0.m4', install_dir : join_paths(get_option('datadir'), 'aclocal'))
 623
 624 if meson.version().version_compare('>= 0.54')
 625   plugin_names = []
 626   foreach plugin: plugins
 627     # FIXME: Use str.subtring() when we can depend on Meson 0.56
 628     split = plugin.name().split('gst')
 629     if split.length() == 2
 630       plugin_names += [split[1]]
 631     else
 632       warning('Need substring API in meson >= 0.56 to properly parse plugin name: ' + plugin.name())
 633       plugin_names += [plugin.name()]
 634     endif
 635   endforeach
 636   summary({'Plugins':plugin_names}, list_sep: ', ')
 637 endif