meson.build

   1 project('gst-editing-services', 'c',
   2   version : '1.9.90',
   3   meson_version : '>= 0.33.0',
   4   default_options : [ 'warning_level=1',
   5                       'c_std=gnu99',
   6                       'buildtype=debugoptimized' ])
   7
   8 gst_version = meson.project_version()
   9 version_arr = gst_version.split('.')
  10 gst_version_major = version_arr[0]
  11 gst_version_minor = version_arr[1]
  12 gst_version_micro = version_arr[2]
  13 if version_arr.length() == 4
  14   gst_version_nano = version_arr[3]
  15 else
  16   gst_version_nano = 0
  17 endif
  18
  19 apiversion = '1.0'
  20 soversion = 0
  21 # maintaining compatibility with the previous libtool versioning
  22 # current = minor * 100 + micro
  23 libversion = '@0@.@1@.0'.format(soversion, gst_version_minor.to_int() * 100 + gst_version_micro.to_int())
  24
  25 glib_req = '>= 2.40.0'
  26 gst_req = '>= @0@.@1@.0'.format(gst_version_major, gst_version_minor)
  27
  28 cc = meson.get_compiler('c')
  29 # Ignore several spurious warnings for things gstreamer does very commonly
  30 # If a warning is completely useless and spammy, use '/wdXXXX' to suppress it
  31 # If a warning is harmless but hard to fix, use '/woXXXX' so it's shown once
  32 # NOTE: Only add warnings here if you are sure they're spurious
  33 if cc.get_id() == 'msvc'
  34   add_global_arguments('/wd4018', '/wd4244', '/wd4996', language : 'c')
  35 endif
  36
  37 cdata = configuration_data()
  38 cdata.set('VERSION', '"@0@"'.format(gst_version))
  39 cdata.set('PACKAGE', '"gst-editing-services"')
  40 cdata.set('PACKAGE_VERSION', '"@0@"'.format(gst_version))
  41 cdata.set('PACKAGE_BUGREPORT', '"http://bugzilla.gnome.org/enter_bug.cgi?product=GStreamer"')
  42 cdata.set('PACKAGE_NAME', '"GStreamer Editing Services"')
  43 cdata.set('GST_PACKAGE_NAME', '"GStreamer Editing Services"')
  44 cdata.set('GST_PACKAGE_ORIGIN', '"Unknown package origin"')
  45 cdata.set('GST_LICENSE', '"LGPL"')
  46 cdata.set('LIBDIR', '"@0@"'.format(get_option('libdir')))
  47
  48 # Mandatory GST deps
  49 gst_dep = dependency('gstreamer-' + apiversion, version : gst_req,
  50     fallback : ['gstreamer', 'gst_dep'])
  51 gstpbutils_dep = dependency('gstreamer-pbutils-' + apiversion, version : gst_req,
  52     fallback : ['gst-plugins-base', 'pbutils_dep'])
  53 gstvideo_dep = dependency('gstreamer-video-' + apiversion, version : gst_req,
  54     fallback : ['gst-plugins-base', 'video_dep'])
  55 gstbase_dep = dependency('gstreamer-base-1.0', version : gst_req,
  56     fallback : ['gstreamer', 'gst_base_dep'])
  57 gstcheck_dep = dependency('gstreamer-check-1.0', version : gst_req,
  58   fallback : ['gstreamer', 'gst_check_dep'])
  59 gstcontroller_dep = dependency('gstreamer-controller-1.0', version : gst_req,
  60   fallback : ['gstreamer', 'gst_controller_dep'])
  61 gstvalidate_dep = dependency('gst-validate-1.0', version : gst_req, required : false,
  62   fallback : ['gst-devtools', 'validate_dep'])
  63
  64 gio_dep = dependency('gio-2.0', version : glib_req)
  65 libxml_dep = dependency('libxml-2.0')
  66
  67 # TODO Properly port to Gtk 3
  68 # gtk_dep = dependency('gtk+-3.0', required : false)
  69
  70 libges_deps = [gst_dep, gstbase_dep, gstvideo_dep, gstpbutils_dep,
  71                gstcontroller_dep, gio_dep, libxml_dep]
  72
  73 if gstvalidate_dep.found()
  74     libges_deps = libges_deps + [gstvalidate_dep]
  75     cdata.set('HAVE_GST_VALIDATE', 1)
  76 endif
  77
  78 configure_file(input : 'config.h.meson',
  79   output : 'config.h',
  80   configuration : cdata)
  81
  82
  83 gir = find_program('g-ir-scanner', required : false)
  84 gnome = import('gnome')
  85 gtkdoc = find_program('gtkdoc-scan', required : false)
  86
  87 # Fixme, not very elegant.
  88 build_gir = gir.found() and not meson.is_cross_build() and not get_option('disable_introspection')
  89 gir_init_section = [ '--add-init-section=extern void gst_init(gint*,gchar**); gst_init(NULL,NULL);' ]
  90
  91 ges_c_args = ['-DHAVE_CONFIG_H']
  92 plugins_install_dir = '@0@/gstreamer-1.0'.format(get_option('libdir'))
  93
  94 configinc = include_directories('.')
  95 subdir('ges')
  96 subdir('plugins')
  97 subdir('tools')
  98 subdir('pkgconfig')
  99 subdir('tests')
 100 subdir('examples')
 101
 102 if build_machine.system() != 'windows'
 103   if gtkdoc.found()
 104     subdir('docs')
 105   else
 106     message('Not building documentation as gtk-doc was not found')
 107   endif
 108 else
 109   message('Disabling gtk-doc while building on Windows')
 110 endif
 111
 112 python3 = find_program('python3')
 113 run_command(python3, '-c', 'import shutil; shutil.copy("hooks/pre-commit.hook", ".git/hooks/pre-commit")')